[gentoo-commits] gentoo-x86 commit in media-libs/clutter: clutter-1.6.12.ebuild ChangeLog clutter-1.6.8.ebuild

["Nirbheek Chauhan (nirbheek)" <nirbheek@gentoo.org>]

nirbheek    11/04/04 14:47:25

  Modified:             ChangeLog
  Added:                clutter-1.6.12.ebuild
  Removed:              clutter-1.6.8.ebuild
  Log:
  Bump to 1.6.12, remove old
  
  (Portage version: 2.1.9.45/cvs/Linux x86_64)

Revision  Changes    Path
1.31                 media-libs/clutter/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/clutter/ChangeLog?rev=1.31&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/clutter/ChangeLog?rev=1.31&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/clutter/ChangeLog?r1=1.30&r2=1.31

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/clutter/ChangeLog,v
retrieving revision 1.30
retrieving revision 1.31
diff -u -r1.30 -r1.31
--- ChangeLog	23 Mar 2011 08:33:38 -0000	1.30
+++ ChangeLog	4 Apr 2011 14:47:25 -0000	1.31
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/clutter
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/clutter/ChangeLog,v 1.30 2011/03/23 08:33:38 nirbheek Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/clutter/ChangeLog,v 1.31 2011/04/04 14:47:25 nirbheek Exp $
+
+*clutter-1.6.12 (04 Apr 2011)
+
+  04 Apr 2011; Nirbheek Chauhan <nirbheek@gentoo.org> -clutter-1.6.8.ebuild,
+  +clutter-1.6.12.ebuild:
+  Bump to 1.6.12, remove old
 
   23 Mar 2011; Nirbheek Chauhan <nirbheek@gentoo.org> clutter-1.2.14.ebuild:
   Fix slot-deps on gnome libs



1.1                  media-libs/clutter/clutter-1.6.12.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/clutter/clutter-1.6.12.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/clutter/clutter-1.6.12.ebuild?rev=1.1&content-type=text/plain

Index: clutter-1.6.12.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/clutter/clutter-1.6.12.ebuild,v 1.1 2011/04/04 14:47:25 nirbheek Exp $

EAPI="2"
WANT_AUTOMAKE="1.11"
[[ ${PV} = 9999 ]] && GIT_ECLASS="autotools git"

inherit clutter ${GIT_ECLASS}

DESCRIPTION="Clutter is a library for creating graphical user interfaces"

SLOT="1.0"
IUSE="debug doc +introspection"
if [[ ${PV} = 9999 ]]; then
	EGIT_BOOTSTRAP="echo > build/config.rpath
		gtkdocize
		cp "${ROOT}/usr/share/gettext/po/Makefile.in.in" po/
		eautoreconf"
	EGIT_REPO_URI="git://git.clutter-project.org/${PN}.git"
	SRC_URI=""
	KEYWORDS=""
	DEPEND=">=dev-util/gtk-doc-1.13"
else
	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
fi

# NOTE: glx flavour uses libdrm + >=mesa-7.3
# We always use the gdk-pixbuf backend now since it's been split out
RDEPEND="${RDEPEND}
	>=dev-libs/glib-2.26:2
	>=x11-libs/cairo-1.10
	>=x11-libs/pango-1.20[introspection?]
	>=dev-libs/json-glib-0.12[introspection?]
	>=dev-libs/atk-1.17

	virtual/opengl
	x11-libs/libdrm
	x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXdamage
	x11-proto/inputproto
	>=x11-libs/libXi-1.3
	>=x11-libs/libXfixes-3
	>=x11-libs/libXcomposite-0.4

	|| ( x11-libs/gdk-pixbuf:2
		 >=x11-libs/gtk+-2.0:2 )

	introspection? ( >=dev-libs/gobject-introspection-0.9.6 )
"
DEPEND="${RDEPEND}
	${DEPEND}
	sys-devel/gettext
	dev-util/pkgconfig
	>=dev-util/gtk-doc-am-1.13
	doc? (
		>=dev-util/gtk-doc-1.13
		>=app-text/docbook-sgml-utils-0.6.14[jadetex]
		dev-libs/libxslt )
"
DOCS="AUTHORS README NEWS ChangeLog*"

src_configure() {
	# We only need conformance tests, the rest are useless for us
	sed -e 's/^\(SUBDIRS =\).*/\1/g' \
		-i tests/Makefile.am || die "am tests sed failed"
	sed -e 's/^\(SUBDIRS =\).*/\1/g' \
		-i tests/Makefile.in || die "in tests sed failed"

	# XXX: Conformance test suite (and clutter itself) does not work under Xvfb
	# XXX: Profiling, coverage disabled for now
	# XXX: What about eglx/eglnative/opengl-egl-xlib/osx/wayland/etc flavours?
	#      Uses gudev-1.0 and libxkbcommon for eglnative/cex1000
	local myconf="
		--enable-debug=minimum
		--enable-cogl-debug=minimum
		--enable-conformance=no
		--disable-gcov
		--enable-profile=no
		--enable-maintainer-flags=no
		--enable-xinput
		--with-flavour=glx
		--with-imagebackend=gdk-pixbuf
		$(use_enable introspection)
		$(use_enable doc docs)"

	if use debug; then
		myconf="${myconf}
			--enable-debug=yes
			--enable-cogl-debug=yes"
	fi

	econf ${myconf}
}