* [gentoo-commits] gentoo-x86 commit in dev-lang/R: R-2.12.1.ebuild R-2.12.2.ebuild ChangeLog R-2.13.0.ebuild R-2.10.1.ebuild
@ 2011-06-23 13:03 Justin Lecher (jlec)
0 siblings, 0 replies; only message in thread
From: Justin Lecher (jlec) @ 2011-06-23 13:03 UTC (permalink / raw
To: gentoo-commits
jlec 11/06/23 13:03:38
Modified: R-2.12.1.ebuild R-2.12.2.ebuild ChangeLog
R-2.10.1.ebuild
Added: R-2.13.0.ebuild
Log:
Version Bump, #372197
(Portage version: 2.2.0_alpha41/cvs/Linux x86_64)
Revision Changes Path
1.4 dev-lang/R/R-2.12.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/R/R-2.12.1.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/R/R-2.12.1.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/R/R-2.12.1.ebuild?r1=1.3&r2=1.4
Index: R-2.12.1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/R/R-2.12.1.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- R-2.12.1.ebuild 22 Jun 2011 18:46:09 -0000 1.3
+++ R-2.12.1.ebuild 23 Jun 2011 13:03:38 -0000 1.4
@@ -1,6 +1,6 @@
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/R/R-2.12.1.ebuild,v 1.3 2011/06/22 18:46:09 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/R/R-2.12.1.ebuild,v 1.4 2011/06/23 13:03:38 jlec Exp $
EAPI=2
@@ -8,14 +8,15 @@
DESCRIPTION="Language and environment for statistical computing and graphics"
HOMEPAGE="http://www.r-project.org/"
-SRC_URI="mirror://cran/src/base/R-2/${P}.tar.gz
+SRC_URI="
+ mirror://cran/src/base/R-2/${P}.tar.gz
bash-completion? ( mirror://gentoo/R.bash_completion.bz2 )"
LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
-IUSE="doc java jpeg lapack minimal nls perl png profile readline static-libs threads tk X cairo"
+IUSE="cairo doc java jpeg lapack minimal nls perl png profile readline static-libs threads tk X"
# common depends
CDEPEND="
@@ -53,6 +54,7 @@
R_DIR=/usr/$(get_libdir)/${PN}
pkg_setup() {
+ fortran-2_pkg_setup
filter-ldflags -Wl,-Bdirect -Bdirect
# avoid using existing R installation
unset R_HOME
1.3 dev-lang/R/R-2.12.2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/R/R-2.12.2.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/R/R-2.12.2.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/R/R-2.12.2.ebuild?r1=1.2&r2=1.3
Index: R-2.12.2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/R/R-2.12.2.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- R-2.12.2.ebuild 22 Jun 2011 18:46:09 -0000 1.2
+++ R-2.12.2.ebuild 23 Jun 2011 13:03:38 -0000 1.3
@@ -1,6 +1,6 @@
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/R/R-2.12.2.ebuild,v 1.2 2011/06/22 18:46:09 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/R/R-2.12.2.ebuild,v 1.3 2011/06/23 13:03:38 jlec Exp $
EAPI=3
@@ -8,14 +8,15 @@
DESCRIPTION="Language and environment for statistical computing and graphics"
HOMEPAGE="http://www.r-project.org/"
-SRC_URI="mirror://cran/src/base/R-2/${P}.tar.gz
+SRC_URI="
+ mirror://cran/src/base/R-2/${P}.tar.gz
bash-completion? ( mirror://gentoo/R.bash_completion.bz2 )"
LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
-IUSE="doc java jpeg lapack minimal nls perl png profile readline static-libs tk X cairo"
+IUSE="cairo doc java jpeg lapack minimal nls perl png profile readline static-libs tk X"
# common depends
CDEPEND="
@@ -53,6 +54,7 @@
R_DIR="${EPREFIX}"/usr/$(get_libdir)/${PN}
pkg_setup() {
+ fortran-2_pkg_setup
filter-ldflags -Wl,-Bdirect -Bdirect
# avoid using existing R installation
unset R_HOME
1.185 dev-lang/R/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/R/ChangeLog?rev=1.185&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/R/ChangeLog?rev=1.185&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/R/ChangeLog?r1=1.184&r2=1.185
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/R/ChangeLog,v
retrieving revision 1.184
retrieving revision 1.185
diff -u -r1.184 -r1.185
--- ChangeLog 22 Jun 2011 18:46:09 -0000 1.184
+++ ChangeLog 23 Jun 2011 13:03:38 -0000 1.185
@@ -1,6 +1,12 @@
# ChangeLog for dev-lang/R
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/R/ChangeLog,v 1.184 2011/06/22 18:46:09 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/R/ChangeLog,v 1.185 2011/06/23 13:03:38 jlec Exp $
+
+*R-2.13.0 (23 Jun 2011)
+
+ 23 Jun 2011; Justin Lecher <jlec@gentoo.org> R-2.10.1.ebuild,
+ R-2.12.1.ebuild, R-2.12.2.ebuild, +R-2.13.0.ebuild:
+ Version Bump, #372197
22 Jun 2011; Justin Lecher <jlec@gentoo.org> R-2.10.1.ebuild,
R-2.12.1.ebuild, R-2.12.2.ebuild:
1.12 dev-lang/R/R-2.10.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/R/R-2.10.1.ebuild?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/R/R-2.10.1.ebuild?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/R/R-2.10.1.ebuild?r1=1.11&r2=1.12
Index: R-2.10.1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/R/R-2.10.1.ebuild,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- R-2.10.1.ebuild 22 Jun 2011 18:46:09 -0000 1.11
+++ R-2.10.1.ebuild 23 Jun 2011 13:03:38 -0000 1.12
@@ -1,6 +1,6 @@
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/R/R-2.10.1.ebuild,v 1.11 2011/06/22 18:46:09 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/R/R-2.10.1.ebuild,v 1.12 2011/06/23 13:03:38 jlec Exp $
EAPI=2
@@ -8,14 +8,15 @@
DESCRIPTION="Language and environment for statistical computing and graphics"
HOMEPAGE="http://www.r-project.org/"
-SRC_URI="mirror://cran/src/base/R-2/${P}.tar.gz
+SRC_URI="
+ mirror://cran/src/base/R-2/${P}.tar.gz
bash-completion? ( mirror://gentoo/R.bash_completion.bz2 )"
LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="alpha amd64 hppa ia64 ppc ppc64 sparc x86 ~x86-fbsd"
-IUSE="doc java jpeg lapack minimal nls perl png readline threads tk X cairo"
+IUSE="cairo doc java jpeg lapack minimal nls perl png readline threads tk X"
# common depends
CDEPEND="
@@ -53,6 +54,7 @@
R_DIR=/usr/$(get_libdir)/${PN}
pkg_setup() {
+ fortran-2_pkg_setup
filter-ldflags -Wl,-Bdirect -Bdirect
# avoid using existing R installation
unset R_HOME
1.1 dev-lang/R/R-2.13.0.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/R/R-2.13.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/R/R-2.13.0.ebuild?rev=1.1&content-type=text/plain
Index: R-2.13.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/R/R-2.13.0.ebuild,v 1.1 2011/06/23 13:03:38 jlec Exp $
EAPI=4
inherit bash-completion eutils flag-o-matic fortran-2 versionator
DESCRIPTION="Language and environment for statistical computing and graphics"
HOMEPAGE="http://www.r-project.org/"
SRC_URI="
mirror://cran/src/base/R-2/${P}.tar.gz
bash-completion? ( mirror://gentoo/R.bash_completion.bz2 )"
LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="cairo doc java jpeg lapack minimal nls openmp perl png profile readline static-libs tk X"
# common depends
CDEPEND="
app-arch/bzip2
app-text/ghostscript-gpl
dev-libs/libpcre
virtual/blas
virtual/fortran[openmp?]
cairo? (
x11-libs/cairo[X]
|| ( >=x11-libs/pango-1.20[X] <x11-libs/pango-1.20 ) )
jpeg? ( virtual/jpeg )
lapack? ( virtual/lapack )
perl? ( dev-lang/perl )
png? ( media-libs/libpng )
readline? ( sys-libs/readline )
tk? ( dev-lang/tk )
X? ( x11-libs/libXmu x11-misc/xdg-utils )"
DEPEND="${CDEPEND}
dev-util/pkgconfig
doc? (
virtual/latex-base
|| (
dev-texlive/texlive-fontsrecommended
app-text/ptex ) )"
RDEPEND="${CDEPEND}
app-arch/unzip
app-arch/xz-utils
app-arch/zip
java? ( >=virtual/jre-1.5 )"
RESTRICT="minimal? ( test )"
R_DIR="${EPREFIX}"/usr/$(get_libdir)/${PN}
pkg_setup() {
if use openmp; then
FORTRAN_NEED_OPENMP=1
tc-has-openmp || die "Please enable openmp support in your compiler"
fi
fortran-2_pkg_setup
filter-ldflags -Wl,-Bdirect -Bdirect
# avoid using existing R installation
unset R_HOME
}
src_prepare() {
# fix ocasional failure with parallel install (bug #322965)
# upstream in R-12.3?
# https://bugs.r-project.org/bugzilla3/show_bug.cgi?id=14505
epatch "${FILESDIR}"/${PN}-2.11.1-parallel.patch
# respect ldflags on rscript
# upstream does not want it, no reasons given
# https://bugs.r-project.org/bugzilla3/show_bug.cgi?id=14506
epatch "${FILESDIR}"/${PN}-2.12.1-ldflags.patch
# fix Rscript
sed \
-e "s:-DR_HOME='\"\$(rhome)\"':-DR_HOME='\"${R_DIR}\"':" \
-i src/unix/Makefile.in || die "sed unix Makefile failed"
# fix HTML links to manual (bug #273957)
sed \
-e 's:\.\./manual/:manual/:g' \
-i $(grep -Flr ../manual/ doc) \
|| die "sed for HTML links to manual failed"
use lapack && \
export LAPACK_LIBS="$(pkg-config --libs lapack)"
if use X; then
export R_BROWSER="$(type -p xdg-open)"
export R_PDFVIEWER="$(type -p xdg-open)"
fi
use perl && \
export PERL5LIB="${S}/share/perl:${PERL5LIB:+:}${PERL5LIB}"
}
src_configure() {
econf \
--enable-R-shlib \
--with-system-zlib \
--with-system-bzlib \
--with-system-pcre \
--enable-byte-compiled-packages \
--with-blas="$(pkg-config --libs blas)" \
--docdir="${EPREFIX}"/usr/share/doc/${PF} \
rdocdir="${EPREFIX}"/usr/share/doc/${PF} \
$(use_enable openmp) \
$(use_enable nls) \
$(use_enable profile R-profiling) \
$(use_enable profile memory-profiling) \
$(use_enable static-libs static) \
$(use_enable static-libs R-static-lib) \
$(use_with lapack) \
$(use_with tk tcltk) \
$(use_with jpeg jpeglib) \
$(use_with !minimal recommended-packages) \
$(use_with png libpng) \
$(use_with readline) \
$(use_with cairo) \
$(use_with X x)
}
src_compile(){
export VARTEXFONTS="${T}/fonts"
emake || die "emake failed"
RMATH_V=0.0.0
emake -C src/nmath/standalone \
libRmath_la_LDFLAGS=-Wl,-soname,libRmath.so.${RMATH_V} \
|| die "emake math library failed"
if use doc; then
emake info pdf || die "emake docs failed"
fi
}
src_install() {
emake DESTDIR="${D}" install || die "emake install failed"
if use doc; then
emake DESTDIR="${D}" \
install-info install-pdf || die "emake install docs failed"
dosym /usr/share/doc/${PF}/manual /usr/share/doc/${PF}/html/manual
fi
# standalone math lib install (-j1 basically harmless)
emake \
-C src/nmath/standalone \
DESTDIR="${D}" install \
|| die "emake install math library failed"
local mv=$(get_major_version ${RMATH_V})
mv "${ED}"/usr/$(get_libdir)/libRmath.so \
"${ED}"/usr/$(get_libdir)/libRmath.so.${RMATH_V}
dosym libRmath.so.${RMATH_V} /usr/$(get_libdir)/libRmath.so.${mv}
dosym libRmath.so.${mv} /usr/$(get_libdir)/libRmath.so
# env file
cat > 99R <<-EOF
LDPATH=${R_DIR}/lib
R_HOME=${R_DIR}
EOF
doenvd 99R || die "doenvd failed"
dobashcompletion "${WORKDIR}"/R.bash_completion
}
pkg_postinst() {
if use java; then
einfo "Re-initializing java paths for ${P}"
R CMD javareconf
fi
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-06-23 13:03 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-06-23 13:03 [gentoo-commits] gentoo-x86 commit in dev-lang/R: R-2.12.1.ebuild R-2.12.2.ebuild ChangeLog R-2.13.0.ebuild R-2.10.1.ebuild Justin Lecher (jlec)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox