[gentoo-commits] gentoo-x86 commit in net-im/ekg2: ChangeLog ekg2-0.3.1-r1.ebuild ekg2-0.3.1.ebuild ekg2-0.3.0.ebuild

[gentoo-commits] gentoo-x86 commit in net-im/ekg2: ChangeLog ekg2-0.3.1-r1.ebuild ekg2-0.3.1.ebuild ekg2-0.3.0.ebuild

[Michal Gorny (mgorny)]

mgorny      11/04/06 15:42:45

  Modified:             ChangeLog
  Added:                ekg2-0.3.1-r1.ebuild
  Removed:              ekg2-0.3.1.ebuild ekg2-0.3.0.ebuild
  Log:
  Install Perl modules in vendor-dir instead of site-dir. Drop old version. Fixes bug #362231.
  
  (Portage version: 2.2.0_alpha29_p5/cvs/Linux x86_64)

Revision  Changes    Path
1.46                 net-im/ekg2/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/ekg2/ChangeLog?rev=1.46&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/ekg2/ChangeLog?rev=1.46&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/ekg2/ChangeLog?r1=1.45&r2=1.46

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/ekg2/ChangeLog,v
retrieving revision 1.45
retrieving revision 1.46
diff -u -r1.45 -r1.46
--- ChangeLog	1 Apr 2011 20:10:19 -0000	1.45
+++ ChangeLog	6 Apr 2011 15:42:45 -0000	1.46
@@ -1,6 +1,14 @@
 # ChangeLog for net-im/ekg2
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/ekg2/ChangeLog,v 1.45 2011/04/01 20:10:19 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/ekg2/ChangeLog,v 1.46 2011/04/06 15:42:45 mgorny Exp $
+
+*ekg2-0.3.1-r1 (06 Apr 2011)
+
+  06 Apr 2011; Michał Górny <mgorny@gentoo.org>
+  +files/0001-Gentoo-use-vendor-dirs-for-perl-modules.patch,
+  -ekg2-0.3.0.ebuild, -ekg2-0.3.1.ebuild, +ekg2-0.3.1-r1.ebuild:
+  Install Perl modules in vendor-dir instead of site-dir. Drop old version.
+  Fixes bug #362231.
 
 *ekg2-0.3.1 (01 Apr 2011)
 



1.1                  net-im/ekg2/ekg2-0.3.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/ekg2/ekg2-0.3.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/ekg2/ekg2-0.3.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: ekg2-0.3.1-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/ekg2/ekg2-0.3.1-r1.ebuild,v 1.1 2011/04/06 15:42:45 mgorny Exp $

EAPI=3
inherit autotools-utils versionator

DESCRIPTION="Text-based, multi-protocol instant messenger"
HOMEPAGE="http://www.ekg2.org"
SRC_URI="http://pl.ekg2.org/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="gadu gif gnutls gpg gpm gsm gtk idn inotify jabber jpeg ncurses nls
	oracle perl python readline rss spell sqlite sqlite3 ssl threads unicode
	xosd zlib"

RDEPEND="
	gpg? ( app-crypt/gpgme )
	gsm? ( media-sound/gsm )
	gtk? ( x11-libs/gtk+:2 )
	idn? ( net-dns/libidn )
	nls? ( virtual/libintl )
	oracle?	( dev-db/oracle-instantclient-basic )
	perl? ( dev-lang/perl )
	python?	( dev-lang/python )
	readline? ( sys-libs/readline )
	ssl? ( dev-libs/openssl )
	xosd? ( x11-libs/xosd )
	zlib? ( sys-libs/zlib )

	gadu? ( net-libs/libgadu
		gif? ( media-libs/giflib )
		jpeg? ( virtual/jpeg ) )
	jabber? ( dev-libs/expat
		gnutls? ( net-libs/gnutls ) )
	ncurses? ( sys-libs/ncurses[unicode?]
		gpm? ( sys-libs/gpm )
		spell? ( app-text/aspell ) )
	rss? ( dev-libs/expat )
	sqlite3? ( dev-db/sqlite:3 )
	!sqlite3? ( sqlite? ( dev-db/sqlite:0 ) )"

DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )"

PATCHES=(
	"${FILESDIR}"/0001-Gentoo-use-vendor-dirs-for-perl-modules.patch
)
DOCS=(
	AUTHORS docs/README docs/TODO
	docs/events.txt docs/mouse.txt docs/sim.txt docs/voip.txt
	docs/themes.txt docs/themes-en.txt
	docs/ui-ncurses.txt docs/ui-ncurses-en.txt
)

# Due to MakeMaker being used to build Perl modules.
AUTOTOOLS_IN_SOURCE_BUILD=1

pkg_setup() {
	if ! use gtk && ! use ncurses && ! use readline; then
		ewarn 'ekg2 is being compiled without any frontend, you should consider'
		ewarn 'enabling at least one of following USEflags:'
		ewarn '  gtk, ncurses, readline.'
	fi

	if use gnutls && ! use ssl; then
		ewarn 'You have enabled USE=gnutls without USE=ssl. The SSL support'
		ewarn 'in ekg2 will be limited to the plugins supporting GnuTLS.'
	fi
}

src_configure() {
	myeconfargs=(
		$(use_with gadu libgadu)
		$(use_with gif)
		# gnutls is jabber-specific
		$(use jabber && use_with gnutls libgnutls || echo '--without-libgnutls')
		$(use_with gpg)
		$(use_with gpm gpm-mouse)
		$(use_with gsm libgsm)
		$(use_with gtk)
		$(use_with idn libidn)
		$(use_with inotify)
		$(use jabber && echo '--with-expat' || use_with rss expat)
		$(use_with jpeg libjpeg)
		$(use_with ncurses)
		$(use_with oracle logsoracle)
		$(use_with perl)
		$(use_with python)
		$(use_with readline)
		$(use_with spell aspell)
		$(use_with sqlite)
		$(use_with sqlite3)
		$(use_with ssl openssl)
		$(use_with threads pthread)
		$(use_with xosd libxosd)
		$(use_with zlib)
		$(use_enable nls)
		$(use_enable unicode)
		--without-ioctld
		--disable-remote
		--enable-skip-relative-plugins-dir
	)
	autotools-utils_src_configure
}

src_install() {
	autotools-utils_src_install
	remove_libtool_files all
}