* [gentoo-commits] gentoo-x86 commit in media-gfx/iscan: ChangeLog iscan-2.26.2.ebuild
@ 2011-04-03 0:17 Stefan Briesenick (sbriesen)
0 siblings, 0 replies; 2+ messages in thread
From: Stefan Briesenick (sbriesen) @ 2011-04-03 0:17 UTC (permalink / raw
To: gentoo-commits
sbriesen 11/04/03 00:17:14
Modified: ChangeLog
Added: iscan-2.26.2.ebuild
Log:
version bump (bug #359601)
(Portage version: 2.2.0_alpha29/cvs/Linux x86_64)
Revision Changes Path
1.41 media-gfx/iscan/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/iscan/ChangeLog?rev=1.41&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/iscan/ChangeLog?rev=1.41&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/iscan/ChangeLog?r1=1.40&r2=1.41
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/iscan/ChangeLog,v
retrieving revision 1.40
retrieving revision 1.41
diff -u -r1.40 -r1.41
--- ChangeLog 29 Mar 2011 12:22:06 -0000 1.40
+++ ChangeLog 3 Apr 2011 00:17:14 -0000 1.41
@@ -1,6 +1,11 @@
# ChangeLog for media-gfx/iscan
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/iscan/ChangeLog,v 1.40 2011/03/29 12:22:06 angelos Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/iscan/ChangeLog,v 1.41 2011/04/03 00:17:14 sbriesen Exp $
+
+*iscan-2.26.2 (03 Apr 2011)
+
+ 03 Apr 2011; Stefan Briesenick <sbriesen@gentoo.org> +iscan-2.26.2.ebuild:
+ version bump (bug #359601)
29 Mar 2011; Christoph Mende <angelos@gentoo.org> iscan-2.11.0.ebuild,
iscan-2.21.0.ebuild, iscan-2.25.0.ebuild:
1.1 media-gfx/iscan/iscan-2.26.2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/iscan/iscan-2.26.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/iscan/iscan-2.26.2.ebuild?rev=1.1&content-type=text/plain
Index: iscan-2.26.2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/iscan/iscan-2.26.2.ebuild,v 1.1 2011/04/03 00:17:14 sbriesen Exp $
EAPI="2"
inherit eutils flag-o-matic autotools
SRC_REV="1" # revision used by upstream
# HINTS:
# -> non-free modules are x86 and amd64 only
# -> iscan frontend needs non-free modules
# -> sane-epkowa should be usable on every arch
# -> ${P}-${SRC_REV}.tar.gz (for gcc 3.2/3.3)
# -> ${P}-${SRC_REV}.c2.tar.gz (for gcc 3.4 or later)
# FIXME:
# Make jpeg/png optional. The problem is, that the configure script ignores --disable-*,
# if the corresponding lib is found on the system.
# Furthermore, iscan doesn't compile w/o libusb, this should be fixed somehow.
# TODO:
# (re)add closed-source binary modules which are needed for some scanners.
KEYWORDS="~amd64 ~x86"
DESCRIPTION="EPSON Image Scan! for Linux (including sane-epkowa backend)"
HOMEPAGE="http://www.avasys.jp/english/linux_e/dl_scan.html"
SRC_URI="http://linux.avasys.jp/drivers/iscan/${PV}/${PN}_${PV}-${SRC_REV}.tar.gz
doc? ( http://linux.avasys.jp/drivers/iscan/doc/userg_revL_e.pdf )"
LICENSE="GPL-2 AVASYS"
SLOT="0"
IUSE="X gimp jpeg png tiff doc"
IUSE_LINGUAS="ar de es fr it ja ko nl pt zh_CN zh_TW"
for X in ${IUSE_LINGUAS}; do IUSE="${IUSE} linguas_${X}"; done
QA_PRESTRIPPED="usr/$(get_libdir)/libesmod.so.*"
QA_TEXTRELS="${QA_PRESTRIPPED}"
QA_DT_HASH="${QA_PRESTRIPPED}"
# Upstream ships broken sanity test
RESTRICT="test"
RDEPEND="media-gfx/iscan-data
media-gfx/sane-backends
>=sys-fs/udev-103
>=dev-libs/libusb-0.1.12
sys-libs/libieee1284
X? (
x11-libs/gtk+:2
gimp? ( media-gfx/gimp )
png? ( media-libs/libpng )
jpeg? ( virtual/jpeg )
tiff? ( media-libs/tiff )
)"
DEPEND="${RDEPEND}
X? ( sys-devel/gettext )"
src_prepare() {
local i
# convert japanese docs to UTF-8
if use linguas_ja; then
for i in {NEWS,README}.ja non-free/*.ja.txt; do
if [ -f "${i}" ]; then
echo ">>> Converting ${i} to UTF-8"
iconv -f eucjp -t utf8 -o "${i}~" "${i}" && mv -f "${i}~" "${i}" || rm -f "${i}~"
fi
done
fi
# disable checks for gtk+
if ! use X; then
sed -i -e "s:PKG_CHECK_MODULES(GTK,.*):AC_DEFINE([HAVE_GTK_2], 0):g" \
-e "s:\(PKG_CHECK_MODULES(GDK_IMLIB,.*)\):#\1:g" configure.ac
fi
epatch "${FILESDIR}/iscan-2.25.0-drop-ltdl.patch"
epatch "${FILESDIR}/iscan-2.25.0-fix-g++-test.patch"
eautoreconf
}
src_configure() {
append-flags -D_GNU_SOURCE # needed for 'strndup'
local myconf="--enable-dependency-reduction"
if use X; then
myconf="${myconf}
--enable-frontend
$(use_enable gimp)
$(use_enable jpeg)
$(use_enable png)
$(use_enable tiff)"
else
myconf="${myconf}
--disable-frontend --disable-gimp
--disable-jpeg --disable-png --disable-tiff"
fi
econf --disable-static ${myconf}
}
src_install() {
local MY_LIB="/usr/$(get_libdir)"
emake DESTDIR="${D}" install || die "emake install failed"
# install docs
dodoc AUTHORS NEWS README
use linguas_ja && dodoc NEWS.ja README.ja
# install sane config
insinto /etc/sane.d
doins backend/epkowa.conf
# install extra docs
if use doc; then
insinto /usr/share/doc/${PF}
doins "${DISTDIR}/userg_revL_e.pdf"
fi
# link iscan so it is seen as a plugin in gimp
if use X && use gimp; then
local plugindir
if [ -x /usr/bin/gimptool ]; then
plugindir="$(gimptool --gimpplugindir)/plug-ins"
elif [ -x /usr/bin/gimptool-2.0 ]; then
plugindir="$(gimptool-2.0 --gimpplugindir)/plug-ins"
else
die "Can't find GIMP plugin directory."
fi
dodir "${plugindir}"
dosym /usr/bin/iscan "${plugindir}"
fi
# install desktop entry
if use X; then
make_desktop_entry iscan "Image Scan! for Linux ${PV}" scanner
fi
}
pkg_postinst() {
local i
local DLL_CONF="/etc/sane.d/dll.conf"
local EPKOWA_CONF="/etc/sane.d/epkowa.conf"
elog
if grep -q "^[ \t]*\<epkowa\>" ${DLL_CONF}; then
elog "Please edit ${EPKOWA_CONF} to suit your needs."
elif grep -q "\<epkowa\>" ${DLL_CONF}; then
elog "Hint: to enable the backend, add 'epkowa' to ${DLL_CONF}"
elog "Then edit ${EPKOWA_CONF} to suit your needs."
else
echo "epkowa" >> ${DLL_CONF}
elog "A new entry 'epkowa' was added to ${DLL_CONF}"
elog "Please edit ${EPKOWA_CONF} to suit your needs."
fi
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in media-gfx/iscan: ChangeLog iscan-2.26.2.ebuild
@ 2011-09-30 17:58 Samuli Suominen (ssuominen)
0 siblings, 0 replies; 2+ messages in thread
From: Samuli Suominen (ssuominen) @ 2011-09-30 17:58 UTC (permalink / raw
To: gentoo-commits
ssuominen 11/09/30 17:58:25
Modified: ChangeLog iscan-2.26.2.ebuild
Log:
Fix building with libpng15 wrt #383799 by Ian Stakenvicius (patch pending upstream review)
(Portage version: 2.2.0_alpha59/cvs/Linux x86_64)
Revision Changes Path
1.43 media-gfx/iscan/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/iscan/ChangeLog?rev=1.43&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/iscan/ChangeLog?rev=1.43&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/iscan/ChangeLog?r1=1.42&r2=1.43
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/iscan/ChangeLog,v
retrieving revision 1.42
retrieving revision 1.43
diff -u -r1.42 -r1.43
--- ChangeLog 23 Apr 2011 18:26:30 -0000 1.42
+++ ChangeLog 30 Sep 2011 17:58:25 -0000 1.43
@@ -1,6 +1,11 @@
# ChangeLog for media-gfx/iscan
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/iscan/ChangeLog,v 1.42 2011/04/23 18:26:30 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/iscan/ChangeLog,v 1.43 2011/09/30 17:58:25 ssuominen Exp $
+
+ 30 Sep 2011; Samuli Suominen <ssuominen@gentoo.org> iscan-2.26.2.ebuild,
+ +files/iscan-2.26.2-libpng15.patch:
+ Fix building with libpng15 wrt #383799 by Ian Stakenvicius (patch pending
+ upstream review)
23 Apr 2011; Diego E. Pettenò <flameeyes@gentoo.org> iscan-2.26.2.ebuild:
Drop dependency over libieee1284 (no longer used by iscan), add missing
1.3 media-gfx/iscan/iscan-2.26.2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/iscan/iscan-2.26.2.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/iscan/iscan-2.26.2.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/iscan/iscan-2.26.2.ebuild?r1=1.2&r2=1.3
Index: iscan-2.26.2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/iscan/iscan-2.26.2.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- iscan-2.26.2.ebuild 23 Apr 2011 18:26:30 -0000 1.2
+++ iscan-2.26.2.ebuild 30 Sep 2011 17:58:25 -0000 1.3
@@ -1,6 +1,6 @@
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/iscan/iscan-2.26.2.ebuild,v 1.2 2011/04/23 18:26:30 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/iscan/iscan-2.26.2.ebuild,v 1.3 2011/09/30 17:58:25 ssuominen Exp $
EAPI="2"
@@ -79,8 +79,9 @@
-e "s:\(PKG_CHECK_MODULES(GDK_IMLIB,.*)\):#\1:g" configure.ac
fi
- epatch "${FILESDIR}/iscan-2.25.0-drop-ltdl.patch"
- epatch "${FILESDIR}/iscan-2.25.0-fix-g++-test.patch"
+ epatch "${FILESDIR}"/iscan-2.25.0-drop-ltdl.patch
+ epatch "${FILESDIR}"/iscan-2.25.0-fix-g++-test.patch
+ epatch "${FILESDIR}"/iscan-2.26.2-libpng15.patch
eautoreconf
}
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2011-09-30 17:58 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-04-03 0:17 [gentoo-commits] gentoo-x86 commit in media-gfx/iscan: ChangeLog iscan-2.26.2.ebuild Stefan Briesenick (sbriesen)
-- strict thread matches above, loose matches on Subject: below --
2011-09-30 17:58 Samuli Suominen (ssuominen)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox