[gentoo-commits] gentoo-x86 commit in dev-util/valgrind: ChangeLog valgrind-3.7.0-r1.ebuild valgrind-3.7.0.ebuild

[gentoo-commits] gentoo-x86 commit in dev-util/valgrind: ChangeLog valgrind-3.7.0-r1.ebuild valgrind-3.7.0.ebuild

[Anthony G. Basile (blueness)]

blueness    11/11/23 19:19:48

  Modified:             ChangeLog
  Added:                valgrind-3.7.0-r1.ebuild
  Removed:              valgrind-3.7.0.ebuild
  Log:
  Replace original patch with the version accepted upstream
  
  (Portage version: 2.1.10.11/cvs/Linux x86_64)

Revision  Changes    Path
1.131                dev-util/valgrind/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/valgrind/ChangeLog?rev=1.131&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/valgrind/ChangeLog?rev=1.131&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/valgrind/ChangeLog?r1=1.130&r2=1.131

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/valgrind/ChangeLog,v
retrieving revision 1.130
retrieving revision 1.131
diff -u -r1.130 -r1.131
--- ChangeLog	11 Nov 2011 01:40:06 -0000	1.130
+++ ChangeLog	23 Nov 2011 19:19:48 -0000	1.131
@@ -1,6 +1,13 @@
 # ChangeLog for dev-util/valgrind
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/valgrind/ChangeLog,v 1.130 2011/11/11 01:40:06 blueness Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/valgrind/ChangeLog,v 1.131 2011/11/23 19:19:48 blueness Exp $
+
+*valgrind-3.7.0-r1 (23 Nov 2011)
+
+  23 Nov 2011; Anthony G. Basile <blueness@gentoo.org> -valgrind-3.7.0.ebuild,
+  +valgrind-3.7.0-r1.ebuild, files/valgrind-3.7.0-fix-gcc-regex.patch:
+  Replace original patch with the version accepted upstream
+  https://bugs.kde.org/show_bug.cgi?id=286384
 
 *valgrind-3.7.0 (11 Nov 2011)
 



1.1                  dev-util/valgrind/valgrind-3.7.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/valgrind/valgrind-3.7.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/valgrind/valgrind-3.7.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: valgrind-3.7.0-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/valgrind/valgrind-3.7.0-r1.ebuild,v 1.1 2011/11/23 19:19:48 blueness Exp $

EAPI=4
inherit autotools eutils flag-o-matic toolchain-funcs multilib pax-utils

DESCRIPTION="An open-source memory debugger for GNU/Linux"
HOMEPAGE="http://www.valgrind.org"
SRC_URI="http://www.valgrind.org/downloads/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="-* ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="mpi"

DEPEND="mpi? ( virtual/mpi )"
RDEPEND="${DEPEND}"

src_prepare() {
	# Correct hard coded doc location
	sed -i -e "s:doc/valgrind:doc/${PF}:" docs/Makefile.am || die

	# Respect CFLAGS, LDFLAGS
	epatch "${FILESDIR}"/${PN}-3.7.0-respect-flags.patch

	# Changing Makefile.all.am to disable SSP
	epatch "${FILESDIR}"/${PN}-3.7.0-fno-stack-protector.patch

	# Yet more local labels, this time for ppc32 & ppc64
	epatch "${FILESDIR}"/${PN}-3.6.0-local-labels.patch

	# Don't build in empty assembly files for other platforms or we'll get a QA
	# warning about executable stacks.
	epatch "${FILESDIR}"/${PN}-3.7.0-non-exec-stack.patch

	# Fix the regex to get gcc's version
	epatch "${FILESDIR}"/${PN}-3.7.0-fix-gcc-regex.patch

	# Regenerate autotools files
	eautoreconf
}

src_configure() {
	local myconf

	# -fomit-frame-pointer	"Assembler messages: Error: junk `8' after expression"
	#                       while compiling insn_sse.c in none/tests/x86
	# -fpie                 valgrind seemingly hangs when built with pie on
	#                       amd64 (bug #102157)
	# -fstack-protector     more undefined references to __guard and __stack_smash_handler
	#                       because valgrind doesn't link to glibc (bug #114347)
	# -ggdb3                segmentation fault on startup
	filter-flags -fomit-frame-pointer
	filter-flags -fpie
	filter-flags -fstack-protector
	replace-flags -ggdb3 -ggdb2

	if use amd64 || use ppc64; then
		! has_multilib_profile && myconf="${myconf} --enable-only64bit"
	fi

	# Don't use mpicc unless the user asked for it (bug #258832)
	if ! use mpi; then
		myconf="${myconf} --without-mpicc"
	fi

	econf ${myconf}
}

src_install() {
	emake DESTDIR="${D}" install
	dodoc AUTHORS FAQ.txt NEWS README*

	pax-mark m "${D}"/usr/$(get_libdir)/valgrind/*-*-linux
}

pkg_postinst() {
	ewarn "Valgrind will not work if glibc does not have debug symbols."
	ewarn "To fix this you can add splitdebug to FEATURES in make.conf"
	ewarn "and remerge glibc.  See:"
	ewarn "https://bugs.gentoo.org/show_bug.cgi?id=214065"
	ewarn "https://bugs.gentoo.org/show_bug.cgi?id=274771"
	ewarn "https://bugs.gentoo.org/show_bug.cgi?id=388703"
}