[gentoo-commits] gentoo-x86 commit in net-dns/unbound: metadata.xml ChangeLog unbound-1.4.9.ebuild

[gentoo-commits] gentoo-x86 commit in net-dns/unbound: metadata.xml ChangeLog unbound-1.4.9.ebuild

[Matsuu Takuto (matsuu)]

matsuu      11/04/11 15:01:36

  Modified:             metadata.xml ChangeLog
  Added:                unbound-1.4.9.ebuild
  Log:
  Version bumepd, bug #362013. Added proxied developer.
  
  (Portage version: 2.1.9.45/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  net-dns/unbound/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-dns/unbound/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	9 Nov 2010 00:03:12 -0000	1.2
+++ metadata.xml	11 Apr 2011 15:01:36 -0000	1.3
@@ -3,7 +3,14 @@
 <pkgmetadata>
 <herd>no-herd</herd>
 <maintainer>
-<email>matsuu@gentoo.org</email>
+  <email>matsuu@gentoo.org</email>
+  <description>Primary maintainer</description>
+  <name>MATSUU Takuto</name>
+</maintainer>
+<maintainer>
+  <email>nabeken@tknetworks.org</email>
+  <description>Proxied developer. Please CC on bugs.</description>
+  <name>TANABE Ken-ichi</name>
 </maintainer>
 <longdescription lang="en">
 Unbound is a validating, recursive, and caching DNS resolver.
@@ -17,8 +24,7 @@
 as a server, but are linked into an application) are easily possible.
 </longdescription>
 <use>
-  <flag name='libevent'>Use <pkg>dev-libs/libevent</pkg> instead of internal
-  select based events</flag>
+  <flag name='libevent'>Use <pkg>dev-libs/libevent</pkg> instead of internal select based events</flag>
   <flag name='gost'>Enable GOST support</flag>
 </use>
 </pkgmetadata>



1.21                 net-dns/unbound/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/ChangeLog?rev=1.21&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/ChangeLog?rev=1.21&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/ChangeLog?r1=1.20&r2=1.21

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-dns/unbound/ChangeLog,v
retrieving revision 1.20
retrieving revision 1.21
diff -u -r1.20 -r1.21
--- ChangeLog	25 Jan 2011 14:20:31 -0000	1.20
+++ ChangeLog	11 Apr 2011 15:01:36 -0000	1.21
@@ -1,6 +1,12 @@
 # ChangeLog for net-dns/unbound
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-dns/unbound/ChangeLog,v 1.20 2011/01/25 14:20:31 matsuu Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-dns/unbound/ChangeLog,v 1.21 2011/04/11 15:01:36 matsuu Exp $
+
+*unbound-1.4.9 (11 Apr 2011)
+
+  11 Apr 2011; MATSUU Takuto <matsuu@gentoo.org> +unbound-1.4.9.ebuild,
+  metadata.xml:
+  Version bumepd, bug #362013. Added proxied developer.
 
 *unbound-1.4.8 (25 Jan 2011)
 



1.1                  net-dns/unbound/unbound-1.4.9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/unbound-1.4.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/unbound-1.4.9.ebuild?rev=1.1&content-type=text/plain

Index: unbound-1.4.9.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dns/unbound/unbound-1.4.9.ebuild,v 1.1 2011/04/11 15:01:36 matsuu Exp $

EAPI="3"
PYTHON_DEPEND="python? 2"
inherit eutils python

DESCRIPTION="A validating, recursive and caching DNS resolver"
HOMEPAGE="http://unbound.net/"
SRC_URI="http://unbound.net/downloads/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~x64-macos"
IUSE="debug gost python static-libs test threads"

RDEPEND="dev-libs/expat
	dev-libs/libevent
	>=dev-libs/openssl-0.9.8
	>=net-libs/ldns-1.6.5[ssl,gost?]"

DEPEND="${RDEPEND}
	python? ( dev-lang/swig )
	test? (
		net-dns/ldns-utils[examples]
		dev-util/splint
		app-text/wdiff
	)"

# bug #347415
RDEPEND="${RDEPEND}
	net-dns/dnssec-root"

pkg_setup() {
	python_set_active_version 2
	enewgroup unbound
	enewuser unbound -1 -1 /etc/unbound unbound
}

src_configure() {
	econf \
		--with-pidfile="${EPREFIX}"/var/run/unbound.pid \
		--with-ldns="${EPREFIX}"/usr \
		--with-libevent="${EPREFIX}"/usr \
		--with-rootkey-file="${EPREFIX}"/etc/dnssec/root-anchors.txt \
		$(use_enable debug) \
		$(use_enable gost) \
		$(use_enable static-libs static) \
		$(use_with threads pthreads) \
		$(use_with python pyunbound) \
		$(use_with python pythonmodule) \
		--disable-rpath || die

		# http://unbound.nlnetlabs.nl/pipermail/unbound-users/2011-April/001801.html
		# $(use_enable debug lock-checks) \
		# $(use_enable debug alloc-checks) \
		# $(use_enable debug alloc-lite) \
		# $(use_enable debug alloc-nonregional) \
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	# bug #299016
	if use python ; then
		find "${ED}$(python_get_sitedir)" "(" -name "*.a" -o -name "*.la" ")" -type f -delete || die
	fi

	newinitd "${FILESDIR}/unbound.initd" unbound || die "newinitd failed"
	newconfd "${FILESDIR}/unbound.confd" unbound || die "newconfd failed"

	dodoc doc/{README,CREDITS,TODO,Changelog,FEATURES} || die "dodoc failed"

	# bug #315519
	#exeinto /usr/libexec/munin/plugins
	#doexe contrib/unbound_munin_ || die "doexe failed"
	dodoc contrib/unbound_munin_ || die "dodoc failed"

	docinto selinux
	dodoc contrib/selinux/* || die "dodoc failed"

	exeinto /usr/share/${PN}
	doexe contrib/update-anchor.sh || die "doexe failed"
}