[gentoo-commits] gentoo-x86 commit in net-print/hplip: hplip-3.10.9-r1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in net-print/hplip: hplip-3.10.9-r1.ebuild ChangeLog

[Daniel Pielmeier (billie)]

billie      11/01/20 18:36:23

  Modified:             ChangeLog
  Added:                hplip-3.10.9-r1.ebuild
  Log:
  Revision bump to fix security bug #352085.
  
  (Portage version: 2.1.9.25/cvs/Linux i686)

Revision  Changes    Path
1.174                net-print/hplip/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/ChangeLog?rev=1.174&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/ChangeLog?rev=1.174&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/ChangeLog?r1=1.173&r2=1.174

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-print/hplip/ChangeLog,v
retrieving revision 1.173
retrieving revision 1.174
diff -u -r1.173 -r1.174
--- ChangeLog	10 Jan 2011 20:43:58 -0000	1.173
+++ ChangeLog	20 Jan 2011 18:36:23 -0000	1.174
@@ -1,6 +1,12 @@
 # ChangeLog for net-print/hplip
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/ChangeLog,v 1.173 2011/01/10 20:43:58 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/ChangeLog,v 1.174 2011/01/20 18:36:23 billie Exp $
+
+*hplip-3.10.9-r1 (20 Jan 2011)
+
+  20 Jan 2011; Daniel Pielmeier <billie@gentoo.org> +hplip-3.10.9-r1.ebuild,
+  +files/hplip-3.10.9-cve-2010-4267.patch:
+  Revision bump to fix security bug #352085.
 
   10 Jan 2011; Brent Baude <ranger@gentoo.org> hplip-3.10.9.ebuild:
   stable ppc, bug 345457



1.1                  net-print/hplip/hplip-3.10.9-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/hplip-3.10.9-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/hplip-3.10.9-r1.ebuild?rev=1.1&content-type=text/plain

Index: hplip-3.10.9-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/hplip-3.10.9-r1.ebuild,v 1.1 2011/01/20 18:36:23 billie Exp $

EAPI=2

PYTHON_DEPEND="!minimal? 2"
PYTHON_USE_WITH="threads xml"
PYTHON_USE_WITH_OPT="!minimal"

inherit fdo-mime linux-info python autotools

DESCRIPTION="HP Linux Imaging and Printing System. Includes printer, scanner, fax drivers and service tools."
HOMEPAGE="http://hplipopensource.com/hplip-web/index.html"
SRC_URI="mirror://sourceforge/hplip/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"

# zeroconf does not work properly with >=cups-1.4. thus support for it is also disabled in hplip.
IUSE="doc fax +hpcups hpijs kde libnotify minimal parport policykit qt4 scanner snmp static-ppds -udev-acl X"

COMMON_DEPEND="
	virtual/jpeg
	hpijs? ( >=net-print/foomatic-filters-3.0.20080507[cups] )
	udev-acl? ( >=sys-fs/udev-145[extras] )
	snmp? (
		net-analyzer/net-snmp
		dev-libs/openssl
	)
	!minimal? (
		net-print/cups
		virtual/libusb:0
		scanner? ( >=media-gfx/sane-backends-1.0.19-r1 )
		fax? ( sys-apps/dbus )
	)"

DEPEND="${COMMON_DEPEND}
	dev-util/pkgconfig"

RDEPEND="${COMMON_DEPEND}
	>=app-text/ghostscript-gpl-8.71-r3
	!static-ppds? ( || ( >=net-print/cups-1.4.0 net-print/cupsddk ) )
	!minimal? (
		dev-python/pygobject
		kernel_linux? ( >=sys-fs/udev-114 )
		scanner? (
			dev-python/imaging
			X? ( || (
				kde? ( kde-misc/skanlite )
				media-gfx/xsane
				media-gfx/sane-frontends
			) )
		)
		fax? (
			dev-python/reportlab
			dev-python/dbus-python
		)
		qt4? (
			dev-python/PyQt4[dbus,X]
			libnotify? (
				dev-python/notify-python
			)
			policykit? (
				sys-auth/polkit
			)
		)
	)"

CONFIG_CHECK="~PARPORT ~PPDEV"
ERROR_PARPORT="Please make sure parallel port support is enabled in your kernel (PARPORT and PPDEV)."

pkg_setup() {
	if ! use minimal; then
		python_set_active_version 2
		python_pkg_setup
	fi

	! use qt4 && ewarn "You need USE=qt4 for the hplip GUI."

	use scanner && ! use X && ewarn "You need USE=X for the scanner GUI."

	if ! use hpcups && ! use hpijs ; then
		ewarn "Installing neither hpcups (USE=-hpcups) nor hpijs (USE=-hpijs) driver,"
		ewarn "which is probably not what you want."
		ewarn "You will almost certainly not be able to print."
		ewarn "Recommended USE flags: USE=\"hpcups -hpijs\")."
	fi

	if use minimal ; then
		ewarn "Installing driver portions only, make sure you know what you are doing."
		ewarn "Depending on the USE flags set for hpcups and/or hpijs the appropiate"
		ewarn "drivers are installed."
	else
		use parport && linux-info_pkg_setup
	fi
}

src_prepare() {
	python_convert_shebangs -q -r 2 .

	# Test for Gentoo bug #345725
	#sed -i -e "s|/etc/udev/rules.d|/$(get_libdir)/udev/rules.d|" \
	#	$(find ./ -type f -exec grep -l '/etc/udev/rules.d' '{}' '+') \
	#	|| die "sed udev rules"

	# Do not install desktop files if there is no gui
	# Upstream bug: https://bugs.launchpad.net/hplip/+bug/452113
	epatch "${FILESDIR}"/${PN}-3.9.10-desktop.patch

	# Browser detection through xdg-open
	# Upstream bug: https://bugs.launchpad.net/hplip/+bug/482674
	epatch "${FILESDIR}"/${PN}-3.9.10-browser.patch

	# Use cups-config when checking for cupsddk
	# Upstream bug: https://bugs.launchpad.net/hplip/+bug/483136
	epatch "${FILESDIR}"/${PN}-3.9.12-cupsddk.patch

	# Htmldocs are not installed under docdir/html so enable htmldir configure switch
	# Upstream bug: https://bugs.launchpad.net/hplip/+bug/483217
	epatch "${FILESDIR}"/${PN}-3.9.10-htmldir.patch

	# Increase systray check timeout for slower machines
	# Upstream bug: https://bugs.launchpad.net/hplip/+bug/335662
	epatch "${FILESDIR}"/${PN}-3.9.12-systray.patch

	# SYSFS deprecated but kept upstream for compatibility reasons
	# Upstream bug: https://bugs.launchpad.net/hplip/+bug/346390
	epatch "${FILESDIR}"/${PN}-3.10.5-udev-attrs.patch

	# CVE-2010-4267 SNMP Response Processing Buffer Overflow Vulnerability
	# http://secunia.com/advisories/42956/
	# https://bugzilla.redhat.com/show_bug.cgi?id=662740
	epatch "${FILESDIR}"/${P}-cve-2010-4267.patch

	# Force recognition of Gentoo distro by hp-check
	sed -i \
		-e "s:file('/etc/issue', 'r').read():'Gentoo':" \
		installer/core_install.py || die

	# Use system foomatic-rip for hpijs driver instead of foomatic-rip-hplip
	# The hpcups driver does not use foomatic-rip
	local i
	for i in ppd/hpijs/*.ppd.gz
	do
		rm -f ${i}.temp
		gunzip -c ${i} | sed 's/foomatic-rip-hplip/foomatic-rip/g' | gzip > ${i}.temp || die
		mv ${i}.temp ${i}
	done

	eautoreconf
}

src_configure() {
	local gui_build myconf drv_build minimal_build

	if use qt4 ; then
		gui_build="--enable-gui-build --enable-qt4 --disable-qt3"
		if use policykit ; then
			myconf="--enable-policykit"
		else
			myconf="--disable-policykit"
		fi
	else
		gui_build="--disable-gui-build --disable-qt3 --disable-qt4"
	fi

	if use fax || use qt4 ; then
		myconf="${myconf} --enable-dbus-build"
	else
		myconf="${myconf} --disable-dbus-build"
	fi

	if use hpcups ; then
		drv_build="$(use_enable hpcups hpcups-install)"
		if use static-ppds ; then
			drv_build="${drv_build} --enable-cups-ppd-install"
			drv_build="${drv_build} --disable-cups-drv-install"
		else
			drv_build="${drv_build} --enable-cups-drv-install"
			drv_build="${drv_build} --disable-cups-ppd-install"
		fi
	else
		drv_build="--disable-hpcups-install --disable-cups-drv-install"
		drv_build="${drv_build} --disable-cups-ppd-install"
	fi

	if use hpijs ; then
		drv_build="${drv_build} $(use_enable hpijs hpijs-install)"
		if use static-ppds ; then
			drv_build="${drv_build} --enable-foomatic-ppd-install"
			drv_build="${drv_build} --disable-foomatic-drv-install"
		else
			drv_build="${drv_build} --enable-foomatic-drv-install"
			drv_build="${drv_build} --disable-foomatic-ppd-install"
		fi
	else
		drv_build="${drv_build} --disable-hpijs-install"
		drv_build="${drv_build} --disable-foomatic-drv-install"
		drv_build="${drv_build} --disable-foomatic-ppd-install"
	fi

	if use minimal ; then
		if use hpijs ; then
			minimal_build="--enable-hpijs-only-build"
		else
			minimal_build="--disable-hpijs-only-build"
		fi
		if use hpcups ; then
			minimal_build="${minimal_build} --enable-hpcups-only-build"
		else
			minimal_build="${minimal_build} --disable-hpcups-only-build"
		fi
	fi

	econf \
		--disable-dependency-tracking \
		--disable-cups11-build \
		--disable-lite-build \
		--disable-foomatic-rip-hplip-install \
		--disable-shadow-build \
		--with-cupsbackenddir=$(cups-config --serverbin)/backend \
		--with-cupsfilterdir=$(cups-config --serverbin)/filter \
		--with-docdir=/usr/share/doc/${PF} \
		--with-htmldir=/usr/share/doc/${PF}/html \
		${gui_build} \
		${myconf} \
		${drv_build} \
		${minimal_build} \
		$(use_enable doc doc-build) \
		$(use_enable fax fax-build) \
		$(use_enable parport pp-build) \
		$(use_enable scanner scan-build) \
		$(use_enable snmp network-build) \
		$(use_enable udev-acl udev-acl-rules)
}

src_install() {
	emake DESTDIR="${D}" install || die

	# Installed by sane-backends
	# Gentoo Bug: #201023
	rm -f "${D}"/etc/sane.d/dll.conf || die
}

pkg_postinst() {
	use !minimal && python_mod_optimize /usr/share/${PN}
	fdo-mime_desktop_database_update

	elog "You should run hp-setup as root if you are installing hplip for the first time,"
	elog "and may also need to run it if you are upgrading from an earlier version."
	elog
	elog "If your device is connected using USB, users will need to be in the lp group to"
	elog "access it."
	elog
	elog "Starting with versions of hplip >=3.9.8 mDNS is the default network search"
	elog "mechanism. To make use of it you need to activate the zeroconf flag on cups."
	elog "If you prefer the SLP method you have to choose this when configuring the"
	elog "device."
	elog "Note: For cups-1.4.x SLP is the only supported method as mDNS (zeroconf) is not"
	elog "available here."

}

pkg_postrm() {
	use !minimal && python_mod_cleanup /usr/share/${PN}
	fdo-mime_desktop_database_update
}

[gentoo-commits] gentoo-x86 commit in net-print/hplip: hplip-3.10.9-r1.ebuild ChangeLog

[Markos Chandras (hwoarang)]

hwoarang    11/01/20 21:26:31

  Modified:             hplip-3.10.9-r1.ebuild ChangeLog
  Log:
  Stable on amd64 wrt bug #352085
  
  (Portage version: 2.1.9.33/cvs/Linux x86_64)

Revision  Changes    Path
1.2                  net-print/hplip/hplip-3.10.9-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/hplip-3.10.9-r1.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/hplip-3.10.9-r1.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/hplip-3.10.9-r1.ebuild?r1=1.1&r2=1.2

Index: hplip-3.10.9-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-print/hplip/hplip-3.10.9-r1.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- hplip-3.10.9-r1.ebuild	20 Jan 2011 18:36:23 -0000	1.1
+++ hplip-3.10.9-r1.ebuild	20 Jan 2011 21:26:31 -0000	1.2
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/hplip-3.10.9-r1.ebuild,v 1.1 2011/01/20 18:36:23 billie Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/hplip-3.10.9-r1.ebuild,v 1.2 2011/01/20 21:26:31 hwoarang Exp $
 
 EAPI=2
 
@@ -16,7 +16,7 @@
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+KEYWORDS="amd64 ~arm ~ppc ~ppc64 ~x86"
 
 # zeroconf does not work properly with >=cups-1.4. thus support for it is also disabled in hplip.
 IUSE="doc fax +hpcups hpijs kde libnotify minimal parport policykit qt4 scanner snmp static-ppds -udev-acl X"



1.175                net-print/hplip/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/ChangeLog?rev=1.175&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/ChangeLog?rev=1.175&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/ChangeLog?r1=1.174&r2=1.175

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-print/hplip/ChangeLog,v
retrieving revision 1.174
retrieving revision 1.175
diff -u -r1.174 -r1.175
--- ChangeLog	20 Jan 2011 18:36:23 -0000	1.174
+++ ChangeLog	20 Jan 2011 21:26:31 -0000	1.175
@@ -1,6 +1,9 @@
 # ChangeLog for net-print/hplip
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/ChangeLog,v 1.174 2011/01/20 18:36:23 billie Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/ChangeLog,v 1.175 2011/01/20 21:26:31 hwoarang Exp $
+
+  20 Jan 2011; Markos Chandras <hwoarang@gentoo.org> hplip-3.10.9-r1.ebuild:
+  Stable on amd64 wrt bug #352085
 
 *hplip-3.10.9-r1 (20 Jan 2011)
 

[gentoo-commits] gentoo-x86 commit in net-print/hplip: hplip-3.10.9-r1.ebuild ChangeLog

[Kacper Kowalik (xarthisius)]

xarthisius    11/01/21 08:29:01

  Modified:             hplip-3.10.9-r1.ebuild ChangeLog
  Log:
  ppc/ppc64 stable wrt #352085
  
  (Portage version: 2.1.9.25/cvs/Linux ppc64)

Revision  Changes    Path
1.3                  net-print/hplip/hplip-3.10.9-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/hplip-3.10.9-r1.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/hplip-3.10.9-r1.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/hplip-3.10.9-r1.ebuild?r1=1.2&r2=1.3

Index: hplip-3.10.9-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-print/hplip/hplip-3.10.9-r1.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- hplip-3.10.9-r1.ebuild	20 Jan 2011 21:26:31 -0000	1.2
+++ hplip-3.10.9-r1.ebuild	21 Jan 2011 08:29:01 -0000	1.3
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/hplip-3.10.9-r1.ebuild,v 1.2 2011/01/20 21:26:31 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/hplip-3.10.9-r1.ebuild,v 1.3 2011/01/21 08:29:01 xarthisius Exp $
 
 EAPI=2
 
@@ -16,7 +16,7 @@
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS="amd64 ~arm ~ppc ~ppc64 ~x86"
+KEYWORDS="amd64 ~arm ppc ppc64 ~x86"
 
 # zeroconf does not work properly with >=cups-1.4. thus support for it is also disabled in hplip.
 IUSE="doc fax +hpcups hpijs kde libnotify minimal parport policykit qt4 scanner snmp static-ppds -udev-acl X"



1.176                net-print/hplip/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/ChangeLog?rev=1.176&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/ChangeLog?rev=1.176&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/ChangeLog?r1=1.175&r2=1.176

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-print/hplip/ChangeLog,v
retrieving revision 1.175
retrieving revision 1.176
diff -u -r1.175 -r1.176
--- ChangeLog	20 Jan 2011 21:26:31 -0000	1.175
+++ ChangeLog	21 Jan 2011 08:29:01 -0000	1.176
@@ -1,6 +1,10 @@
 # ChangeLog for net-print/hplip
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/ChangeLog,v 1.175 2011/01/20 21:26:31 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/ChangeLog,v 1.176 2011/01/21 08:29:01 xarthisius Exp $
+
+  21 Jan 2011; Kacper Kowalik <xarthisius@gentoo.org>
+  hplip-3.10.9-r1.ebuild:
+  ppc/ppc64 stable wrt #352085
 
   20 Jan 2011; Markos Chandras <hwoarang@gentoo.org> hplip-3.10.9-r1.ebuild:
   Stable on amd64 wrt bug #352085

[gentoo-commits] gentoo-x86 commit in net-print/hplip: hplip-3.10.9-r1.ebuild ChangeLog

[Christian Faulhammer (fauli)]

fauli       11/01/21 13:44:04

  Modified:             hplip-3.10.9-r1.ebuild ChangeLog
  Log:
  stable x86, security bug 352085
  
  (Portage version: 2.1.9.34/cvs/Linux i686)

Revision  Changes    Path
1.4                  net-print/hplip/hplip-3.10.9-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/hplip-3.10.9-r1.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/hplip-3.10.9-r1.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/hplip-3.10.9-r1.ebuild?r1=1.3&r2=1.4

Index: hplip-3.10.9-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-print/hplip/hplip-3.10.9-r1.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- hplip-3.10.9-r1.ebuild	21 Jan 2011 08:29:01 -0000	1.3
+++ hplip-3.10.9-r1.ebuild	21 Jan 2011 13:44:04 -0000	1.4
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/hplip-3.10.9-r1.ebuild,v 1.3 2011/01/21 08:29:01 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/hplip-3.10.9-r1.ebuild,v 1.4 2011/01/21 13:44:04 fauli Exp $
 
 EAPI=2
 
@@ -16,7 +16,7 @@
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS="amd64 ~arm ppc ppc64 ~x86"
+KEYWORDS="amd64 ~arm ppc ppc64 x86"
 
 # zeroconf does not work properly with >=cups-1.4. thus support for it is also disabled in hplip.
 IUSE="doc fax +hpcups hpijs kde libnotify minimal parport policykit qt4 scanner snmp static-ppds -udev-acl X"



1.177                net-print/hplip/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/ChangeLog?rev=1.177&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/ChangeLog?rev=1.177&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/ChangeLog?r1=1.176&r2=1.177

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-print/hplip/ChangeLog,v
retrieving revision 1.176
retrieving revision 1.177
diff -u -r1.176 -r1.177
--- ChangeLog	21 Jan 2011 08:29:01 -0000	1.176
+++ ChangeLog	21 Jan 2011 13:44:04 -0000	1.177
@@ -1,6 +1,10 @@
 # ChangeLog for net-print/hplip
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/ChangeLog,v 1.176 2011/01/21 08:29:01 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/ChangeLog,v 1.177 2011/01/21 13:44:04 fauli Exp $
+
+  21 Jan 2011; Christian Faulhammer <fauli@gentoo.org>
+  hplip-3.10.9-r1.ebuild:
+  stable x86, security bug 352085
 
   21 Jan 2011; Kacper Kowalik <xarthisius@gentoo.org>
   hplip-3.10.9-r1.ebuild: