* [gentoo-commits] gentoo-x86 commit in dev-libs/nspr: nspr-4.8.8.ebuild ChangeLog
@ 2011-05-13 21:13 Jory Pratt (anarchy)
0 siblings, 0 replies; only message in thread
From: Jory Pratt (anarchy) @ 2011-05-13 21:13 UTC (permalink / raw
To: gentoo-commits
anarchy 11/05/13 21:13:30
Modified: ChangeLog
Added: nspr-4.8.8.ebuild
Log:
Version Bump nspr/nss
(Portage version: 2.1.9.49/cvs/Linux x86_64)
Revision Changes Path
1.161 dev-libs/nspr/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/nspr/ChangeLog?rev=1.161&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/nspr/ChangeLog?rev=1.161&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/nspr/ChangeLog?r1=1.160&r2=1.161
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/nspr/ChangeLog,v
retrieving revision 1.160
retrieving revision 1.161
diff -u -r1.160 -r1.161
--- ChangeLog 7 May 2011 17:52:13 -0000 1.160
+++ ChangeLog 13 May 2011 21:13:30 -0000 1.161
@@ -1,6 +1,11 @@
# ChangeLog for dev-libs/nspr
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/nspr/ChangeLog,v 1.160 2011/05/07 17:52:13 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/nspr/ChangeLog,v 1.161 2011/05/13 21:13:30 anarchy Exp $
+
+*nspr-4.8.8 (13 May 2011)
+
+ 13 May 2011; Jory A. Pratt <anarchy@gentoo.org> +nspr-4.8.8.ebuild:
+ Version bump
07 May 2011; Raúl Porcel <armin76@gentoo.org> nspr-4.8.7.ebuild:
alpha/arm/ia64/sparc stable wrt #360315
1.1 dev-libs/nspr/nspr-4.8.8.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/nspr/nspr-4.8.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/nspr/nspr-4.8.8.ebuild?rev=1.1&content-type=text/plain
Index: nspr-4.8.8.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/nspr/nspr-4.8.8.ebuild,v 1.1 2011/05/13 21:13:30 anarchy Exp $
EAPI=3
inherit eutils multilib toolchain-funcs versionator
MIN_PV="$(get_version_component_range 2)"
DESCRIPTION="Netscape Portable Runtime"
HOMEPAGE="http://www.mozilla.org/projects/nspr/"
SRC_URI="ftp://ftp.mozilla.org/pub/mozilla.org/nspr/releases/v${PV}/src/${P}.tar.gz"
LICENSE="|| ( MPL-1.1 GPL-2 LGPL-2.1 )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~ppc-aix ~x86-fbsd ~amd64-linux ~x86-linux ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="debug"
src_prepare() {
mkdir build inst
epatch "${FILESDIR}"/${PN}-4.8-config.patch
epatch "${FILESDIR}"/${PN}-4.6.1-config-1.patch
epatch "${FILESDIR}"/${PN}-4.6.1-lang.patch
epatch "${FILESDIR}"/${PN}-4.7.0-prtime.patch
epatch "${FILESDIR}"/${PN}-4.8-pkgconfig-gentoo-3.patch
epatch "${FILESDIR}"/${PN}-4.7.1-solaris.patch
epatch "${FILESDIR}"/${PN}-4.7.4-solaris.patch
epatch "${FILESDIR}"/${PN}-4.8.3-aix-gcc.patch
# Patch needs updating
#epatch "${FILESDIR}"/${PN}-4.8.3-aix-soname.patch
epatch "${FILESDIR}"/${PN}-4.8.4-darwin-install_name.patch
# make sure it won't find Perl out of Prefix
sed -i -e "s/perl5//g" mozilla/nsprpub/configure || die
# Respect LDFLAGS
sed -i -e 's/\$(MKSHLIB) \$(OBJS)/\$(MKSHLIB) \$(LDFLAGS) \$(OBJS)/g' \
mozilla/nsprpub/config/rules.mk
}
src_configure() {
cd "${S}"/build
echo > "${T}"/test.c
$(tc-getCC) -c "${T}"/test.c -o "${T}"/test.o
case $(scanelf -BF'%M' "${T}"/test.o)$(scanmacho -BF'%M' "${T}"/test.o) in
ELFCLASS64*|POWERPC64*|X86_64*) myconf="${myconf} --enable-64bit";;
ELFCLASS32*|POWERPC*|I386*|ARM*) ;;
*) die "Failed to detect whether your arch is 64bits or 32bits, disable distcc if you're using it, please";;
esac
myconf="${myconf} --libdir=${EPREFIX}/usr/$(get_libdir)"
ECONF_SOURCE="../mozilla/nsprpub" econf \
$(use_enable debug) \
$(use_enable !debug optimize) \
${myconf} || die "econf failed"
}
src_compile() {
cd "${S}"/build
emake CC="$(tc-getCC)" CXX="$(tc-getCXX)" || die "failed to build"
}
src_install () {
# Their build system is royally confusing, as usual
MINOR_VERSION=${MIN_PV} # Used for .so version
cd "${S}"/build
emake DESTDIR="${D}" install || die "emake install failed"
cd "${ED}"/usr/$(get_libdir)
for file in *.a; do
einfo "removing static libraries as upstream has requested!"
rm -f ${file} || die "failed to remove static libraries."
done
local n=
# aix-soname.patch does this already
[[ ${CHOST} == *-aix* ]] ||
for file in *$(get_libname); do
n=${file%$(get_libname)}$(get_libname ${MINOR_VERSION})
mv ${file} ${n} || die "failed to mv files around"
ln -s ${n} ${file} || die "failed to symlink files."
if [[ ${CHOST} == *-darwin* ]]; then
install_name_tool -id "${EPREFIX}/usr/$(get_libdir)/${n}" ${n} || die
fi
done
# install nspr-config
dobin "${S}"/build/config/nspr-config || die "failed to install nspr-config"
# create pkg-config file
insinto /usr/$(get_libdir)/pkgconfig/
doins "${S}"/build/config/nspr.pc || die "failed to insall nspr pkg-config file"
# Remove stupid files in /usr/bin
rm -f "${ED}"/usr/bin/prerr.properties || die "failed to cleanup unneeded files"
}
pkg_postinst() {
ewarn
ewarn "Please make sure you run revdep-rebuild after upgrade."
ewarn "This is *extremely* important to ensure your system nspr works properly."
ewarn
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-05-13 21:13 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-05-13 21:13 [gentoo-commits] gentoo-x86 commit in dev-libs/nspr: nspr-4.8.8.ebuild ChangeLog Jory Pratt (anarchy)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox