[gentoo-commits] gentoo-x86 commit in dev-libs/libaio: ChangeLog libaio-0.3.109-r2.ebuild

["Mike Frysinger (vapier)" <vapier@gentoo.org>]

vapier      10/11/09 08:19:20

  Modified:             ChangeLog
  Added:                libaio-0.3.109-r2.ebuild
  Log:
  Drop lio_listio man page now provided by man-pages.
  
  (Portage version: 2.2_rc96/cvs/Linux x86_64)

Revision  Changes    Path
1.53                 dev-libs/libaio/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libaio/ChangeLog?rev=1.53&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libaio/ChangeLog?rev=1.53&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libaio/ChangeLog?r1=1.52&r2=1.53

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/libaio/ChangeLog,v
retrieving revision 1.52
retrieving revision 1.53
diff -u -r1.52 -r1.53
--- ChangeLog	21 Oct 2010 23:56:38 -0000	1.52
+++ ChangeLog	9 Nov 2010 08:19:20 -0000	1.53
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/libaio
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libaio/ChangeLog,v 1.52 2010/10/21 23:56:38 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libaio/ChangeLog,v 1.53 2010/11/09 08:19:20 vapier Exp $
+
+*libaio-0.3.109-r2 (09 Nov 2010)
+
+  09 Nov 2010; Mike Frysinger <vapier@gentoo.org> +libaio-0.3.109-r2.ebuild:
+  Drop lio_listio man page now provided by man-pages.
 
 *libaio-0.3.109-r1 (21 Oct 2010)
 



1.1                  dev-libs/libaio/libaio-0.3.109-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libaio/libaio-0.3.109-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libaio/libaio-0.3.109-r2.ebuild?rev=1.1&content-type=text/plain

Index: libaio-0.3.109-r2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/libaio/libaio-0.3.109-r2.ebuild,v 1.1 2010/11/09 08:19:20 vapier Exp $

EAPI="3"

inherit eutils multilib toolchain-funcs

DESCRIPTION="Asynchronous input/output library that uses the kernels native interface"
HOMEPAGE="http://www.kernel.org/pub/linux/kernel/people/andrea/libaio/ http://lse.sourceforge.net/io/aio.html"
SRC_URI="mirror://kernel/linux/libs/aio/${P}.tar.bz2"

LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="static-libs"

RESTRICT="test"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-0.3.109-unify-bits-endian.patch
	epatch "${FILESDIR}"/${PN}-0.3.109-generic-arch.patch
	epatch "${FILESDIR}"/${PN}-0.3.106-build.patch
	epatch "${FILESDIR}"/${PN}-0.3.107-ar-ranlib.patch
	epatch "${FILESDIR}"/${PN}-0.3.109-install.patch
	sed -i \
		-e "/^libdir=/s:lib$:$(get_libdir):" \
		-e "/^prefix=/s:/usr:${EPREFIX}/usr:" \
		src/Makefile Makefile || die
}

src_configure() {
	tc-export AR CC RANLIB
}

src_test() {
	cd "${S}"/harness
	mkdir testdir
	emake check prefix="${S}/src" libdir="${S}/src" || die
}

src_install() {
	emake install DESTDIR="${ED}" || die
	doman man/*
	dodoc ChangeLog TODO

	# move crap to / for multipath-tools #325355
	gen_usr_ldscript -a aio
	if ! use static-libs ; then
		rm "${ED}"usr/lib*/*.a || die
	fi

	# remove stuff provided by man-pages now
	rm "${ED}"usr/share/man/man3/{lio_listio,aio_{cancel,error,fsync,init,read,return,suspend,write}}.*
}