[gentoo-commits] gentoo-x86 commit in net-dns/unbound: metadata.xml ChangeLog unbound-1.4.10.ebuild unbound-1.4.7-r1.ebuild unbound-1.4.3.ebuild unbound-1.4.6.ebuild unbound-1.4.7.ebuild

[gentoo-commits] gentoo-x86 commit in net-dns/unbound: metadata.xml ChangeLog unbound-1.4.10.ebuild unbound-1.4.7-r1.ebuild unbound-1.4.3.ebuild unbound-1.4.6.ebuild unbound-1.4.7.ebuild

[Matsuu Takuto (matsuu)]

matsuu      11/05/25 15:41:15

  Modified:             metadata.xml ChangeLog
  Added:                unbound-1.4.10.ebuild
  Removed:              unbound-1.4.7-r1.ebuild unbound-1.4.3.ebuild
                        unbound-1.4.6.ebuild unbound-1.4.7.ebuild
  Log:
  Version bumped. Removed *.la files.
  
  (Portage version: 2.1.9.49/cvs/Linux x86_64)

Revision  Changes    Path
1.4                  net-dns/unbound/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/metadata.xml?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/metadata.xml?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/metadata.xml?r1=1.3&r2=1.4

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-dns/unbound/metadata.xml,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- metadata.xml	11 Apr 2011 15:01:36 -0000	1.3
+++ metadata.xml	25 May 2011 15:41:15 -0000	1.4
@@ -24,7 +24,6 @@
 as a server, but are linked into an application) are easily possible.
 </longdescription>
 <use>
-  <flag name='libevent'>Use <pkg>dev-libs/libevent</pkg> instead of internal select based events</flag>
   <flag name='gost'>Enable GOST support</flag>
 </use>
 </pkgmetadata>



1.24                 net-dns/unbound/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/ChangeLog?rev=1.24&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/ChangeLog?rev=1.24&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/ChangeLog?r1=1.23&r2=1.24

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-dns/unbound/ChangeLog,v
retrieving revision 1.23
retrieving revision 1.24
diff -u -r1.23 -r1.24
--- ChangeLog	11 May 2011 19:37:25 -0000	1.23
+++ ChangeLog	25 May 2011 15:41:15 -0000	1.24
@@ -1,6 +1,13 @@
 # ChangeLog for net-dns/unbound
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-dns/unbound/ChangeLog,v 1.23 2011/05/11 19:37:25 angelos Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-dns/unbound/ChangeLog,v 1.24 2011/05/25 15:41:15 matsuu Exp $
+
+*unbound-1.4.10 (25 May 2011)
+
+  25 May 2011; MATSUU Takuto <matsuu@gentoo.org> -unbound-1.4.3.ebuild,
+  -unbound-1.4.6.ebuild, -unbound-1.4.7.ebuild, -unbound-1.4.7-r1.ebuild,
+  +unbound-1.4.10.ebuild:
+  Version bumped. Removed *.la files. Removed old versions.
 
   11 May 2011; Christoph Mende <angelos@gentoo.org> unbound-1.4.8.ebuild:
   Stable on amd64 wrt bug #362015



1.1                  net-dns/unbound/unbound-1.4.10.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/unbound-1.4.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/unbound-1.4.10.ebuild?rev=1.1&content-type=text/plain

Index: unbound-1.4.10.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dns/unbound/unbound-1.4.10.ebuild,v 1.1 2011/05/25 15:41:15 matsuu Exp $

EAPI="3"
PYTHON_DEPEND="python? 2"
inherit eutils python

DESCRIPTION="A validating, recursive and caching DNS resolver"
HOMEPAGE="http://unbound.net/"
SRC_URI="http://unbound.net/downloads/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~x64-macos"
IUSE="debug gost python static-libs test threads"

RDEPEND="dev-libs/expat
	dev-libs/libevent
	>=dev-libs/openssl-0.9.8
	>=net-libs/ldns-1.6.5[ssl,gost?]"

DEPEND="${RDEPEND}
	python? ( dev-lang/swig )
	test? (
		net-dns/ldns-utils[examples]
		dev-util/splint
		app-text/wdiff
	)"

# bug #347415
RDEPEND="${RDEPEND}
	net-dns/dnssec-root"

pkg_setup() {
	python_set_active_version 2
	enewgroup unbound
	enewuser unbound -1 -1 /etc/unbound unbound
}

src_configure() {
	econf \
		--with-pidfile="${EPREFIX}"/var/run/unbound.pid \
		--with-ldns="${EPREFIX}"/usr \
		--with-libevent="${EPREFIX}"/usr \
		--with-rootkey-file="${EPREFIX}"/etc/dnssec/root-anchors.txt \
		$(use_enable debug) \
		$(use_enable gost) \
		$(use_enable static-libs static) \
		$(use_with threads pthreads) \
		$(use_with python pyunbound) \
		$(use_with python pythonmodule) \
		--disable-rpath || die

		# http://unbound.nlnetlabs.nl/pipermail/unbound-users/2011-April/001801.html
		# $(use_enable debug lock-checks) \
		# $(use_enable debug alloc-checks) \
		# $(use_enable debug alloc-lite) \
		# $(use_enable debug alloc-nonregional) \
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	# bug #299016
	if use python ; then
		find "${ED}$(python_get_sitedir)" "(" -name "*.a" -o -name "*.la" ")" -type f -delete || die
	fi
	if ! use static-libs ; then
		find "${ED}" -name "*.la" -type f -delete || die
	fi

	newinitd "${FILESDIR}/unbound.initd" unbound || die "newinitd failed"
	newconfd "${FILESDIR}/unbound.confd" unbound || die "newconfd failed"

	dodoc doc/{README,CREDITS,TODO,Changelog,FEATURES} || die "dodoc failed"

	# bug #315519
	#exeinto /usr/libexec/munin/plugins
	#doexe contrib/unbound_munin_ || die "doexe failed"
	dodoc contrib/unbound_munin_ || die "dodoc failed"

	docinto selinux
	dodoc contrib/selinux/* || die "dodoc failed"

	exeinto /usr/share/${PN}
	doexe contrib/update-anchor.sh || die "doexe failed"
}