* [gentoo-commits] gentoo-x86 commit in net-mail/cyrus-imapd: cyrus-imapd-2.4.9.ebuild ChangeLog
@ 2011-06-22 10:53 Eray Aslan (eras)
0 siblings, 0 replies; 2+ messages in thread
From: Eray Aslan (eras) @ 2011-06-22 10:53 UTC (permalink / raw
To: gentoo-commits
eras 11/06/22 10:53:39
Modified: ChangeLog
Added: cyrus-imapd-2.4.9.ebuild
Log:
version bump
(Portage version: 2.1.10.3/cvs/Linux x86_64)
Revision Changes Path
1.174 net-mail/cyrus-imapd/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/cyrus-imapd/ChangeLog?rev=1.174&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/cyrus-imapd/ChangeLog?rev=1.174&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/cyrus-imapd/ChangeLog?r1=1.173&r2=1.174
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-mail/cyrus-imapd/ChangeLog,v
retrieving revision 1.173
retrieving revision 1.174
diff -u -r1.173 -r1.174
--- ChangeLog 22 Jun 2011 10:50:31 -0000 1.173
+++ ChangeLog 22 Jun 2011 10:53:39 -0000 1.174
@@ -1,6 +1,11 @@
# ChangeLog for net-mail/cyrus-imapd
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-mail/cyrus-imapd/ChangeLog,v 1.173 2011/06/22 10:50:31 eras Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-mail/cyrus-imapd/ChangeLog,v 1.174 2011/06/22 10:53:39 eras Exp $
+
+*cyrus-imapd-2.4.9 (22 Jun 2011)
+
+ 22 Jun 2011; Eray Aslan <eras@gentoo.org> +cyrus-imapd-2.4.9.ebuild:
+ Version bump
22 Jun 2011; Eray Aslan <eras@gentoo.org>
-files/cyrus-imapd-2.2-libwrap.patch,
1.1 net-mail/cyrus-imapd/cyrus-imapd-2.4.9.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/cyrus-imapd/cyrus-imapd-2.4.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/cyrus-imapd/cyrus-imapd-2.4.9.ebuild?rev=1.1&content-type=text/plain
Index: cyrus-imapd-2.4.9.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-mail/cyrus-imapd/cyrus-imapd-2.4.9.ebuild,v 1.1 2011/06/22 10:53:39 eras Exp $
EAPI=4
inherit db-use eutils ssl-cert pam multilib
MY_P=${P/_/}
DESCRIPTION="The Cyrus IMAP Server."
HOMEPAGE="http://www.cyrusimap.org/"
SRC_URI="ftp://ftp.cyrusimap.org/cyrus-imapd/${MY_P}.tar.gz"
LICENSE="as-is"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="afs berkdb kerberos mysql nntp pam postgres replication +sieve snmp sqlite ssl tcpd"
RDEPEND="sys-libs/zlib
>=dev-libs/cyrus-sasl-2.1.13
afs? ( net-fs/openafs )
berkdb? ( >=sys-libs/db-3.2 )
kerberos? ( virtual/krb5 )
mysql? ( virtual/mysql )
nntp? ( !net-nntp/leafnode )
pam? (
virtual/pam
>=net-mail/mailbase-1
)
postgres? ( dev-db/postgresql-base )
snmp? ( >=net-analyzer/net-snmp-5.2.2-r1 )
sqlite? ( dev-db/sqlite )
ssl? ( >=dev-libs/openssl-0.9.6 )
tcpd? ( >=sys-apps/tcp-wrappers-7.6 snmp? ( net-analyzer/net-snmp[tcpd=] ) )"
DEPEND="$RDEPEND"
# get rid of old style virtual - bug 350792
# all blockers really needed?
RDEPEND="${RDEPEND}
!mail-mta/courier
!net-mail/bincimap
!net-mail/courier-imap
!net-mail/uw-imap"
REQUIRED_USE="afs? ( kerberos )"
S=${WORKDIR}/${MY_P}
pkg_setup() {
enewuser cyrus -1 -1 /usr/cyrus mail
}
src_prepare() {
# Fix master(8)->cyrusmaster(8) manpage.
for i in `grep -rl -e 'master\.8' -e 'master(8)' "${S}"` ; do
sed -i -e 's:master\.8:cyrusmaster.8:g' \
-e 's:master(8):cyrusmaster(8):g' \
"${i}" || die "sed failed" || die "sed failed"
done
mv man/master.8 man/cyrusmaster.8 || die "mv failed"
sed -i -e "s:MASTER:CYRUSMASTER:g" \
-e "s:Master:Cyrusmaster:g" \
-e "s:master:cyrusmaster:g" \
man/cyrusmaster.8 || die "sed failed"
# do not strip
sed -i -e '/(INSTALL/s/-s //' "${S}"/imtest/Makefile.in
# correct afs include and liblwp.a directory
sed -i -e '/I${with_afs_incdir/s/\/include//' \
-e '/liblwp/s/liblwp/afs\/liblwp/' \
"${S}"/configure{,.in}
}
src_configure() {
local myconf
if use mysql ; then
myconf=$(mysql_config --include)
myconf="--with-mysql-incdir=${myconf#-I}"
fi
if use afs ; then
myconf+=" --with-afs-libdir=/usr/$(get_libdir)"
myconf+=" --with-afs-incdir=/usr/include/afs"
fi
if use berkdb ; then
myconf+="--with-bdb-incdir=$(db_includedir)"
fi
econf \
--enable-murder \
--enable-netscapehack \
--enable-idled \
--with-service-path=/usr/$(get_libdir)/cyrus \
--with-cyrus-user=cyrus \
--with-cyrus-group=mail \
--with-com_err=yes \
--with-sasl \
--without-perl \
--without-krb \
--without-krbdes \
--with-zlib \
$(use_enable afs) \
$(use_enable afs krb5afspts) \
$(use_with berkdb bdb) \
$(use_enable nntp) \
$(use_enable replication) \
$(use_enable kerberos gssapi) \
$(use_enable sieve) \
$(use_with mysql) \
$(use_with postgres pgsql) \
$(use_with sqlite) \
$(use_with ssl openssl) \
$(use_with snmp) \
$(use_with tcpd libwrap) \
${myconf}
}
src_install() {
emake DESTDIR="${D}" install
# file collision - bug #368245
if ! use nntp ; then
rm "${D}"/usr/share/man/man8/fetchnews.8*
fi
dodoc README*
dohtml doc/*.html doc/murder.png
docinto text
dodoc doc/text/*
cp doc/cyrusv2.mc "${D}/usr/share/doc/${PF}/html"
cp -r contrib tools "${D}/usr/share/doc/${PF}"
rm -f doc/text/Makefile*
insinto /etc
doins "${FILESDIR}/cyrus.conf" "${FILESDIR}/imapd.conf"
newinitd "${FILESDIR}/cyrus.rc6" cyrus
newconfd "${FILESDIR}/cyrus.confd" cyrus
newpamd "${FILESDIR}/cyrus.pam-include" sieve
for subdir in imap/{,db,log,msg,proc,socket,sieve} spool/imap/{,stage.} ; do
keepdir "/var/${subdir}"
fowners cyrus:mail "/var/${subdir}"
fperms 0750 "/var/${subdir}"
done
for subdir in imap/{user,quota,sieve} spool/imap ; do
for i in a b c d e f g h i j k l m n o p q r s t v u w x y z ; do
keepdir "/var/${subdir}/${i}"
fowners cyrus:mail "/var/${subdir}/${i}"
fperms 0750 "/var/${subdir}/${i}"
done
done
}
pkg_postinst() {
# do not install server.{key,pem) if they exist.
if use ssl ; then
if [ ! -f "${ROOT}"etc/ssl/cyrus/server.key ]; then
install_cert /etc/ssl/cyrus/server
chown cyrus:mail "${ROOT}"etc/ssl/cyrus/server.{key,pem}
fi
fi
elog "For correct logging add the following to /etc/syslog.conf:"
elog " local6.* /var/log/imapd.log"
elog " auth.debug /var/log/auth.log"
echo
elog "You have to add user cyrus to the sasldb2. Do this with:"
elog " saslpasswd2 cyrus"
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in net-mail/cyrus-imapd: cyrus-imapd-2.4.9.ebuild ChangeLog
@ 2011-06-24 15:37 Eray Aslan (eras)
0 siblings, 0 replies; 2+ messages in thread
From: Eray Aslan (eras) @ 2011-06-24 15:37 UTC (permalink / raw
To: gentoo-commits
eras 11/06/24 15:37:40
Modified: cyrus-imapd-2.4.9.ebuild ChangeLog
Log:
ix compiling against openafs - bug #372829 by Andrej Filipcic.
(Portage version: 2.1.10.3/cvs/Linux x86_64)
Revision Changes Path
1.2 net-mail/cyrus-imapd/cyrus-imapd-2.4.9.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/cyrus-imapd/cyrus-imapd-2.4.9.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/cyrus-imapd/cyrus-imapd-2.4.9.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/cyrus-imapd/cyrus-imapd-2.4.9.ebuild?r1=1.1&r2=1.2
Index: cyrus-imapd-2.4.9.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-mail/cyrus-imapd/cyrus-imapd-2.4.9.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- cyrus-imapd-2.4.9.ebuild 22 Jun 2011 10:53:39 -0000 1.1
+++ cyrus-imapd-2.4.9.ebuild 24 Jun 2011 15:37:40 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-mail/cyrus-imapd/cyrus-imapd-2.4.9.ebuild,v 1.1 2011/06/22 10:53:39 eras Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-mail/cyrus-imapd/cyrus-imapd-2.4.9.ebuild,v 1.2 2011/06/24 15:37:40 eras Exp $
EAPI=4
@@ -71,7 +71,13 @@
# correct afs include and liblwp.a directory
sed -i -e '/I${with_afs_incdir/s/\/include//' \
-e '/liblwp/s/liblwp/afs\/liblwp/' \
- "${S}"/configure{,.in}
+ "${S}"/configure{,.in} || die
+ # same with lock.h
+ sed -i -e '/lock.h/s:lock.h:afs/lock.h:' \
+ ptclient/afskrb.c || die
+ # libcom_err.a to libafscom_err.a
+ sed -i -e '/afs\/libcom_err.a/s:libcom_err.a:libafscom_err.a:' \
+ configure{,.in} || die
}
src_configure() {
@@ -85,7 +91,7 @@
myconf+=" --with-afs-incdir=/usr/include/afs"
fi
if use berkdb ; then
- myconf+="--with-bdb-incdir=$(db_includedir)"
+ myconf+=" --with-bdb-incdir=$(db_includedir)"
fi
econf \
--enable-murder \
1.175 net-mail/cyrus-imapd/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/cyrus-imapd/ChangeLog?rev=1.175&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/cyrus-imapd/ChangeLog?rev=1.175&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/cyrus-imapd/ChangeLog?r1=1.174&r2=1.175
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-mail/cyrus-imapd/ChangeLog,v
retrieving revision 1.174
retrieving revision 1.175
diff -u -r1.174 -r1.175
--- ChangeLog 22 Jun 2011 10:53:39 -0000 1.174
+++ ChangeLog 24 Jun 2011 15:37:40 -0000 1.175
@@ -1,6 +1,9 @@
# ChangeLog for net-mail/cyrus-imapd
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-mail/cyrus-imapd/ChangeLog,v 1.174 2011/06/22 10:53:39 eras Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-mail/cyrus-imapd/ChangeLog,v 1.175 2011/06/24 15:37:40 eras Exp $
+
+ 24 Jun 2011; Eray Aslan <eras@gentoo.org> cyrus-imapd-2.4.9.ebuild:
+ Fix compiling against openafs - bug #372829 by Andrej Filipcic.
*cyrus-imapd-2.4.9 (22 Jun 2011)
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2011-06-24 15:37 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-06-24 15:37 [gentoo-commits] gentoo-x86 commit in net-mail/cyrus-imapd: cyrus-imapd-2.4.9.ebuild ChangeLog Eray Aslan (eras)
-- strict thread matches above, loose matches on Subject: below --
2011-06-22 10:53 Eray Aslan (eras)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox