From: "Jorge Manuel B. S. Vicetto (jmbsvicetto)" <jmbsvicetto@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] gentoo-x86 commit in media-sound/amarok: amarok-2.4.1.ebuild ChangeLog amarok-2.4.0.90.ebuild
Date: Sun, 8 May 2011 16:21:45 +0000 (UTC) [thread overview]
Message-ID: <20110508162145.DDC7C20054@flycatcher.gentoo.org> (raw)
jmbsvicetto 11/05/08 16:21:45
Modified: ChangeLog amarok-2.4.0.90.ebuild
Added: amarok-2.4.1.ebuild
Log:
Bumped amarok to the 2.4.1 release.
Renamed the patch to fix the upnp detection.
(Portage version: 2.2.0_alpha30/cvs/Linux x86_64)
Revision Changes Path
1.405 media-sound/amarok/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/amarok/ChangeLog?rev=1.405&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/amarok/ChangeLog?rev=1.405&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/amarok/ChangeLog?r1=1.404&r2=1.405
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v
retrieving revision 1.404
retrieving revision 1.405
diff -u -r1.404 -r1.405
--- ChangeLog 26 Apr 2011 22:03:26 -0000 1.404
+++ ChangeLog 8 May 2011 16:21:45 -0000 1.405
@@ -1,6 +1,14 @@
# ChangeLog for media-sound/amarok
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v 1.404 2011/04/26 22:03:26 jmbsvicetto Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v 1.405 2011/05/08 16:21:45 jmbsvicetto Exp $
+
+*amarok-2.4.1 (08 May 2011)
+
+ 08 May 2011; Jorge Manuel B. S. Vicetto <jmbsvicetto@gentoo.org>
+ amarok-2.4.0.90.ebuild, +amarok-2.4.1.ebuild,
+ +files/amarok-fix-upnp-dep.patch:
+ Bumped amarok to the 2.4.1 release.
+ Renamed the patch to fix the upnp detection.
26 Apr 2011; Jorge Manuel B. S. Vicetto <jmbsvicetto@gentoo.org>
amarok-2.4.0.90.ebuild:
1.5 media-sound/amarok/amarok-2.4.0.90.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/amarok/amarok-2.4.0.90.ebuild?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/amarok/amarok-2.4.0.90.ebuild?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/amarok/amarok-2.4.0.90.ebuild?r1=1.4&r2=1.5
Index: amarok-2.4.0.90.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/amarok/amarok-2.4.0.90.ebuild,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- amarok-2.4.0.90.ebuild 26 Apr 2011 22:03:26 -0000 1.4
+++ amarok-2.4.0.90.ebuild 8 May 2011 16:21:45 -0000 1.5
@@ -1,6 +1,6 @@
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/amarok-2.4.0.90.ebuild,v 1.4 2011/04/26 22:03:26 jmbsvicetto Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/amarok-2.4.0.90.ebuild,v 1.5 2011/05/08 16:21:45 jmbsvicetto Exp $
EAPI="3"
@@ -79,7 +79,7 @@
# Upstream patch to fix the plugin detection on startup
# https://projects.kde.org/projects/extragear/multimedia/amarok/repository/revisions/37eda947bd8181a73ad0fffc88e66c25ddd69f28
PATCHES=(
- "${FILESDIR}/${P}-fix-upnp-dep.patch"
+ "${FILESDIR}/${PN}-fix-upnp-dep.patch"
"${FILESDIR}/${P}-fix-plugin-detection.patch"
)
1.1 media-sound/amarok/amarok-2.4.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/amarok/amarok-2.4.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/amarok/amarok-2.4.1.ebuild?rev=1.1&content-type=text/plain
Index: amarok-2.4.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/amarok-2.4.1.ebuild,v 1.1 2011/05/08 16:21:45 jmbsvicetto Exp $
EAPI="3"
# Translations are only in the tarballs, not the git repo
if [[ ${PV} != *9999* ]]; then
KDE_LINGUAS="bg ca cs da de en_GB es et eu fi fr hu it ja km nb nds nl
pa pl pt pt_BR ru sl sr sr@latin sv th tr uk wa zh_TW"
SRC_URI="mirror://kde/stable/${PN}/${PV}/src/${P}.tar.bz2"
KEYWORDS="~amd64 ~x86"
else
KDE_SCM="git"
KEYWORDS=""
fi
KDE_REQUIRED="never"
inherit flag-o-matic kde4-base
DESCRIPTION="Advanced audio player based on KDE framework."
HOMEPAGE="http://amarok.kde.org/"
LICENSE="GPL-2"
SLOT="4"
IUSE="cdda daap debug +embedded handbook ipod lastfm mp3tunes mtp opengl playdar +player semantic-desktop upnp +utils"
# Tests require gmock - http://code.google.com/p/gmock/
# It's not in the tree yet
RESTRICT="test"
# ipod requires gdk enabled and also gtk compiled in libgpod
COMMONDEPEND="
>=media-libs/taglib-1.6.1[asf,mp4]
>=media-libs/taglib-extras-1.0.1
player? (
app-crypt/qca:2
>=app-misc/strigi-0.5.7[dbus,qt4]
$(add_kdebase_dep kdelibs 'opengl?,semantic-desktop?')
sys-libs/zlib
>=virtual/mysql-5.1[embedded?]
x11-libs/qt-script
>=x11-libs/qtscriptgenerator-0.1.0
cdda? (
$(add_kdebase_dep libkcddb)
$(add_kdebase_dep libkcompactdisc)
$(add_kdebase_dep kdemultimedia-kioslaves)
)
ipod? ( >=media-libs/libgpod-0.7.0[gtk] )
lastfm? ( >=media-libs/liblastfm-0.3.0 )
mp3tunes? (
dev-libs/glib:2
dev-libs/libxml2
dev-libs/openssl
net-libs/loudmouth
net-misc/curl
x11-libs/qt-core[glib]
)
mtp? ( >=media-libs/libmtp-1.0.0 )
opengl? ( virtual/opengl )
playdar? ( dev-libs/qjson )
upnp? ( kde-misc/kio-upnp-ms )
)
utils? (
x11-libs/qt-core
x11-libs/qt-dbus
)
!player? ( !utils? ( media-sound/amarok[player] ) )
"
DEPEND="${COMMONDEPEND}
dev-util/automoc
dev-util/pkgconfig
"
RDEPEND="${COMMONDEPEND}
!media-sound/amarok-utils
player? ( $(add_kdebase_dep phonon-kde) )
"
# Upstream patch to fix the plugin detection on startup
# https://projects.kde.org/projects/extragear/multimedia/amarok/repository/revisions/37eda947bd8181a73ad0fffc88e66c25ddd69f28
PATCHES=(
"${FILESDIR}/${PN}-fix-upnp-dep.patch"
)
src_prepare() {
if ! use player; then
# Disable po processing
sed -e "s:include(MacroOptionalAddSubdirectory)::" \
-i "${S}/CMakeLists.txt" \
|| die "Removing include of MacroOptionalAddSubdirectory failed."
sed -e "s:macro_optional_add_subdirectory( po )::" \
-i "${S}/CMakeLists.txt" \
|| die "Removing include of MacroOptionalAddSubdirectory failed."
fi
kde4-base_src_prepare
}
src_configure() {
# Append minimal-toc cflag for ppc64, see bug 280552 and 292707
use ppc64 && append-flags -mminimal-toc
if use player; then
mycmakeargs=(
-DWITH_PLAYER=ON
-DWITH_Libgcrypt=OFF
$(cmake-utils_use embedded WITH_MYSQL_EMBEDDED)
$(cmake-utils_use_with ipod)
$(cmake-utils_use_with ipod Gdk)
$(cmake-utils_use_with lastfm LibLastFm)
$(cmake-utils_use_with mtp)
$(cmake-utils_use_with mp3tunes MP3Tunes)
$(cmake-utils_use_with playdar QJSON)
$(cmake-utils_use_with upnp HUpnp)
)
else
mycmakeargs=(
-DWITH_PLAYER=OFF
)
fi
mycmakeargs+=(
$(cmake-utils_use_with utils UTILITIES)
)
# $(cmake-utils_use_with semantic-desktop Nepomuk)
# $(cmake-utils_use_with semantic-desktop Soprano)
kde4-base_src_configure
}
pkg_postinst() {
kde4-base_pkg_postinst
if use player; then
if use daap; then
echo
elog "You have installed amarok with daap support."
elog "You may be interested in installing www-servers/mongrel as well."
echo
fi
if ! use embedded; then
echo
elog "You've disabled the amarok support for embedded mysql DBs."
elog "You'll have to configure amarok to use an external db server."
echo
elog "Please read http://amaroklive.com/wiki/MySQL_Server for details on how"
elog "to configure the external db and migrate your data from the embedded database."
echo
if has_version "virtual/mysql[minimal]"; then
elog "You built mysql with the minimal use flag, so it doesn't include the server."
elog "You won't be able to use the local mysql installation to store your amarok collection."
echo
fi
fi
fi
}
reply other threads:[~2011-05-08 16:25 UTC|newest]
Thread overview: [no followups] expand[flat|nested] mbox.gz Atom feed
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20110508162145.DDC7C20054@flycatcher.gentoo.org \
--to=jmbsvicetto@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox