* [gentoo-commits] gentoo-x86 commit in x11-misc/slim: slim-1.3.2-r5.ebuild ChangeLog slim-1.3.2-r4.ebuild
@ 2011-08-19 19:55 Jeremy Olexa (darkside)
0 siblings, 0 replies; only message in thread
From: Jeremy Olexa (darkside) @ 2011-08-19 19:55 UTC (permalink / raw
To: gentoo-commits
darkside 11/08/19 19:55:10
Modified: ChangeLog
Added: slim-1.3.2-r5.ebuild
Removed: slim-1.3.2-r4.ebuild
Log:
revbump for consolekit fixes by Ian Stakenvicius
(Portage version: 2.1.10.3/cvs/Linux i686)
Revision Changes Path
1.69 x11-misc/slim/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/slim/ChangeLog?rev=1.69&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/slim/ChangeLog?rev=1.69&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/slim/ChangeLog?r1=1.68&r2=1.69
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/slim/ChangeLog,v
retrieving revision 1.68
retrieving revision 1.69
diff -u -r1.68 -r1.69
--- ChangeLog 16 Aug 2011 02:18:37 -0000 1.68
+++ ChangeLog 19 Aug 2011 19:55:10 -0000 1.69
@@ -1,6 +1,12 @@
# ChangeLog for x11-misc/slim
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/slim/ChangeLog,v 1.68 2011/08/16 02:18:37 darkside Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/slim/ChangeLog,v 1.69 2011/08/19 19:55:10 darkside Exp $
+
+*slim-1.3.2-r5 (19 Aug 2011)
+
+ 19 Aug 2011; Jeremy Olexa <darkside@gentoo.org> -slim-1.3.2-r4.ebuild,
+ +slim-1.3.2-r5.ebuild, files/Xsession-r2:
+ revbump for consolekit fixes by Ian Stakenvicius
*slim-1.3.2-r4 (16 Aug 2011)
1.1 x11-misc/slim/slim-1.3.2-r5.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/slim/slim-1.3.2-r5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/slim/slim-1.3.2-r5.ebuild?rev=1.1&content-type=text/plain
Index: slim-1.3.2-r5.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/slim/slim-1.3.2-r5.ebuild,v 1.1 2011/08/19 19:55:10 darkside Exp $
EAPI=2
inherit toolchain-funcs pam eutils
DESCRIPTION="Simple Login Manager"
HOMEPAGE="http://slim.berlios.de"
SRC_URI="mirror://berlios/${PN}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="branding pam"
RDEPEND="x11-libs/libXmu
x11-libs/libX11
x11-libs/libXpm
x11-libs/libXft
>=media-libs/libpng-1.4
virtual/jpeg
x11-apps/sessreg
pam? ( virtual/pam )"
DEPEND="${RDEPEND}
dev-util/pkgconfig
x11-proto/xproto"
PDEPEND="branding? ( >=x11-themes/slim-themes-1.2.3a-r3 )"
src_prepare() {
# respect C[XX]FLAGS, fix crosscompile,
# fix linking order for --as-needed"
sed -i -e "s:^CXX=.*:CXX=$(tc-getCXX) ${CXXFLAGS}:" \
-e "s:^CC=.*:CC=$(tc-getCC) ${CFLAGS}:" \
-e "s:^MANDIR=.*:MANDIR=/usr/share/man:" \
-e "s:^\t\(.*\)\ \$(LDFLAGS)\ \(.*\):\t\1\ \2\ \$(LDFLAGS):g" \
-e "s:-I/usr/include/libpng12:$(pkg-config --cflags-only-I libpng):" \
-e "s:-lpng12:$(pkg-config --libs-only-l libpng):" \
-r -e "s:^LDFLAGS=(.*):LDFLAGS=\1 ${LDFLAGS}:" \
Makefile || die "sed failed in Makefile"
# Our Gentoo-specific config changes
epatch "${FILESDIR}"/${PN}-1.3.2-r2-config.diff
if use elibc_FreeBSD; then
sed -i -e "s/CUSTOM=-DHAVE_SHADOW/CUSTOM=-DNEEDS_BASENAME/" Makefile \
|| die "sed failed in Makefile"
epatch "${FILESDIR}"/${PN}-1.3.2-bsd-install.patch
fi
if use branding; then
sed -i -e 's/ default/ slim-gentoo-simple/' slim.conf || die
fi
# Gentoo bug 297655
epatch "${FILESDIR}"/14509-fix-keyboard-in-tty-from-which-${PN}-is-lauched.patch
# Upstream bug #15287
epatch "${FILESDIR}"/15287-fix-pam-authentication-with-pam_unix2.patch
# Gentoo Bug 261713
epatch "${FILESDIR}"/261713-restart-xserver-if-killed.patch
# Gentoo bug 261359, upstream 15326
epatch "${FILESDIR}"/261359-fix-SIGTERM-freeze.patch
# Gentoo bug 346037
epatch "${FILESDIR}"/346037-stop_setting_host_for_pam_ck_connector_so.patch
# Gentoo bug 378505
epatch "${FILESDIR}"/${P}-libpng15.patch
}
src_compile() {
if use pam ; then
emake USE_PAM=1 || die "emake failed."
else
emake || die "emake failed."
fi
}
src_install() {
if use pam ; then
emake USE_PAM=1 DESTDIR="${D}" install || die "emake install failed."
pamd_mimic system-local-login slim auth account session
else
emake DESTDIR="${D}" install || die "emake install failed."
fi
insinto /usr/share/slim
newins "${FILESDIR}/Xsession-r2" Xsession || die "newins failed"
insinto /etc/logrotate.d
newins "${FILESDIR}/slim.logrotate" slim || die "newins failed"
dodoc xinitrc.sample ChangeLog README TODO THEMES
}
pkg_postinst() {
elog
elog "The configuration file is located at /etc/slim.conf."
elog
elog "If you wish ${PN} to start automatically, set DISPLAYMANAGER=\"${PN}\" "
elog "in /etc/conf.d/xdm and run \"rc-update add xdm default\"."
elog
elog "By default, ${PN} now does proper X session selection, including ~/.xsession"
elog "support, as well as selection between sessions available in"
elog "/etc/X11/Sessions/ at login by pressing [F1]."
elog
elog "The XSESSION environment variable is still supported as a default"
elog "if no session has been specified by the user."
elog
elog "If you want to use .xinitrc in the user's home directory for session"
elog "management instead, see README and xinitrc.sample in"
elog "/usr/share/doc/${PF} and change your login_cmd in /etc/slim.conf"
elog "accordingly."
elog
ewarn "Please note that the slim session start script now supports consolekit"
ewarn "directly, via xinitrc.d scripts. Please remove any existing work-arounds to"
ewarn "avoid multiple calls to ck-launch-session."
if has_version "<=sys-auth/pambase-20101024[consolekit]" ; then
ewarn
ewarn "You should also remove the 'nox11' flag from the pam_ck_connector.so module "
ewarn "in /etc/pam.d/system-login if you have not already done so."
ewarn "(this is safe, it will be default in the next version of pambase)"
fi
elog
if ! use pam; then
elog "You have merged ${PN} without USE=pam, this will cause ${PN} to fall back to"
elog "the console when restarting your window manager. If this is not"
elog "desired, then please remerge ${PN} with USE=pam"
elog
fi
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-08-19 19:55 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-08-19 19:55 [gentoo-commits] gentoo-x86 commit in x11-misc/slim: slim-1.3.2-r5.ebuild ChangeLog slim-1.3.2-r4.ebuild Jeremy Olexa (darkside)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox