* [gentoo-commits] gentoo-x86 commit in dev-ruby/rcairo: ChangeLog rcairo-1.10.0.ebuild
@ 2011-01-22 8:07 Hans de Graaff (graaff)
0 siblings, 0 replies; only message in thread
From: Hans de Graaff (graaff) @ 2011-01-22 8:07 UTC (permalink / raw
To: gentoo-commits
graaff 11/01/22 08:07:31
Modified: ChangeLog
Added: rcairo-1.10.0.ebuild
Log:
Version bump, fixing bug 339604. Exclude one failing test from test suite.
(Portage version: 2.1.9.25/cvs/Linux x86_64)
Revision Changes Path
1.48 dev-ruby/rcairo/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/rcairo/ChangeLog?rev=1.48&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/rcairo/ChangeLog?rev=1.48&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/rcairo/ChangeLog?r1=1.47&r2=1.48
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/ChangeLog,v
retrieving revision 1.47
retrieving revision 1.48
diff -u -r1.47 -r1.48
--- ChangeLog 7 Jan 2011 15:03:59 -0000 1.47
+++ ChangeLog 22 Jan 2011 08:07:31 -0000 1.48
@@ -1,6 +1,11 @@
# ChangeLog for dev-ruby/rcairo
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/ChangeLog,v 1.47 2011/01/07 15:03:59 graaff Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/ChangeLog,v 1.48 2011/01/22 08:07:31 graaff Exp $
+
+*rcairo-1.10.0 (22 Jan 2011)
+
+ 22 Jan 2011; Hans de Graaff <graaff@gentoo.org> +rcairo-1.10.0.ebuild:
+ Version bump, fixing bug 339604. Exclude one failing test from test suite.
07 Jan 2011; Hans de Graaff <graaff@gentoo.org> rcairo-1.8.1.ebuild:
Use proper call to install gemspec now that the eclass changed interface.
1.1 dev-ruby/rcairo/rcairo-1.10.0.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/rcairo/rcairo-1.10.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/rcairo/rcairo-1.10.0.ebuild?rev=1.1&content-type=text/plain
Index: rcairo-1.10.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/rcairo-1.10.0.ebuild,v 1.1 2011/01/22 08:07:31 graaff Exp $
EAPI=2
# ruby19 → fails, and even crashes Ruby
# jruby → cannot work, it's a compiled extension
USE_RUBY="ruby18"
RUBY_FAKEGEM_NAME="cairo"
# Documentation depends on files that are not distributed.
RUBY_FAKEGEM_TASK_DOC=""
# Depends on test-unit-2 which is currently masked.
RUBY_FAKEGEM_TASK_TEST=""
RUBY_FAKEGEM_DOCDIR="doc"
RUBY_FAKEGEM_EXTRADOC="AUTHORS NEWS"
inherit multilib ruby-fakegem
DESCRIPTION="Ruby bindings for cairo"
HOMEPAGE="http://cairographics.org/rcairo/"
IUSE=""
SLOT="0"
LICENSE="|| ( Ruby GPL-2 )"
KEYWORDS="~amd64 ~ia64 ~sparc ~x86"
RDEPEND="${RDEPEND}
>=x11-libs/cairo-1.2.0[svg]"
DEPEND="${DEPEND}
>=x11-libs/cairo-1.2.0[svg]
dev-util/pkgconfig"
ruby_add_bdepend "test? ( >=dev-ruby/test-unit-2.1.0-r1:2 )"
each_ruby_prepare() {
# Remove a failing test for the new recording surface. It's not
# clear if this is a test failure or not, but we need to move on
# with cairo 1.10.
rm test/test_recording_surface.rb || die
}
each_ruby_configure() {
${RUBY} extconf.rb || die "extconf failed"
}
each_ruby_compile() {
emake || die "make failed"
# again, try to make it more standard, to install it more easily.
cp ext/cairo/cairo$(get_modname) lib/ || die
}
each_ruby_test() {
# don't rely on the Rakefile because it's a mess to load with
# their hierarchy, do it manually.
${RUBY} -Ilib -r ./test/cairo-test-utils.rb \
-e 'gem "test-unit"; require "test/unit"; Dir.glob("test/**/test_*.rb") {|f| load f}' || die "tests failed"
}
all_ruby_install() {
all_fakegem_install
insinto /usr/share/doc/${PF}/samples
doins -r samples/* || die "Cannot install sample files."
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-01-22 8:07 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-01-22 8:07 [gentoo-commits] gentoo-x86 commit in dev-ruby/rcairo: ChangeLog rcairo-1.10.0.ebuild Hans de Graaff (graaff)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox