[gentoo-commits] gentoo-x86 commit in dev-python/pymongo: ChangeLog pymongo-2.0.1.ebuild pymongo-1.10.1.ebuild pymongo-1.11.ebuild

[gentoo-commits] gentoo-x86 commit in dev-python/pymongo: ChangeLog pymongo-2.0.1.ebuild pymongo-1.10.1.ebuild pymongo-1.11.ebuild

[Alexys Jacob (ultrabug)]

ultrabug    11/08/19 09:39:34

  Modified:             ChangeLog
  Added:                pymongo-2.0.1.ebuild
  Removed:              pymongo-1.10.1.ebuild pymongo-1.11.ebuild
  Log:
  Version bump, drop old
  
  (Portage version: 2.1.10.9/cvs/Linux x86_64)

Revision  Changes    Path
1.7                  dev-python/pymongo/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pymongo/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pymongo/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pymongo/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/pymongo/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	8 Aug 2011 18:24:42 -0000	1.6
+++ ChangeLog	19 Aug 2011 09:39:34 -0000	1.7
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/pymongo
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pymongo/ChangeLog,v 1.6 2011/08/08 18:24:42 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pymongo/ChangeLog,v 1.7 2011/08/19 09:39:34 ultrabug Exp $
+
+*pymongo-2.0.1 (19 Aug 2011)
+
+  19 Aug 2011; Ultrabug <ultrabug@gentoo.org> -pymongo-1.10.1.ebuild,
+  -pymongo-1.11.ebuild, +pymongo-2.0.1.ebuild:
+  Version bump, drop old.
 
   08 Aug 2011; Markos Chandras <hwoarang@gentoo.org> pymongo-1.11-r1.ebuild:
   Ignore test failures with Jython. Update HOMEPAGE. Fix dependencies. Set



1.1                  dev-python/pymongo/pymongo-2.0.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pymongo/pymongo-2.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pymongo/pymongo-2.0.1.ebuild?rev=1.1&content-type=text/plain

Index: pymongo-2.0.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/pymongo/pymongo-2.0.1.ebuild,v 1.1 2011/08/19 09:39:34 ultrabug Exp $

EAPI="3"
PYTHON_DEPEND="2"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.*"
PYTHON_TESTS_FAILURES_TOLERANT_ABIS="*-jython"
DISTUTILS_SRC_TEST="nosetests"

inherit distutils

DESCRIPTION="Python driver for MongoDB"
HOMEPAGE="http://github.com/mongodb/mongo-python-driver http://pypi.python.org/pypi/pymongo"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc mod_wsgi"

RDEPEND="dev-db/mongodb"
DEPEND="${RDEPEND}
	dev-python/setuptools
	doc? ( dev-python/sphinx )"

PYTHON_MODNAME="bson gridfs pymongo"

src_compile() {
	distutils_src_compile

	if use doc; then
		einfo "Generation of documentation"
		mkdir html
		sphinx-build doc html || die "Generation of documentation failed"
	fi
}

distutils_src_test_pre_hook() {
	mkdir -p "${T}/tests-${PYTHON_ABI}/mongo.db"
	mongod --dbpath "${T}/tests-${PYTHON_ABI}/mongo.db" --fork --logpath "${T}/tests-${PYTHON_ABI}/mongo.log"
}

src_test() {
	distutils_src_test
	killall -u "$(id -nu)" mongod
}

src_install() {
	# Maintainer note:
	# In order to work with mod_wsgi, we need to disable the C extension.
	# See [1] for more information.
	# [1] http://api.mongodb.org/python/current/faq.html#does-pymongo-work-with-mod-wsgi
	distutils_src_install $(use mod_wsgi && echo --no_ext)

	if use doc; then
		dohtml -r html/* || die "Error installing docs"
	fi
}