* [gentoo-commits] gentoo-x86 commit in net-im/ekg2: metadata.xml ChangeLog ekg2-9999.ebuild
@ 2010-10-08 13:53 Michal Gorny (mgorny)
0 siblings, 0 replies; 2+ messages in thread
From: Michal Gorny (mgorny) @ 2010-10-08 13:53 UTC (permalink / raw
To: gentoo-commits
mgorny 10/10/08 13:53:08
Added: metadata.xml ChangeLog ekg2-9999.ebuild
Log:
Re-introduce EKG2 in gx86, as per bug #187330. The live ebuild goes first, I'll drop in a snapshot too soon.
(Portage version: 2.2_rc91_p1/cvs/Linux x86_64)
Revision Changes Path
1.6 net-im/ekg2/metadata.xml
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/ekg2/metadata.xml?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/ekg2/metadata.xml?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/ekg2/metadata.xml?r1=1.5&r2=1.6
1.31 net-im/ekg2/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/ekg2/ChangeLog?rev=1.31&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/ekg2/ChangeLog?rev=1.31&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/ekg2/ChangeLog?r1=1.30&r2=1.31
1.1 net-im/ekg2/ekg2-9999.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/ekg2/ekg2-9999.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/ekg2/ekg2-9999.ebuild?rev=1.1&content-type=text/plain
Index: ekg2-9999.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/ekg2/ekg2-9999.ebuild,v 1.1 2010/10/08 13:53:08 mgorny Exp $
EAPI=2
ESVN_REPO_URI="http://toxygen.net/svn/ekg2/trunk"
inherit multilib perl-module scons-utils subversion toolchain-funcs
DESCRIPTION="Text-based, multi-protocol instant messenger"
HOMEPAGE="http://www.ekg2.org"
SRC_URI=""
LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="dbus extra gadu gif gnutls gpg gpm gsm gtk icq idn inotify irc
jabber jogger jpeg mail minimal ncurses nls nntp oracle oss pcap
perl python readline remote rss ruby sim sms spell
sqlite sqlite3 srv ssl static unicode web xosd zlib"
# -- non-obvious plugin mappings --
# extra -> autoresponder, polchat, rivchat, rot13, xmsg
# !minimal -> ioctld, logs, rc
# any sound -> pcm
# web -> httprc_xajax
RDEPEND="
dbus? ( sys-apps/dbus )
gpg? ( app-crypt/gpgme )
gsm? ( media-sound/gsm )
gtk? ( x11-libs/gtk+:2 )
idn? ( net-dns/libidn )
nls? ( virtual/libintl )
oracle? ( dev-db/oracle-instantclient-basic )
pcap? ( net-libs/libpcap )
perl? ( dev-lang/perl )
python? ( dev-lang/python )
readline? ( sys-libs/readline )
rss? ( dev-libs/expat )
ruby? ( dev-lang/ruby )
sim? ( dev-libs/openssl )
xosd? ( x11-libs/xosd )
gadu? ( net-libs/libgadu
gif? ( media-libs/giflib )
jpeg? ( media-libs/jpeg ) )
irc? ( ssl? ( dev-libs/openssl ) )
jabber? ( dev-libs/expat
gnutls? ( net-libs/gnutls )
!gnutls? ( ssl? ( dev-libs/openssl ) )
zlib? ( sys-libs/zlib ) )
!minimal? (
zlib? ( sys-libs/zlib ) )
ncurses? ( sys-libs/ncurses[unicode?]
gpm? ( sys-libs/gpm )
spell? ( app-text/aspell ) )
sqlite3? ( dev-db/sqlite:3 )
!sqlite3? ( sqlite? ( dev-db/sqlite:0 ) )"
DEPEND="${RDEPEND}
nls? ( sys-devel/gettext )"
pkg_setup() {
if ! use gtk && ! use ncurses && ! use readline && ! use remote && ! use web; then
ewarn 'ekg2 is being compiled without any frontend, you should consider'
ewarn 'enabling at least one of following USEflags:'
ewarn ' gtk, ncurses, readline, remote, web.'
fi
}
use_plug() {
use ${1} && echo -n ,${2:-${1}}
}
# Build comma-separated plugin list based on USE
# We can put the same plugin few times if it's referenced by more than one flag
build_plugin_list() {
echo '@none' \
$(use_plug dbus) \
$(use_plug extra autoresponder,polchat,rivchat,rot13,xmsg) \
$(use_plug gadu gg) \
$(use_plug gpg) \
$(use_plug gsm) \
$(use_plug gtk) \
$(use_plug icq) \
$(use_plug irc) \
$(use_plug jabber jabber) \
$(use_plug jogger jogger) \
$(use_plug mail) \
$(use_plug !minimal ioctld,logs,rc) \
$(use_plug ncurses) \
$(use_plug nntp feed) \
$(use_plug oracle logsoracle) \
$(use_plug oss oss,pcm) \
$(use_plug pcap sniff) \
$(use_plug perl) \
$(use_plug python) \
$(use_plug readline) \
$(use_plug remote) \
$(use_plug rss feed) \
$(use_plug ruby) \
$(use_plug sim) \
$(use_plug sms) \
$(use_plug sqlite logsqlite) \
$(use_plug sqlite3 logsqlite) \
$(use_plug web httprc_xajax) \
$(use_plug xosd) \
| tr -d '[[:space:]]'
}
# create DEPS list for plugin
# + means dep forced (fail if unavailable, prioritize over other one-of)
# - means dep disabled (don't even check for it)
# use:opt maps USEflag to specified opt
# usea|useb|usec makes one-of opt
make_deps() {
local spls spll flag fopt out
echo -n " ${1}_DEPS="
shift
# loop over different opts
while [[ -n ${1} ]]; do
spls=${1}
out=
# loop over one-of opts
while true; do
# get next one-of, make sure spls gets empty if last
spll=${spls%%|*}
spls=${spls:$(( ${#spll} + 1 ))}
# parse use:opt, if no :opt specified fopt=flag
flag=${spll%:*}
fopt=${spll#*:}
# if one of one-of opt matches, we output only it
# else we need to output all of them disabled
use ${flag} && out=+ || out=${out}-
out=${out}${fopt}
# got more one-of opts? parse them only if this didn't match
if [[ -n ${spls} ]] && ! use ${flag}; then
out=${out},
continue
fi
echo -n ${out}
shift
[[ -n ${1} ]] && echo -n ,
break
done
done
}
# create all DEPS lists
build_addopts_list() {
use extra && make_deps XMSG inotify
use gadu && make_deps GG gif jpeg
use irc && make_deps IRC 'ssl:openssl'
use jabber && make_deps JABBER zlib 'gnutls|ssl:openssl'
use mail && make_deps MAIL inotify
use !minimal && make_deps LOGS zlib
use ncurses && make_deps NCURSES gpm spell:aspell
use rss || use nntp && make_deps FEED rss:expat
use sqlite3 || use sqlite && make_deps LOGSQLITE 'sqlite3|sqlite'
}
# SCons doesn't build perl modules, perl-module.eclass does it better
foreach_perl_module() {
if use perl; then
local d
for d in "${S}"/plugins/perl/*/; do
cd "${d}" || die
${1}
# workaround perl-module.eclass
unset SRC_PREP
done
fi
}
src_configure() {
# HARDDEPS -> build should fail if some dep is unsatisfied
# DISTNOTES -> are displayed with /version, helpful for upstream bug reports
tc-export CC
escons PLUGINS=$(build_plugin_list) $(build_addopts_list) \
HARDDEPS=1 SKIPCHECKS=1 RELPLUGINS=0 \
$(use_scons unicode UNICODE) $(use_scons nls NLS) \
$(use_scons static STATIC) $(use_scons idn IDN) \
$(use_scons srv RESOLV) \
PREFIX=/usr LIBDIR="\$EPREFIX/$(get_libdir)" \
DOCDIR="\$DATAROOTDIR/doc/${PF}" \
DISTNOTES="Gentoo ebuild ${PVR}, USE='${USE}'" \
${MAKEOPTS} conf || die "escons conf failed"
foreach_perl_module perl-module_src_configure
}
src_compile() {
# SKIPCONF -> no need to reconfigure
escons SKIPCONF=1 ${MAKEOPTS} || die
foreach_perl_module perl-module_src_compile
}
src_test() {
foreach_perl_module perl-module_src_test
}
src_install() {
escons DESTDIR="${D}" ${MAKEOPTS} install || die
foreach_perl_module perl-module_src_install
# XXX: replace it when an alternative is available
prepalldocs
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in net-im/ekg2: metadata.xml ChangeLog ekg2-9999.ebuild
@ 2010-12-17 20:08 Michal Gorny (mgorny)
0 siblings, 0 replies; 2+ messages in thread
From: Michal Gorny (mgorny) @ 2010-12-17 20:08 UTC (permalink / raw
To: gentoo-commits
mgorny 10/12/17 20:08:37
Modified: metadata.xml ChangeLog ekg2-9999.ebuild
Log:
Sync the live ebuild with the mgorny repo. This means switching it into the new git repo and switching it back to the original autotools build system.
(Portage version: 2.2.0_alpha7_p8/cvs/Linux x86_64)
Revision Changes Path
1.7 net-im/ekg2/metadata.xml
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/ekg2/metadata.xml?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/ekg2/metadata.xml?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/ekg2/metadata.xml?r1=1.6&r2=1.7
Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/ekg2/metadata.xml,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- metadata.xml 8 Oct 2010 13:53:08 -0000 1.6
+++ metadata.xml 17 Dec 2010 20:08:36 -0000 1.7
@@ -8,13 +8,20 @@
</maintainer>
<use>
+ <flag name='expat'>Enable plugins relying on <pkg>dev-libs/expat</pkg>
+ (jabber & feed plugins).</flag>
<flag name='extra'>Enable following plugins: autoresponder,
polchat, rivchat, rot13, xmsg.</flag>
<flag name='gadu'>Enable Gadu-Gadu protocol support (requires
<pkg>net-libs/libgadu</pkg>).</flag>
<flag name='gif'>GIF token support for Gadu-Gadu protocol.</flag>
- <flag name='gnutls'>Enable SSL/TLS support through GnuTLS (for jabber
- plugin). If 'ssl' is set too, GnuTLS will be used.</flag>
+ <flag name='gnutls' restrict='<net-im/ekg2-0.3.0_rc'>Enable SSL/TLS
+ support through GnuTLS for the plugins supporting it. If 'ssl'
+ is enabled too, GnuTLS will be preferred where possible (and
+ OpenSSL will be used elsewhere).</flag>
+ <flag name='gnutls' restrict='>=net-im/ekg2-0.3.0_rc'>Enable SSL/TLS
+ support through GnuTLS (for jabber plugin). If 'ssl' is set too,
+ GnuTLS will be used.</flag>
<flag name='gpg'>Enable jabber message encryption through
<pkg>app-crypt/gpgme</pkg>.</flag>
<flag name='inotify'>Enable inotify-based filesystem moniotoring support
@@ -40,8 +47,12 @@
<flag name='sqlite'>Support logging messages into SQLite2 database.
If 'sqlite3' is set too, it will be used instead.</flag>
<flag name='srv'>Use SRV-capable resolver through libresolv.</flag>
- <flag name='ssl'>Enable SSL/TLS support through OpenSSL (for jabber
- plugin). If 'gnutls' is set too, it will be used instead.</flag>
+ <flag name='ssl' restrict='<net-im/ekg2-0.3.0_rc'>Enable SSL/TLS support
+ through OpenSSL (for jabber plugin). If 'gnutls' is set too, it
+ will be used instead.</flag>
+ <flag name='ssl' restrict='>=net-im/ekg2-0.3.0_rc'>Enable the complete
+ SSL/TLS support through OpenSSL. This also enables the 'sim' plugin
+ which relies on OpenSSL.</flag>
<flag name='static'>Link statically with plugins instead of installing
them as shared libraries (external libraries can still be linked
dynamically).</flag>
1.36 net-im/ekg2/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/ekg2/ChangeLog?rev=1.36&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/ekg2/ChangeLog?rev=1.36&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/ekg2/ChangeLog?r1=1.35&r2=1.36
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/ekg2/ChangeLog,v
retrieving revision 1.35
retrieving revision 1.36
diff -u -r1.35 -r1.36
--- ChangeLog 25 Oct 2010 00:24:12 -0000 1.35
+++ ChangeLog 17 Dec 2010 20:08:36 -0000 1.36
@@ -1,6 +1,11 @@
# ChangeLog for net-im/ekg2
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/ekg2/ChangeLog,v 1.35 2010/10/25 00:24:12 fauli Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/ekg2/ChangeLog,v 1.36 2010/12/17 20:08:36 mgorny Exp $
+
+ 17 Dec 2010; Michał Górny <mgorny@gentoo.org> ekg2-9999.ebuild,
+ metadata.xml:
+ Sync the live ebuild with the mgorny repo. This means switching it into the
+ new git repo and switching it back to the original autotools build system.
25 Oct 2010; Christian Faulhammer <fauli@gentoo.org>
ekg2-0.3_pre20101008.ebuild:
1.2 net-im/ekg2/ekg2-9999.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/ekg2/ekg2-9999.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/ekg2/ekg2-9999.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/ekg2/ekg2-9999.ebuild?r1=1.1&r2=1.2
Index: ekg2-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/ekg2/ekg2-9999.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ekg2-9999.ebuild 8 Oct 2010 13:53:08 -0000 1.1
+++ ekg2-9999.ebuild 17 Dec 2010 20:08:36 -0000 1.2
@@ -1,11 +1,11 @@
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/ekg2/ekg2-9999.ebuild,v 1.1 2010/10/08 13:53:08 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/ekg2/ekg2-9999.ebuild,v 1.2 2010/12/17 20:08:36 mgorny Exp $
EAPI=2
-ESVN_REPO_URI="http://toxygen.net/svn/ekg2/trunk"
+EGIT_REPO_URI="git://github.com/leafnode/ekg2.git"
-inherit multilib perl-module scons-utils subversion toolchain-funcs
+inherit autotools autotools-utils git
DESCRIPTION="Text-based, multi-protocol instant messenger"
HOMEPAGE="http://www.ekg2.org"
@@ -14,43 +14,29 @@
LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
-IUSE="dbus extra gadu gif gnutls gpg gpm gsm gtk icq idn inotify irc
- jabber jogger jpeg mail minimal ncurses nls nntp oracle oss pcap
- perl python readline remote rss ruby sim sms spell
- sqlite sqlite3 srv ssl static unicode web xosd zlib"
-
-# -- non-obvious plugin mappings --
-# extra -> autoresponder, polchat, rivchat, rot13, xmsg
-# !minimal -> ioctld, logs, rc
-# any sound -> pcm
-# web -> httprc_xajax
+IUSE="expat gadu gif gnutls gpg gpm gsm gtk idn inotify jpeg ncurses nls
+ oracle perl python readline spell sqlite sqlite3 ssl threads unicode
+ xosd zlib"
RDEPEND="
- dbus? ( sys-apps/dbus )
gpg? ( app-crypt/gpgme )
gsm? ( media-sound/gsm )
gtk? ( x11-libs/gtk+:2 )
idn? ( net-dns/libidn )
nls? ( virtual/libintl )
oracle? ( dev-db/oracle-instantclient-basic )
- pcap? ( net-libs/libpcap )
perl? ( dev-lang/perl )
python? ( dev-lang/python )
readline? ( sys-libs/readline )
- rss? ( dev-libs/expat )
- ruby? ( dev-lang/ruby )
- sim? ( dev-libs/openssl )
+ ssl? ( dev-libs/openssl )
xosd? ( x11-libs/xosd )
+ zlib? ( sys-libs/zlib )
+
gadu? ( net-libs/libgadu
gif? ( media-libs/giflib )
jpeg? ( media-libs/jpeg ) )
- irc? ( ssl? ( dev-libs/openssl ) )
- jabber? ( dev-libs/expat
- gnutls? ( net-libs/gnutls )
- !gnutls? ( ssl? ( dev-libs/openssl ) )
- zlib? ( sys-libs/zlib ) )
- !minimal? (
- zlib? ( sys-libs/zlib ) )
+ expat? ( dev-libs/expat
+ gnutls? ( net-libs/gnutls ) )
ncurses? ( sys-libs/ncurses[unicode?]
gpm? ( sys-libs/gpm )
spell? ( app-text/aspell ) )
@@ -60,163 +46,65 @@
DEPEND="${RDEPEND}
nls? ( sys-devel/gettext )"
+DOCS=(
+ AUTHORS README.md docs/README docs/TODO
+ docs/events.txt docs/mouse.txt docs/sim.txt docs/voip.txt
+ docs/themes.txt docs/themes-en.txt
+ docs/ui-ncurses.txt docs/ui-ncurses-en.txt
+)
+AUTOTOOLS_IN_SOURCE_BUILD=1
+
pkg_setup() {
- if ! use gtk && ! use ncurses && ! use readline && ! use remote && ! use web; then
+ if ! use gtk && ! use ncurses && ! use readline; then
ewarn 'ekg2 is being compiled without any frontend, you should consider'
ewarn 'enabling at least one of following USEflags:'
- ewarn ' gtk, ncurses, readline, remote, web.'
+ ewarn ' gtk, ncurses, readline.'
fi
-}
-
-use_plug() {
- use ${1} && echo -n ,${2:-${1}}
-}
-
-# Build comma-separated plugin list based on USE
-# We can put the same plugin few times if it's referenced by more than one flag
-
-build_plugin_list() {
- echo '@none' \
- $(use_plug dbus) \
- $(use_plug extra autoresponder,polchat,rivchat,rot13,xmsg) \
- $(use_plug gadu gg) \
- $(use_plug gpg) \
- $(use_plug gsm) \
- $(use_plug gtk) \
- $(use_plug icq) \
- $(use_plug irc) \
- $(use_plug jabber jabber) \
- $(use_plug jogger jogger) \
- $(use_plug mail) \
- $(use_plug !minimal ioctld,logs,rc) \
- $(use_plug ncurses) \
- $(use_plug nntp feed) \
- $(use_plug oracle logsoracle) \
- $(use_plug oss oss,pcm) \
- $(use_plug pcap sniff) \
- $(use_plug perl) \
- $(use_plug python) \
- $(use_plug readline) \
- $(use_plug remote) \
- $(use_plug rss feed) \
- $(use_plug ruby) \
- $(use_plug sim) \
- $(use_plug sms) \
- $(use_plug sqlite logsqlite) \
- $(use_plug sqlite3 logsqlite) \
- $(use_plug web httprc_xajax) \
- $(use_plug xosd) \
- | tr -d '[[:space:]]'
-}
-
-# create DEPS list for plugin
-# + means dep forced (fail if unavailable, prioritize over other one-of)
-# - means dep disabled (don't even check for it)
-# use:opt maps USEflag to specified opt
-# usea|useb|usec makes one-of opt
-
-make_deps() {
- local spls spll flag fopt out
-
- echo -n " ${1}_DEPS="
- shift
-
- # loop over different opts
- while [[ -n ${1} ]]; do
- spls=${1}
- out=
- # loop over one-of opts
- while true; do
- # get next one-of, make sure spls gets empty if last
- spll=${spls%%|*}
- spls=${spls:$(( ${#spll} + 1 ))}
- # parse use:opt, if no :opt specified fopt=flag
- flag=${spll%:*}
- fopt=${spll#*:}
-
- # if one of one-of opt matches, we output only it
- # else we need to output all of them disabled
- use ${flag} && out=+ || out=${out}-
- out=${out}${fopt}
-
- # got more one-of opts? parse them only if this didn't match
- if [[ -n ${spls} ]] && ! use ${flag}; then
- out=${out},
- continue
- fi
-
- echo -n ${out}
- shift
- [[ -n ${1} ]] && echo -n ,
- break
- done
- done
-}
-
-# create all DEPS lists
-
-build_addopts_list() {
- use extra && make_deps XMSG inotify
- use gadu && make_deps GG gif jpeg
- use irc && make_deps IRC 'ssl:openssl'
- use jabber && make_deps JABBER zlib 'gnutls|ssl:openssl'
- use mail && make_deps MAIL inotify
- use !minimal && make_deps LOGS zlib
- use ncurses && make_deps NCURSES gpm spell:aspell
- use rss || use nntp && make_deps FEED rss:expat
- use sqlite3 || use sqlite && make_deps LOGSQLITE 'sqlite3|sqlite'
-}
-# SCons doesn't build perl modules, perl-module.eclass does it better
-
-foreach_perl_module() {
- if use perl; then
- local d
- for d in "${S}"/plugins/perl/*/; do
- cd "${d}" || die
- ${1}
-
- # workaround perl-module.eclass
- unset SRC_PREP
- done
+ if use gnutls && ! use ssl; then
+ ewarn 'You have enabled USE=gnutls without USE=ssl. The SSL support'
+ ewarn 'in ekg2 will be limited to the plugins supporting GnuTLS.'
fi
}
-src_configure() {
- # HARDDEPS -> build should fail if some dep is unsatisfied
- # DISTNOTES -> are displayed with /version, helpful for upstream bug reports
-
- tc-export CC
- escons PLUGINS=$(build_plugin_list) $(build_addopts_list) \
- HARDDEPS=1 SKIPCHECKS=1 RELPLUGINS=0 \
- $(use_scons unicode UNICODE) $(use_scons nls NLS) \
- $(use_scons static STATIC) $(use_scons idn IDN) \
- $(use_scons srv RESOLV) \
- PREFIX=/usr LIBDIR="\$EPREFIX/$(get_libdir)" \
- DOCDIR="\$DATAROOTDIR/doc/${PF}" \
- DISTNOTES="Gentoo ebuild ${PVR}, USE='${USE}'" \
- ${MAKEOPTS} conf || die "escons conf failed"
-
- foreach_perl_module perl-module_src_configure
+src_prepare() {
+ autotools-utils_src_prepare
+ eautoreconf
+ eautopoint
+ # Ugly and gives too many files but should work.
+ find -name '*.c' | sort > po/POTFILES.in
}
-src_compile() {
- # SKIPCONF -> no need to reconfigure
-
- escons SKIPCONF=1 ${MAKEOPTS} || die
-
- foreach_perl_module perl-module_src_compile
-}
-
-src_test() {
- foreach_perl_module perl-module_src_test
-}
-
-src_install() {
- escons DESTDIR="${D}" ${MAKEOPTS} install || die
-
- foreach_perl_module perl-module_src_install
-
- # XXX: replace it when an alternative is available
- prepalldocs
+src_configure() {
+ myeconfargs=(
+ $(use_with expat)
+ $(use_with gadu libgadu)
+ $(use_with gif)
+ $(use_with gnutls libgnutls)
+ $(use_with gpg)
+ $(use_with gpm gpm-mouse)
+ $(use_with gsm libgsm)
+ $(use_with gtk)
+ $(use_with idn libidn)
+ $(use_with inotify)
+ $(use_with jpeg libjpeg)
+ $(use_with ncurses)
+ $(use_with oracle logsoracle)
+ $(use_with perl)
+ $(use_with python)
+ $(use_with readline)
+ $(use_with spell aspell)
+ $(use_with sqlite)
+ $(use_with sqlite3)
+ $(use_with ssl openssl)
+ $(use_with threads pthread)
+ $(use_with xosd libxosd)
+ $(use_with zlib)
+ $(use_enable nls)
+ $(use_enable unicode)
+ --without-ioctld
+ --disable-remote
+ --enable-skip-relative-plugins-dir
+ )
+ autotools-utils_src_configure
}
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2010-12-17 20:08 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2010-12-17 20:08 [gentoo-commits] gentoo-x86 commit in net-im/ekg2: metadata.xml ChangeLog ekg2-9999.ebuild Michal Gorny (mgorny)
-- strict thread matches above, loose matches on Subject: below --
2010-10-08 13:53 Michal Gorny (mgorny)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox