[gentoo-commits] gentoo-x86 commit in gnome-extra/libgda: libgda-4.2.11.ebuild metadata.xml ChangeLog libgda-5.0.1.ebuild

public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed

* [gentoo-commits] gentoo-x86 commit in gnome-extra/libgda: libgda-4.2.11.ebuild metadata.xml ChangeLog libgda-5.0.1.ebuild
@ 2011-11-16 18:38 Alexandre Rostovtsev (tetromino)
  0 siblings, 0 replies; only message in thread
From: Alexandre Rostovtsev (tetromino) @ 2011-11-16 18:38 UTC (permalink / raw
  To: gentoo-commits

tetromino    11/11/16 18:38:49

  Modified:             metadata.xml ChangeLog
  Added:                libgda-4.2.11.ebuild libgda-5.0.1.ebuild
  Log:
  Version bump for both slots; fixes several bugs, including building with USE=doc (bug #388501). Enable mdb support for 4.2.11. Enable vala bindings for 5.0.1 (they build now). Enable tests for 5.0.1 (the test suite now passes when running from portage).
  
  (Portage version: 2.2.0_alpha74/cvs/Linux x86_64)

Revision  Changes    Path
1.8                  gnome-extra/libgda/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/libgda/metadata.xml?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/libgda/metadata.xml?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/libgda/metadata.xml?r1=1.7&r2=1.8

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/libgda/metadata.xml,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- metadata.xml	30 Sep 2011 19:27:46 -0000	1.7
+++ metadata.xml	16 Nov 2011 18:38:49 -0000	1.8
@@ -3,13 +3,14 @@
 <pkgmetadata>
 <herd>gnome</herd>
 <use>
-	<flag name="canvas">Enables support for <pkg>x11-libs/goocanvas</pkg></flag>
+	<flag name="canvas">Enable support for <pkg>x11-libs/goocanvas</pkg></flag>
 	<flag name="http">Enable embedded <pkg>net-libs/libsoup</pkg> based server</flag>
 	<flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg> for
 		introspection</flag>
 	<flag name="json">Enable support for JSON format</flag>
-	<flag name="mdb">Enable support for Microsoft Access Database using 
+	<flag name="mdb">Enable support for Microsoft Access database using 
 		<pkg>app-office/mdbtools</pkg></flag>
 	<flag name="sourceview">Enable support for <pkg>x11-libs/gtksourceview</pkg></flag>
+	<flag name="vala">Enable bindings for <pkg>dev-lang/vala</pkg></flag>
 </use>
 </pkgmetadata>



1.186                gnome-extra/libgda/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/libgda/ChangeLog?rev=1.186&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/libgda/ChangeLog?rev=1.186&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/libgda/ChangeLog?r1=1.185&r2=1.186

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/libgda/ChangeLog,v
retrieving revision 1.185
retrieving revision 1.186
diff -u -r1.185 -r1.186
--- ChangeLog	1 Nov 2011 11:29:34 -0000	1.185
+++ ChangeLog	16 Nov 2011 18:38:49 -0000	1.186
@@ -1,6 +1,16 @@
 # ChangeLog for gnome-extra/libgda
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/libgda/ChangeLog,v 1.185 2011/11/01 11:29:34 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/libgda/ChangeLog,v 1.186 2011/11/16 18:38:49 tetromino Exp $
+
+*libgda-5.0.1 (16 Nov 2011)
+*libgda-4.2.11 (16 Nov 2011)
+
+  16 Nov 2011; Alexandre Rostovtsev <tetromino@gentoo.org>
+  +libgda-4.2.11.ebuild, +libgda-5.0.1.ebuild, metadata.xml:
+  Version bump for both slots; fixes several bugs, including building with
+  USE=doc (bug #388501). Enable mdb support for 4.2.11. Enable vala bindings
+  for 5.0.1 (they build now). Enable tests for 5.0.1 (the test suite now passes
+  when running from portage).
 
 *libgda-4.2.10 (01 Nov 2011)
 



1.1                  gnome-extra/libgda/libgda-4.2.11.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/libgda/libgda-4.2.11.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/libgda/libgda-4.2.11.ebuild?rev=1.1&content-type=text/plain

Index: libgda-4.2.11.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/libgda/libgda-4.2.11.ebuild,v 1.1 2011/11/16 18:38:49 tetromino Exp $

EAPI="4"
GCONF_DEBUG="yes"
GNOME2_LA_PUNT="yes"

inherit db-use eutils flag-o-matic gnome2 java-pkg-opt-2

DESCRIPTION="Gnome Database Access Library"
HOMEPAGE="http://www.gnome-db.org/"
LICENSE="GPL-2 LGPL-2"

IUSE="berkdb bindist canvas doc firebird gnome-keyring gtk graphviz http +introspection json ldap mdb mysql oci8 postgres sourceview ssl"

SLOT="4"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"

RDEPEND="
	app-text/iso-codes
	>=dev-libs/glib-2.16:2
	>=dev-libs/libxml2-2:2
	dev-libs/libxslt
	dev-libs/libunique:1
	sys-libs/readline
	sys-libs/ncurses
	>=dev-db/sqlite-3.6.22:3
	berkdb?	( sys-libs/db )
	!bindist? ( firebird? ( dev-db/firebird ) )
	gtk? (
		|| ( >=x11-libs/gtk+-2.12:2 x11-libs/gdk-pixbuf:2 )
		canvas? ( x11-libs/goocanvas:0 )
		sourceview? ( x11-libs/gtksourceview:2.0 )
		graphviz? ( media-gfx/graphviz )
	)
	gnome-keyring? ( gnome-base/libgnome-keyring )
	http?	( >=net-libs/libsoup-2.24:2.4 )
	introspection? ( >=dev-libs/gobject-introspection-0.6.5 )
	json?	( dev-libs/json-glib )
	ldap?	( net-nds/openldap )
	mdb?	( >app-office/mdbtools-0.5 )
	mysql?	( virtual/mysql )
	postgres? ( dev-db/postgresql-base )
	ssl?	( dev-libs/openssl )"

DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.18
	>=dev-util/intltool-0.35.5
	>=app-text/gnome-doc-utils-0.9
	>=dev-util/gtk-doc-am-1
	doc? ( >=dev-util/gtk-doc-1 )"

# Tests are not really good
RESTRICT="test"

pkg_setup() {
	DOCS="AUTHORS ChangeLog NEWS README"

	if use canvas || use graphviz || use sourceview; then
		if ! use gtk; then
			ewarn "You must enable USE=gtk to make use of canvas, graphivz or sourceview USE flag."
			ewarn "Disabling for now."
			G2CONF="${G2CONF} --without-goocanvas --without-graphivz --without-gtksourceview"
		else
			G2CONF="${G2CONF}
				$(use_with canvas goocanvas)
				$(use_with graphviz)
				$(use_with sourceview gtksourceview)"
		fi
	fi

	# Disable vala bindings, they collide with dev-lang/vala's libgda-4.0.vapi
	G2CONF="${G2CONF}
		--with-unique
		--disable-scrollkeeper
		--disable-static
		--enable-system-sqlite
		--disable-vala
		$(use_with berkdb bdb /usr)
		$(use_with gnome-keyring)
		$(use_with gtk ui)
		$(use_with http libsoup)
		$(use_enable introspection)
		$(use_enable introspection gda-gi)
		$(use_enable introspection gdaui-gi)
		$(use_with java java $JAVA_HOME)
		$(use_enable json)
		$(use_with ldap)
		$(use_with mdb mdb /usr)
		$(use_with mysql mysql /usr)
		$(use_with postgres postgres /usr)
		$(use_enable ssl crypto)"

	if use bindist; then
		# firebird license is not GPL compatible
		G2CONF="${G2CONF} --without-firebird"
	else
		G2CONF="${G2CONF} $(use_with firebird firebird /usr)"
	fi

	use berkdb && append-cppflags "-I$(db_includedir)"
	use oci8 || G2CONF="${G2CONF} --without-oracle"

	# Not in portage
	G2CONF="${G2CONF}
		--disable-default-binary"

	export XDG_DATA_HOME="${T}/.local"
}

src_prepare() {
	gnome2_src_prepare

	# Fix compilation failure of keyword_hash.c, upstream #630959
	epatch "${FILESDIR}/${PN}-4.2.0-missing-include-in-keyword_hash-generator.patch"
}



1.1                  gnome-extra/libgda/libgda-5.0.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/libgda/libgda-5.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/libgda/libgda-5.0.1.ebuild?rev=1.1&content-type=text/plain

Index: libgda-5.0.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/libgda/libgda-5.0.1.ebuild,v 1.1 2011/11/16 18:38:49 tetromino Exp $

EAPI="4"
GNOME2_LA_PUNT="yes"
GCONF_DEBUG="yes"
PYTHON_DEPEND="2"

inherit autotools db-use eutils flag-o-matic gnome2 java-pkg-opt-2 python

DESCRIPTION="Gnome Database Access Library"
HOMEPAGE="http://www.gnome-db.org/"
LICENSE="GPL-2 LGPL-2"

IUSE="berkdb bindist canvas doc firebird gnome-keyring gtk graphviz http +introspection json ldap mdb mysql oci8 postgres sourceview ssl vala"
SLOT="5"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"

# FIXME: sqlite is automagic, but maybe it is a hard-dep
# FIXME: autoconf is a hell of inconsistencies
RDEPEND="
	app-text/iso-codes
	>=dev-libs/glib-2.16:2
	>=dev-libs/libxml2-2
	dev-libs/libxslt
	sys-libs/readline
	sys-libs/ncurses
	berkdb?   ( sys-libs/db )
	!bindist? ( firebird? ( dev-db/firebird ) )
	gtk? (
		>=x11-libs/gtk+-3.0.0:3
		canvas? ( x11-libs/goocanvas:2.0 )
		sourceview? ( x11-libs/gtksourceview:3.0 )
		graphviz? ( media-gfx/graphviz )
	)
	gnome-keyring? ( || ( gnome-base/libgnome-keyring <gnome-base/gnome-keyring-2.29.4 ) )
	http? ( >=net-libs/libsoup-2.24:2.4 )
	introspection? ( >=dev-libs/gobject-introspection-0.6.5 )
	json?     ( dev-libs/json-glib )
	ldap?     ( net-nds/openldap )
	mdb?      ( >app-office/mdbtools-0.5 )
	mysql?    ( virtual/mysql )
	postgres? ( dev-db/postgresql-base )
	ssl?      ( dev-libs/openssl )
	>=dev-db/sqlite-3.6.22:3"

DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.18
	>=dev-util/intltool-0.35.5
	>=app-text/gnome-doc-utils-0.9
	doc? ( >=dev-util/gtk-doc-1 )
	vala? ( >=dev-lang/vala-0.14:0.14[vapigen] )"

pkg_setup() {
	DOCS="AUTHORS ChangeLog NEWS README"

	if use canvas || use graphviz || use sourceview; then
		if ! use gtk; then
			ewarn "You must enable USE=gtk to make use of canvas, graphivz or sourceview USE flag."
			ewarn "Disabling for now."
			G2CONF="${G2CONF} --without-goocanvas --without-graphivz --without-gtksourceview"
		else
			G2CONF="${G2CONF}
				$(use_with canvas goocanvas)
				$(use_with graphviz)
				$(use_with sourceview gtksourceview)"
		fi
	fi

	G2CONF="${G2CONF}
		--disable-scrollkeeper
		--disable-static
		--enable-system-sqlite
		$(use_with berkdb bdb /usr)
		$(use_with gnome-keyring)
		$(use_with gtk ui)
		$(use_with http libsoup)
		$(use_enable introspection)
		$(use_with java java $JAVA_HOME)
		$(use_enable json)
		$(use_with ldap)
		$(use_with mdb mdb /usr)
		$(use_with mysql mysql /usr)
		$(use_with postgres postgres /usr)
		$(use_enable ssl crypto)
		$(use_enable vala)"

	if use bindist; then
		# firebird license is not GPL compatible
		G2CONF="${G2CONF} --without-firebird"
	else
		G2CONF="${G2CONF} $(use_with firebird firebird /usr)"
	fi

	use berkdb && append-cppflags "-I$(db_includedir)"
	use oci8 || G2CONF="${G2CONF} --without-oracle"

	# Not in portage
	G2CONF="${G2CONF}
		--disable-default-binary"

	export XDG_DATA_HOME="${T}/.local"

	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	# Fix compilation failure of keyword_hash.c, upstream #630959
	#epatch "${FILESDIR}/${PN}-4.2.0-missing-include-in-keyword_hash-generator.patch"

	# Disable broken tests so we can check the others
	epatch "${FILESDIR}/${PN}-4.99.4-disable-broken-tests.patch"

	# Prevent file collisions with libgda:4
	epatch "${FILESDIR}/${PN}-4.99.1-gda-browser-help-collision.patch"
	epatch "${FILESDIR}/${PN}-4.99.1-gda-browser-doc-collision.patch"
	epatch "${FILESDIR}/${PN}-4.99.1-control-center-icon-collision.patch"
	# Move files with mv (since epatch can't handle rename diffs) and
	# update pre-generated gtk-doc files
	local f
	for f in tools/browser/doc/gda-browser* ; do
		mv ${f} ${f/gda-browser/gda-browser-5.0} || die "mv ${f} failed"
	done
	for f in tools/browser/doc/html/gda-browser.devhelp* ; do
		sed -e 's:name="gda-browser":name="gda-browser-5.0":' \
			-i ${f} || die "sed ${f} failed"
		mv ${f} ${f/gda-browser/gda-browser-5.0} || die "mv ${f} failed"
	done
	for f in control-center/data/*_gda-control-center.png ; do
		mv ${f} ${f/_gda-control-center.png/_gda-control-center-5.0.png} ||
			die "mv ${f} failed"
	done

	python_convert_shebangs -r 2 libgda-report/RML/trml2{html,pdf}

	# Fix valac version
	sed -e 's:"$VALA_BINDIR/valac":"$VALA_BINDIR/valac-0.14":' \
		-i configure.ac || die "sed failed"

	eautoreconf
	gnome2_src_prepare
}

pkg_postinst() {
	gnome2_pkg_postinst
	local d
	for d in /usr/share/libgda-5.0/gda_trml2{html,pdf} ; do
		python_mod_optimize ${d}
	done
}

pkg_postrm() {
	gnome2_pkg_postrm
	local d
	for d in /usr/share/libgda-5.0/gda_trml2{html,pdf} ; do
		python_mod_cleanup ${d}
	done
}






^ permalink raw reply	[flat|nested] only message in thread

only message in thread, other threads:[~2011-11-16 18:39 UTC | newest]

Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-11-16 18:38 [gentoo-commits] gentoo-x86 commit in gnome-extra/libgda: libgda-4.2.11.ebuild metadata.xml ChangeLog libgda-5.0.1.ebuild Alexandre Rostovtsev (tetromino)

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox