[gentoo-commits] gentoo-x86 commit in gnome-extra/gnome-power-manager: gnome-power-manager-3.0.2-r1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in gnome-extra/gnome-power-manager: gnome-power-manager-3.0.2-r1.ebuild ChangeLog

[Nirbheek Chauhan (nirbheek)]

nirbheek    11/08/19 10:49:13

  Modified:             ChangeLog
  Added:                gnome-power-manager-3.0.2-r1.ebuild
  Log:
  Bump to 3.0.2, from gnome overlay for GNOME 3
  
  (Portage version: 2.2.0_alpha51/cvs/Linux x86_64)

Revision  Changes    Path
1.159                gnome-extra/gnome-power-manager/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog?rev=1.159&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog?rev=1.159&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog?r1=1.158&r2=1.159

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog,v
retrieving revision 1.158
retrieving revision 1.159
diff -u -r1.158 -r1.159
--- ChangeLog	13 Aug 2011 17:35:01 -0000	1.158
+++ ChangeLog	19 Aug 2011 10:49:13 -0000	1.159
@@ -1,6 +1,14 @@
 # ChangeLog for gnome-extra/gnome-power-manager
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog,v 1.158 2011/08/13 17:35:01 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog,v 1.159 2011/08/19 10:49:13 nirbheek Exp $
+
+*gnome-power-manager-3.0.2-r1 (19 Aug 2011)
+
+  19 Aug 2011; Nirbheek Chauhan <nirbheek@gentoo.org>
+  +gnome-power-manager-3.0.2-r1.ebuild,
+  +files/gnome-power-manager-3.0.2-idle-status.patch,
+  +files/gnome-power-manager-3.0.2-screensaver.patch:
+  Bump to 3.0.2, from gnome overlay for GNOME 3
 
   13 Aug 2011; Raúl Porcel <armin76@gentoo.org>
   gnome-power-manager-2.32.0-r1.ebuild:



1.1                  gnome-extra/gnome-power-manager/gnome-power-manager-3.0.2-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-power-manager/gnome-power-manager-3.0.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-power-manager/gnome-power-manager-3.0.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: gnome-power-manager-3.0.2-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-power-manager/gnome-power-manager-3.0.2-r1.ebuild,v 1.1 2011/08/19 10:49:13 nirbheek Exp $

EAPI="4"
GCONF_DEBUG="no"
GNOME_TARBALL_SUFFIX="bz2"

inherit eutils gnome2 virtualx

DESCRIPTION="Gnome Power Manager"
HOMEPAGE="http://www.gnome.org/projects/gnome-power-manager/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="doc test"

# FIXME: Interactive testsuite (upstream ? I'm so...pessimistic)
RESTRICT="test"

# Latest libcanberra is needed due to gtk+:3 API changes
COMMON_DEPEND=">=dev-libs/glib-2.25.9
	>=x11-libs/gtk+-2.91.7:3
	>=gnome-base/gnome-keyring-0.6.0
	>=x11-libs/libnotify-0.7.0
	>=x11-libs/cairo-1.0.0
	>=gnome-base/gconf-2.31.1:2
	>=media-libs/libcanberra-0.26-r2[gtk3]
	>=sys-power/upower-0.9.1
	>=x11-apps/xrandr-1.3
	>=x11-proto/xproto-7.0.15
	x11-libs/libX11
	x11-libs/libXext"
RDEPEND="${COMMON_DEPEND}
	>=sys-auth/consolekit-0.4[policykit]
	sys-auth/polkit
	gnome-extra/polkit-gnome"
DEPEND="${COMMON_DEPEND}
	x11-proto/randrproto

	sys-devel/gettext
	app-text/scrollkeeper
	app-text/docbook-xml-dtd:4.3
	>=dev-util/pkgconfig-0.9
	>=dev-util/intltool-0.35
	>=app-text/gnome-doc-utils-0.3.2
	doc? (
		app-text/xmlto
		app-text/docbook-sgml-utils
		app-text/docbook-xml-dtd:4.4
		app-text/docbook-sgml-dtd:4.1
		app-text/docbook-xml-dtd:4.1.2 )
	test? ( sys-apps/dbus )"

# docbook-sgml-utils and docbook-sgml-dtd-4.1 used for creating man pages
# (files under ${S}/man).
# docbook-xml-dtd-4.4 and -4.1.2 are used by the xml files under ${S}/docs.

pkg_setup() {
	G2CONF="${G2CONF}
		$(use_enable test tests)
		$(use_enable doc docbook-docs)
		--disable-strict
		--enable-compile-warnings=minimum
		--disable-schemas-compile"
	DOCS="AUTHORS ChangeLog NEWS README TODO"

	if ! use doc; then
		G2CONF="${G2CONF} DOCBOOK2MAN=$(type -p false)"
	fi
}

src_prepare() {
	gnome2_src_prepare

	# https://bugzilla.redhat.com/show_bug.cgi?id=679083
	# will be in next release
	epatch "${FILESDIR}/${P}-idle-status.patch"

	# https://bugzilla.gnome.org/show_bug.cgi?id=650464
	# will be in next release
	epatch "${FILESDIR}/${P}-screensaver.patch"

	# Drop debugger CFLAGS from configure
	# XXX: touch configure.ac only if running eautoreconf, otherwise
	# maintainer mode gets triggered -- even if the order is correct
	sed -e 's:^CPPFLAGS="$CPPFLAGS -g"$::g' \
		-i configure || die "debugger sed failed"
}

src_test() {
	unset DBUS_SESSION_BUS_ADDRESS
	Xemake check || die "Test phase failed"
}