* [gentoo-commits] gentoo-x86 commit in dev-lang/v8: ChangeLog v8-3.0.0.1.ebuild
@ 2010-12-18 8:58 PaweA Hajdan (phajdan.jr)
0 siblings, 0 replies; only message in thread
From: PaweA Hajdan (phajdan.jr) @ 2010-12-18 8:58 UTC (permalink / raw
To: gentoo-commits
phajdan.jr 10/12/18 08:58:51
Modified: ChangeLog
Added: v8-3.0.0.1.ebuild
Log:
Version bump for dev channel release. Fails tests.
(Portage version: 2.1.9.24/cvs/Linux i686)
Revision Changes Path
1.19 dev-lang/v8/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/v8/ChangeLog?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/v8/ChangeLog?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/v8/ChangeLog?r1=1.18&r2=1.19
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/v8/ChangeLog,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- ChangeLog 14 Dec 2010 15:54:38 -0000 1.18
+++ ChangeLog 18 Dec 2010 08:58:50 -0000 1.19
@@ -1,6 +1,11 @@
# ChangeLog for dev-lang/v8
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/v8/ChangeLog,v 1.18 2010/12/14 15:54:38 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/v8/ChangeLog,v 1.19 2010/12/18 08:58:50 phajdan.jr Exp $
+
+*v8-3.0.0.1 (18 Dec 2010)
+
+ 18 Dec 2010; Pawel Hajdan jr <phajdan.jr@gentoo.org> +v8-3.0.0.1.ebuild:
+ Version bump for dev channel release. Fails tests.
*v8-9999 (14 Dec 2010)
1.1 dev-lang/v8/v8-3.0.0.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/v8/v8-3.0.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/v8/v8-3.0.0.1.ebuild?rev=1.1&content-type=text/plain
Index: v8-3.0.0.1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/v8/v8-3.0.0.1.ebuild,v 1.1 2010/12/18 08:58:50 phajdan.jr Exp $
EAPI="2"
inherit eutils flag-o-matic multilib scons-utils toolchain-funcs
DESCRIPTION="Google's open source JavaScript engine"
HOMEPAGE="http://code.google.com/p/v8"
SRC_URI="mirror://gentoo/${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="readline"
RDEPEND="readline? ( >=sys-libs/readline-6.1 )"
DEPEND="${RDEPEND}"
EXTRA_ESCONS="library=shared soname=on importenv=\"LINKFLAGS\""
pkg_setup() {
tc-export AR CC CXX RANLIB
# Make the build respect LDFLAGS.
export LINKFLAGS="${LDFLAGS}"
}
src_prepare() {
# Stop -Werror from breaking the build.
epatch "${FILESDIR}"/${PN}-no-werror-r0.patch
# Respect the user's CFLAGS, including the optimization level.
epatch "${FILESDIR}"/${PN}-no-O3-r0.patch
# Remove a test that is known to fail:
# http://groups.google.com/group/v8-users/browse_thread/thread/b8a3f42b5aa18d06
rm test/mjsunit/debug-script.js || die
}
src_configure() {
# GCC issues multiple warnings about strict-aliasing issues in v8 code.
append-flags -fno-strict-aliasing
}
src_compile() {
local myconf=""
# Use target arch detection logic from bug #296917.
local myarch="$ABI"
[[ $myarch = "" ]] && myarch="$ARCH"
if [[ $myarch = amd64 ]] ; then
myconf+=" arch=x64"
elif [[ $myarch = x86 ]] ; then
myconf+=" arch=ia32"
elif [[ $myarch = arm ]] ; then
myconf+=" arch=arm"
else
die "Failed to determine target arch, got '$myarch'."
fi
escons $(use_scons readline console readline dumb) ${myconf} . || die
}
src_install() {
insinto /usr
doins -r include || die
dobin d8 || die
dolib libv8-${PV}.so || die
dosym libv8-${PV}.so /usr/$(get_libdir)/libv8.so || die
dodoc AUTHORS ChangeLog || die
}
src_test() {
tools/test.py --no-build -p dots --shell d8 || die
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2010-12-18 8:59 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2010-12-18 8:58 [gentoo-commits] gentoo-x86 commit in dev-lang/v8: ChangeLog v8-3.0.0.1.ebuild PaweA Hajdan (phajdan.jr)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox