* [gentoo-commits] gentoo-x86 commit in x11-libs/cairo: ChangeLog cairo-1.10.2.ebuild cairo-9999.ebuild cairo-1.8.8.ebuild cairo-1.10.0-r3.ebuild cairo-1.8.8-r1.ebuild
@ 2011-01-11 18:58 Tomas Chvatal (scarabeus)
0 siblings, 0 replies; only message in thread
From: Tomas Chvatal (scarabeus) @ 2011-01-11 18:58 UTC (permalink / raw
To: gentoo-commits
scarabeus 11/01/11 18:58:37
Modified: ChangeLog cairo-9999.ebuild
Added: cairo-1.10.2.ebuild
Removed: cairo-1.8.8.ebuild cairo-1.10.0-r3.ebuild
cairo-1.8.8-r1.ebuild
Log:
Version bump fixes bug #351319. Drop older.
(Portage version: 2.2.0_alpha10/cvs/Linux x86_64)
Revision Changes Path
1.266 x11-libs/cairo/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/ChangeLog?rev=1.266&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/ChangeLog?rev=1.266&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/ChangeLog?r1=1.265&r2=1.266
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/cairo/ChangeLog,v
retrieving revision 1.265
retrieving revision 1.266
diff -u -r1.265 -r1.266
--- ChangeLog 6 Nov 2010 15:34:56 -0000 1.265
+++ ChangeLog 11 Jan 2011 18:58:37 -0000 1.266
@@ -1,6 +1,15 @@
# ChangeLog for x11-libs/cairo
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/ChangeLog,v 1.265 2010/11/06 15:34:56 scarabeus Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/ChangeLog,v 1.266 2011/01/11 18:58:37 scarabeus Exp $
+
+*cairo-1.10.2 (11 Jan 2011)
+
+ 11 Jan 2011; Tomáš Chvátal <scarabeus@gentoo.org> -cairo-1.8.8.ebuild,
+ -cairo-1.8.8-r1.ebuild, -files/cairo-1.8.8-libpng14.patch,
+ -cairo-1.10.0-r3.ebuild, -files/cairo-1.10.0-buggy_gradients.patch,
+ -files/cairo-1.10.0-install-sh.patch, +cairo-1.10.2.ebuild,
+ cairo-9999.ebuild:
+ Version bump fixes bug #351319. Drop older.
06 Nov 2010; Tomáš Chvátal <scarabeus@gentoo.org> cairo-1.10.0-r3.ebuild,
cairo-9999.ebuild:
1.9 x11-libs/cairo/cairo-9999.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/cairo-9999.ebuild?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/cairo-9999.ebuild?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/cairo-9999.ebuild?r1=1.8&r2=1.9
Index: cairo-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-9999.ebuild,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- cairo-9999.ebuild 6 Nov 2010 15:34:56 -0000 1.8
+++ cairo-9999.ebuild 11 Jan 2011 18:58:37 -0000 1.9
@@ -1,6 +1,6 @@
-# Copyright 1999-2010 Gentoo Foundation
+# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-9999.ebuild,v 1.8 2010/11/06 15:34:56 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-9999.ebuild,v 1.9 2011/01/11 18:58:37 scarabeus Exp $
EAPI=3
@@ -87,6 +87,7 @@
if use X; then
myopts+="
+ --enable-tee=yes
$(use_enable drm)
"
1.1 x11-libs/cairo/cairo-1.10.2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/cairo-1.10.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/cairo-1.10.2.ebuild?rev=1.1&content-type=text/plain
Index: cairo-1.10.2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-1.10.2.ebuild,v 1.1 2011/01/11 18:58:37 scarabeus Exp $
EAPI=3
EGIT_REPO_URI="git://anongit.freedesktop.org/git/cairo"
[[ ${PV} == *9999 ]] && GIT_ECLASS="git"
inherit eutils flag-o-matic autotools ${GIT_ECLASS}
DESCRIPTION="A vector graphics library with cross-device output support"
HOMEPAGE="http://cairographics.org/"
[[ ${PV} == *9999 ]] || SRC_URI="http://cairographics.org/releases/${P}.tar.gz"
LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="X aqua debug directfb doc drm gallium opengl openvg qt4 static-libs +svg xcb"
# Test causes a circular depend on gtk+... since gtk+ needs cairo but test needs gtk+ so we need to block it
RESTRICT="test"
RDEPEND="media-libs/fontconfig
media-libs/freetype:2
media-libs/libpng:0
sys-libs/zlib
>=x11-libs/pixman-0.18.4
directfb? ( dev-libs/DirectFB )
opengl? ( virtual/opengl )
openvg? ( media-libs/mesa[gallium] )
qt4? ( >=x11-libs/qt-gui-4.4:4 )
svg? ( dev-libs/libxml2 )
X? (
>=x11-libs/libXrender-0.6
x11-libs/libXext
x11-libs/libX11
x11-libs/libXft
drm? (
>=sys-fs/udev-136
gallium? ( media-libs/mesa[gallium] )
)
)
xcb? (
x11-libs/libxcb
x11-libs/xcb-util
)"
DEPEND="${RDEPEND}
dev-util/pkgconfig
>=sys-devel/libtool-2
doc? (
>=dev-util/gtk-doc-1.6
~app-text/docbook-xml-dtd-4.2
)
X? (
x11-proto/renderproto
drm? (
x11-proto/xproto
>=x11-proto/xextproto-7.1
)
)"
src_prepare() {
epatch "${FILESDIR}"/${PN}-1.8.8-interix.patch
# Slightly messed build system YAY
if [[ ${PV} == *9999* ]]; then
touch boilerplate/Makefile.am.features
touch src/Makefile.am.features
touch ChangeLog
fi
# We need to run elibtoolize to ensure correct so versioning on FreeBSD
# upgraded to an eautoreconf for the above interix patch.
eautoreconf
}
src_configure() {
local myopts
[[ ${CHOST} == *-interix* ]] && append-flags -D_REENTRANT
# http://bugs.freedesktop.org/show_bug.cgi?id=15463
[[ ${CHOST} == *-solaris* ]] && append-flags -D_POSIX_PTHREAD_SEMANTICS
#gets rid of fbmmx.c inlining warnings
append-flags -finline-limit=1200
if use X; then
myopts+="
--enable-tee=yes
$(use_enable drm)
"
if use drm; then
myopts+="
$(use_enable gallium)
$(use_enable xcb xcb-drm)
"
else
use gallium && ewarn "Gallium use requires drm use enabled. So disabling for now."
myopts+="
--disable-gallium
--disable-xcb-drm
"
fi
else
use drm && ewarn "drm use requires X use enabled. So disabling for now."
myopts+="
--disable-drm
--disable-gallium
--disable-xcb-drm
"
fi
# --disable-xcb-lib:
# do not override good xlib backed by hardforcing rendering over xcb
econf \
--disable-dependency-tracking \
$(use_with X x) \
$(use_enable X xlib) \
$(use_enable X xlib-xrender) \
$(use_enable aqua quartz) \
$(use_enable aqua quartz-image) \
$(use_enable debug test-surfaces) \
$(use_enable directfb) \
$(use_enable doc gtk-doc) \
$(use_enable openvg vg) \
$(use_enable opengl gl) \
$(use_enable qt4 qt) \
$(use_enable static-libs static) \
$(use_enable svg) \
$(use_enable xcb) \
$(use_enable xcb xcb-shm) \
--enable-ft \
--enable-pdf \
--enable-png \
--enable-ps \
--disable-xlib-xcb \
${myopts}
}
src_install() {
# parallel make install fails
emake -j1 DESTDIR="${D}" install || die "Installation failed"
dodoc AUTHORS ChangeLog NEWS README || die
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-01-11 18:58 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-01-11 18:58 [gentoo-commits] gentoo-x86 commit in x11-libs/cairo: ChangeLog cairo-1.10.2.ebuild cairo-9999.ebuild cairo-1.8.8.ebuild cairo-1.10.0-r3.ebuild cairo-1.8.8-r1.ebuild Tomas Chvatal (scarabeus)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox