[gentoo-commits] gentoo-x86 commit in app-pda/libopensync: ChangeLog libopensync-0.39-r1.ebuild libopensync-0.39.ebuild

[gentoo-commits] gentoo-x86 commit in app-pda/libopensync: ChangeLog libopensync-0.39-r1.ebuild libopensync-0.39.ebuild

[Ryan Hill (dirtyepic)]

dirtyepic    11/02/12 03:51:19

  Modified:             ChangeLog
  Added:                libopensync-0.39-r1.ebuild
  Removed:              libopensync-0.39.ebuild
  Log:
  Revision bump, remove broken version.
    - fix dependencies (bug #354407)
    - use CMake native module for FindPythonLibs (bug #276220 with thanks
    to John W Eckhart)
    - support multiabi python (bug #311763) and fix bindings getting built
    with USE="-python"
    - drop test USE flag since tests are still restricted
    - port to EAPI 3
  
  (Portage version: 2.2.0_alpha23/cvs/Linux x86_64)

Revision  Changes    Path
1.38                 app-pda/libopensync/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/libopensync/ChangeLog?rev=1.38&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/libopensync/ChangeLog?rev=1.38&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/libopensync/ChangeLog?r1=1.37&r2=1.38

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-pda/libopensync/ChangeLog,v
retrieving revision 1.37
retrieving revision 1.38
diff -u -r1.37 -r1.38
--- ChangeLog	27 Sep 2010 13:07:35 -0000	1.37
+++ ChangeLog	12 Feb 2011 03:51:19 -0000	1.38
@@ -1,6 +1,19 @@
 # ChangeLog for app-pda/libopensync
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-pda/libopensync/ChangeLog,v 1.37 2010/09/27 13:07:35 flameeyes Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-pda/libopensync/ChangeLog,v 1.38 2011/02/12 03:51:19 dirtyepic Exp $
+
+*libopensync-0.39-r1 (12 Feb 2011)
+
+  12 Feb 2011; Ryan Hill <dirtyepic@gentoo.org> -libopensync-0.39.ebuild,
+  +libopensync-0.39-r1.ebuild:
+  Revision bump, remove broken version.
+    - fix dependencies (bug #354407)
+    - use CMake native module for FindPythonLibs (bug #276220 with thanks
+	  to John W Eckhart)
+    - support multiabi python (bug #311763) and fix bindings getting built
+	  with USE="-python"
+    - drop test USE flag since tests are still restricted
+    - port to EAPI 3
 
   27 Sep 2010; Diego E. Pettenò <flameeyes@gentoo.org>
   -libopensync-0.38.ebuild:



1.1                  app-pda/libopensync/libopensync-0.39-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/libopensync/libopensync-0.39-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/libopensync/libopensync-0.39-r1.ebuild?rev=1.1&content-type=text/plain

Index: libopensync-0.39-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-pda/libopensync/libopensync-0.39-r1.ebuild,v 1.1 2011/02/12 03:51:19 dirtyepic Exp $

EAPI="3"

PYTHON_DEPEND="python? 2:2.5"
SUPPORT_PYTHON_ABIS="1"

inherit cmake-utils python

DESCRIPTION="OpenSync synchronisation framework library"
HOMEPAGE="http://www.opensync.org/"
SRC_URI="http://www.opensync.org/download/releases/${PV}/${P}.tar.bz2"

KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
SLOT="0"
LICENSE="LGPL-2.1"
IUSE="doc python" # test

RDEPEND="dev-db/sqlite:3
	>=dev-libs/glib-2.12:2
	dev-libs/libxml2
	dev-libs/libxslt"

DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.9.0
	doc?	( app-doc/doxygen
			  media-gfx/graphviz )
	python?	( >=dev-lang/swig-1.3.17 )"
#	test?	( >=dev-libs/check-0.9.2 )"

# 14% tests passed, 275 tests failed out of 321
RESTRICT="test"

DOCS="AUTHORS CODING ChangeLog README"

RESTRICT_PYTHON_ABIS="3.*"

#CMAKE_VERBOSE="1"

src_prepare() {
	# Has hardcoded python versions, use the module shipped with cmake instead
	# bug #276220
	rm "${S}"/cmake/modules/FindPythonLibs.cmake

	use python && python_copy_sources
}

src_configure() {
	local mycmakeargs="
		-DCMAKE_SKIP_RPATH=ON
		$(cmake-utils_use_build doc DOCUMENTATION)
		$(cmake-utils_use_enable python WRAPPER)
		$(cmake-utils_use python OPENSYNC_PYTHONBINDINGS)
		$(cmake-utils_use test OPENSYNC_UNITTESTS)"

	do_configure() {
		if use python; then
			CMAKE_BUILD_DIR="${WORKDIR}/${P}-${PYTHON_ABI}"
			CMAKE_USE_DIR="${CMAKE_BUILD_DIR}"
			# since we're using cmake's FindPythonLibs PYTHON_VERSION is
			# not defined
			sed -i -e "s:\${PYTHON_VERSION}:${PYTHON_ABI}:g" \
				"${CMAKE_BUILD_DIR}"/wrapper/CMakeLists.txt
		fi
		cmake-utils_src_configure || die
	}

	use python \
		&& python_execute_function -s do_configure \
		|| do_configure
}

src_compile() {
	do_compile() {
		if use python; then
			CMAKE_BUILD_DIR="${WORKDIR}/${P}-${PYTHON_ABI}"
			CMAKE_USE_DIR="${CMAKE_BUILD_DIR}"
		fi
		cmake-utils_src_compile || die
	}

	use python \
		&& python_execute_function -s do_compile \
		|| do_compile

	if use doc ; then
		cmake-utils_src_make DoxygenDoc || die
	fi
}

# TODO - fix
src_test() {
	pushd "${CMAKE_BUILD_DIR}" > /dev/null

	if ! LD_LIBRARY_PATH="${CMAKE_BUILD_DIR}/opensync/" emake -j1 test ; then
		die "Make test failed. See above for details."
	fi

	popd > /dev/null
}

src_install() {
	do_install() {
		if use python; then
			CMAKE_BUILD_DIR="${WORKDIR}/${P}-${PYTHON_ABI}"
			CMAKE_USE_DIR="${CMAKE_BUILD_DIR}"
		fi
		cmake-utils_src_install || die
	}

	use python \
		&& python_execute_function -s do_install \
		|| do_install

	if use doc; then
		cd "${CMAKE_BUILD_DIR}"
		dohtml docs/html/* || die
	fi
}

pkg_postinst() {
	einfo "For >=app-pda/libopensync-0.39 use app-pda/osynctool instead of"
	einfo "the older app-pda/msynctool."
}