[gentoo-commits] gentoo-x86 commit in dev-lang/v8: ChangeLog v8-3.0.4.1.ebuild

[gentoo-commits] gentoo-x86 commit in dev-lang/v8: ChangeLog v8-3.0.4.1.ebuild

[PaweA Hajdan (phajdan.jr)]

phajdan.jr    11/01/06 16:07:59

  Modified:             ChangeLog
  Added:                v8-3.0.4.1.ebuild
  Log:
  Version bump for dev channel release. Fails tests.
  
  (Portage version: 2.1.9.25/cvs/Linux i686)

Revision  Changes    Path
1.24                 dev-lang/v8/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/v8/ChangeLog?rev=1.24&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/v8/ChangeLog?rev=1.24&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/v8/ChangeLog?r1=1.23&r2=1.24

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/v8/ChangeLog,v
retrieving revision 1.23
retrieving revision 1.24
diff -u -r1.23 -r1.24
--- ChangeLog	6 Jan 2011 10:11:17 -0000	1.23
+++ ChangeLog	6 Jan 2011 16:07:59 -0000	1.24
@@ -1,6 +1,11 @@
 # ChangeLog for dev-lang/v8
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/v8/ChangeLog,v 1.23 2011/01/06 10:11:17 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/v8/ChangeLog,v 1.24 2011/01/06 16:07:59 phajdan.jr Exp $
+
+*v8-3.0.4.1 (06 Jan 2011)
+
+  06 Jan 2011; Pawel Hajdan jr <phajdan.jr@gentoo.org> +v8-3.0.4.1.ebuild:
+  Version bump for dev channel release. Fails tests.
 
 *v8-3.0.0.1-r1 (06 Jan 2011)
 *v8-2.5.9.6-r1 (06 Jan 2011)



1.1                  dev-lang/v8/v8-3.0.4.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/v8/v8-3.0.4.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/v8/v8-3.0.4.1.ebuild?rev=1.1&content-type=text/plain

Index: v8-3.0.4.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/v8/v8-3.0.4.1.ebuild,v 1.1 2011/01/06 16:07:59 phajdan.jr Exp $

EAPI="2"

inherit eutils flag-o-matic multilib scons-utils toolchain-funcs

DESCRIPTION="Google's open source JavaScript engine"
HOMEPAGE="http://code.google.com/p/v8"
SRC_URI="mirror://gentoo/${P}.tar.gz"
LICENSE="BSD"

SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="readline"

RDEPEND="readline? ( >=sys-libs/readline-6.1 )"
DEPEND="${RDEPEND}"

EXTRA_ESCONS="library=shared soname=on importenv=\"LINKFLAGS\""

pkg_setup() {
	tc-export AR CC CXX RANLIB

	# Make the build respect LDFLAGS.
	export LINKFLAGS="${LDFLAGS}"
}

src_prepare() {
	# Stop -Werror from breaking the build.
	epatch "${FILESDIR}"/${PN}-no-werror-r0.patch

	# Respect the user's CFLAGS, including the optimization level.
	epatch "${FILESDIR}"/${PN}-no-O3-r0.patch

	# Fix a compile error (bug #349794), to be upstreamed.
	epatch "${FILESDIR}"/${PN}-gentoo-bug-349794-r0.patch

	# Backport an upstream bugfix for symbol visibility,
	# see bug #348609.
	epatch "${FILESDIR}"/${PN}-upstream-bug-1016-r0.patch

	# Remove a test that is known to fail:
	# http://groups.google.com/group/v8-users/browse_thread/thread/b8a3f42b5aa18d06
	rm test/mjsunit/debug-script.js || die

	# Remove a test that behaves differently depending on FEATURES="userpriv",
	# see bug #348558.
	rm test/mjsunit/d8-os.js || die
}

src_configure() {
	# GCC issues multiple warnings about strict-aliasing issues in v8 code.
	append-flags -fno-strict-aliasing
}

src_compile() {
	local myconf=""

	# Use target arch detection logic from bug #296917.
	local myarch="$ABI"
	[[ $myarch = "" ]] && myarch="$ARCH"

	if [[ $myarch = amd64 ]] ; then
		myconf+=" arch=x64"
	elif [[ $myarch = x86 ]] ; then
		myconf+=" arch=ia32"
	elif [[ $myarch = arm ]] ; then
		myconf+=" arch=arm"
	else
		die "Failed to determine target arch, got '$myarch'."
	fi

	escons $(use_scons readline console readline dumb) ${myconf} . || die
}

src_install() {
	insinto /usr
	doins -r include || die

	dobin d8 || die

	dolib libv8-${PV}.so || die
	dosym libv8-${PV}.so /usr/$(get_libdir)/libv8.so || die

	dodoc AUTHORS ChangeLog || die
}

src_test() {
	tools/test.py --no-build -p dots --shell d8 || die
}