[gentoo-commits] gentoo-x86 commit in dev-libs/gmp: ChangeLog gmp-5.0.2_p1.ebuild

["Mike Frysinger (vapier)" <vapier@gentoo.org>]

vapier      11/08/25 19:33:46

  Modified:             ChangeLog
  Added:                gmp-5.0.2_p1.ebuild
  Log:
  Add fix from upstream, add USE=static-libs support #378233 by Agostino Sarubbo, restore USE=doc support, and trim .la files as needed.
  
  (Portage version: 2.2.0_alpha51/cvs/Linux x86_64)

Revision  Changes    Path
1.143                dev-libs/gmp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gmp/ChangeLog?rev=1.143&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gmp/ChangeLog?rev=1.143&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gmp/ChangeLog?r1=1.142&r2=1.143

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/gmp/ChangeLog,v
retrieving revision 1.142
retrieving revision 1.143
diff -u -r1.142 -r1.143
--- ChangeLog	5 Aug 2011 15:27:23 -0000	1.142
+++ ChangeLog	25 Aug 2011 19:33:46 -0000	1.143
@@ -1,6 +1,13 @@
 # ChangeLog for dev-libs/gmp
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/gmp/ChangeLog,v 1.142 2011/08/05 15:27:23 darkside Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/gmp/ChangeLog,v 1.143 2011/08/25 19:33:46 vapier Exp $
+
+*gmp-5.0.2_p1 (25 Aug 2011)
+
+  25 Aug 2011; Mike Frysinger <vapier@gentoo.org> +gmp-5.0.2_p1.ebuild,
+  +files/gmp-5.0.2-unnormalised-dividends.patch:
+  Add fix from upstream, add USE=static-libs support #378233 by Agostino
+  Sarubbo, restore USE=doc support, and trim .la files as needed.
 
   05 Aug 2011; Jeremy Olexa <darkside@gentoo.org> gmp-4.3.2.ebuild,
   gmp-5.0.1.ebuild, gmp-5.0.2.ebuild:



1.1                  dev-libs/gmp/gmp-5.0.2_p1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gmp/gmp-5.0.2_p1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gmp/gmp-5.0.2_p1.ebuild?rev=1.1&content-type=text/plain

Index: gmp-5.0.2_p1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/gmp/gmp-5.0.2_p1.ebuild,v 1.1 2011/08/25 19:33:46 vapier Exp $

inherit flag-o-matic eutils libtool flag-o-matic toolchain-funcs

MY_PV=${PV/_p*}
MY_P=${PN}-${MY_PV}
PLEVEL=${PV/*p}
DESCRIPTION="Library for arithmetic on arbitrary precision integers, rational numbers, and floating-point numbers"
HOMEPAGE="http://gmplib.org/"
SRC_URI="mirror://gnu/${PN}/${MY_P}.tar.bz2
	doc? ( http://gmplib.org/${PN}-man-${MY_PV}.pdf )"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
IUSE="doc nocxx static-libs"

DEPEND="sys-devel/m4"
RDEPEND=""

S=${WORKDIR}/${MY_P}

src_unpack() {
	unpack ${MY_P}.tar.bz2
	cd "${S}"
	[[ -d ${FILESDIR}/${PV} ]] && EPATCH_SUFFIX="diff" EPATCH_FORCE="yes" epatch "${FILESDIR}"/${PV}
	epatch "${FILESDIR}"/${PN}-4.1.4-noexecstack.patch
	epatch "${FILESDIR}"/${PN}-5.0.0-s390.diff
	epatch "${FILESDIR}"/${MY_P}-unnormalised-dividends.patch

	# disable -fPIE -pie in the tests for x86  #236054
	if use x86 && gcc-specs-pie ; then
		epatch "${FILESDIR}"/${PN}-5.0.1-x86-nopie-tests.patch
	fi

	# note: we cannot run autotools here as gcc depends on this package
	elibtoolize

	# GMP uses the "ABI" env var during configure as does Gentoo (econf).
	# So, to avoid patching the source constantly, wrap things up.
	mv configure configure.wrapped || die
	cat <<-\EOF > configure
	#!/bin/sh
	exec env ABI="$GMPABI" "${0}.wrapped" "$@"
	EOF
	chmod a+rx configure
}

src_compile() {
	# Because of our 32-bit userland, 1.0 is the only HPPA ABI that works
	# http://gmplib.org/manual/ABI-and-ISA.html#ABI-and-ISA (bug #344613)
	if [[ ${CHOST} == hppa2.0-* ]] ; then
		export GMPABI="1.0"
	fi

	# ABI mappings (needs all architectures supported)
	case ${ABI} in
		32|x86)       GMPABI=32;;
		64|amd64|n64) GMPABI=64;;
		o32|n32)      GMPABI=${ABI};;
	esac
	export GMPABI

	tc-export CC
	econf \
		--localstatedir=/var/state/gmp \
		--disable-mpbsd \
		$(use_enable !nocxx cxx) \
		$(use_enable static-libs static) \
		|| die

	emake || die
}

src_install() {
	emake DESTDIR="${D}" install || die

	# should be a standalone lib
	rm -f "${D}"/usr/$(get_libdir)/libgmp.la
	# this requires libgmp
	use static-libs || rm -f "${D}"/usr/$(get_libdir)/libgmpxx.la

	dodoc AUTHORS ChangeLog NEWS README
	dodoc doc/configuration doc/isa_abi_headache
	dohtml -r doc

	use doc && cp "${DISTDIR}"/gmp-man-${MY_PV}.pdf "${D}"/usr/share/doc/${PF}/
}

pkg_preinst() {
	preserve_old_lib /usr/$(get_libdir)/libgmp.so.3
}

pkg_postinst() {
	preserve_old_lib_notify /usr/$(get_libdir)/libgmp.so.3
}