[gentoo-commits] gentoo-x86 commit in app-misc/mc: ChangeLog mc-4.7.4-r1.ebuild

[gentoo-commits] gentoo-x86 commit in app-misc/mc: ChangeLog mc-4.7.4-r1.ebuild

[Alex Alexander (wired)]

wired       10/09/18 21:18:49

  Modified:             ChangeLog
  Added:                mc-4.7.4-r1.ebuild
  Log:
  fixed bug 337961
  
  (Portage version: 2.2_rc83/cvs/Linux x86_64)

Revision  Changes    Path
1.209                app-misc/mc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mc/ChangeLog?rev=1.209&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mc/ChangeLog?rev=1.209&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mc/ChangeLog?r1=1.208&r2=1.209

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v
retrieving revision 1.208
retrieving revision 1.209
diff -u -r1.208 -r1.209
--- ChangeLog	7 Sep 2010 09:30:11 -0000	1.208
+++ ChangeLog	18 Sep 2010 21:18:49 -0000	1.209
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/mc
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v 1.208 2010/09/07 09:30:11 wired Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v 1.209 2010/09/18 21:18:49 wired Exp $
+
+*mc-4.7.4-r1 (18 Sep 2010)
+
+  18 Sep 2010; Alex Alexander <wired@gentoo.org> +mc-4.7.4-r1.ebuild:
+  fixed bug 337961
 
 *mc-4.7.4 (07 Sep 2010)
 *mc-4.7.0.9 (07 Sep 2010)



1.1                  app-misc/mc/mc-4.7.4-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mc/mc-4.7.4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mc/mc-4.7.4-r1.ebuild?rev=1.1&content-type=text/plain

Index: mc-4.7.4-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/mc-4.7.4-r1.ebuild,v 1.1 2010/09/18 21:18:49 wired Exp $

EAPI=3

inherit base

MY_P=${P/_/-}

DESCRIPTION="GNU Midnight Commander is a text based file manager"
HOMEPAGE="http://www.midnight-commander.org"
SRC_URI="http://www.midnight-commander.org/downloads/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~ppc-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x86-solaris"
IUSE="+edit gpm nls samba slang X"

RDEPEND=">=dev-libs/glib-2.8:2
	gpm? ( sys-libs/gpm )
	kernel_linux? ( sys-fs/e2fsprogs )
	samba? ( net-fs/samba )
	slang? ( >=sys-libs/slang-2 )
	!slang? ( sys-libs/ncurses )
	X? ( x11-libs/libX11
		x11-libs/libICE
		x11-libs/libXau
		x11-libs/libXdmcp
		x11-libs/libSM )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	nls? ( sys-devel/gettext )"

S=${WORKDIR}/${MY_P}

src_configure() {
	local myscreen=ncurses
	use slang && myscreen=slang

	econf \
		--disable-dependency-tracking \
		$(use_enable nls) \
		--enable-vfs \
		$(use_enable kernel_linux vfs-undelfs) \
		--enable-charset \
		$(use_with X x) \
		$(use_enable samba vfs-smb) \
		$(use_with gpm gpm-mouse) \
		--with-screen=${myscreen} \
		$(use_with edit)
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS README

	# fix bug #334383
	if [[ ${EUID} == 0 ]] ; then
		fowners root:tty /usr/libexec/mc/cons.saver ||
			die "setting cons.saver's owner failed"
		fperms g+s /usr/libexec/mc/cons.saver ||
			die "setting cons.saver's permissions failed"
	fi
}

pkg_postinst() {
	elog "To enable exiting to latest working directory,"
	elog "put this into your ~/.bashrc:"
	elog ". ${EPREFIX}/usr/libexec/mc/mc.sh"
}