[gentoo-commits] gentoo-x86 commit in sys-devel/icecream: icecream-0.9.6-r1.ebuild ChangeLog icecream-0.9.6.ebuild

[gentoo-commits] gentoo-x86 commit in sys-devel/icecream: icecream-0.9.6-r1.ebuild ChangeLog icecream-0.9.6.ebuild

[Tomas Chvatal (scarabeus)]

scarabeus    10/09/18 10:24:22

  Modified:             ChangeLog
  Added:                icecream-0.9.6-r1.ebuild
  Removed:              icecream-0.9.6.ebuild
  Log:
  Revision bump to fix CHOST/crosscompile problems per bug #275756 and bug #303545.
  
  (Portage version: 2.2_rc83/cvs/Linux x86_64)

Revision  Changes    Path
1.39                 sys-devel/icecream/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/icecream/ChangeLog?rev=1.39&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/icecream/ChangeLog?rev=1.39&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/icecream/ChangeLog?r1=1.38&r2=1.39

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-devel/icecream/ChangeLog,v
retrieving revision 1.38
retrieving revision 1.39
diff -u -r1.38 -r1.39
--- ChangeLog	11 Sep 2010 12:30:59 -0000	1.38
+++ ChangeLog	18 Sep 2010 10:24:22 -0000	1.39
@@ -1,6 +1,14 @@
 # ChangeLog for sys-devel/icecream
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-devel/icecream/ChangeLog,v 1.38 2010/09/11 12:30:59 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/icecream/ChangeLog,v 1.39 2010/09/18 10:24:22 scarabeus Exp $
+
+*icecream-0.9.6-r1 (18 Sep 2010)
+
+  18 Sep 2010; Tomáš Chvátal <scarabeus@gentoo.org>
+  +files/0.9.6-crosscompile.patch, -icecream-0.9.6.ebuild,
+  +icecream-0.9.6-r1.ebuild, files/icecream-create-env:
+  Revision bump to fix CHOST/crosscompile problems per bug #275756 and bug
+  #303545.
 
 *icecream-0.9.6 (11 Sep 2010)
 



1.1                  sys-devel/icecream/icecream-0.9.6-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/icecream/icecream-0.9.6-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/icecream/icecream-0.9.6-r1.ebuild?rev=1.1&content-type=text/plain

Index: icecream-0.9.6-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-devel/icecream/icecream-0.9.6-r1.ebuild,v 1.1 2010/09/18 10:24:22 scarabeus Exp $

EAPI=3

inherit base autotools

MY_P="icecc-${PV}"

DESCRIPTION="icecc is a program for distributed compiling of C(++) code across several machines; based on distcc"
HOMEPAGE="http://old-en.opensuse.org/Icecream"
SRC_URI="ftp://ftp.suse.com/pub/projects/${PN}/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~ppc ~sparc ~x86"
IUSE=""

S="${WORKDIR}/${MY_P}"

PATCHES=(
	"${FILESDIR}/${PV}-symlinks.patch"
	"${FILESDIR}/${PV}-crosscompile.patch"
	"${FILESDIR}/${PN}-conf.d-verbosity.patch"
	"${FILESDIR}/${PN}-gentoo-multilib.patch"
)

pkg_setup() {
	enewgroup icecream
	enewuser icecream -1 -1 /var/cache/icecream icecream
}

src_prepare() {
	base_src_prepare

	eautoreconf
}

src_install() {
	base_src_install

	dosbin "${FILESDIR}"/icecream-config || die "install failed"
	dosbin "${FILESDIR}"/icecream-create-env || die "install failed"

	newconfd suse/sysconfig.icecream icecream || die "install failed"
	doinitd "${FILESDIR}"/icecream || die "install failed"

	diropts -m0755
	keepdir /usr/lib/icecc/bin
}

pkg_postinst() {
	ebegin "Scanning for compiler front-ends..."
	/usr/sbin/icecream-config --install-links
	/usr/sbin/icecream-config --install-links "${CHOST}"
	eend ${?}

	elog
	elog "If you have compiled binutils/gcc/glibc with processor-specific flags"
	elog "(as normal using Gentoo), there is a greater chance that your compiler"
	elog "won't work on other machines. The best would be to build gcc, glibc and"
	elog "binutils without those flags and then copy the needed files into your"
	elog "tarball for distribution to other machines. This tarball can be created"
	elog "by running /usr/bin/icecc --build-native, and used by setting"
	elog "ICECC_VERSION in /etc/conf.d/icecream"
	elog '  ICECC_VERSION=<filename_of_archive_containing_your_environment>'
	elog
	elog "To use icecream with portage add the following line to /etc/make.conf"
	elog '  PREROOTPATH=/usr/lib/icecc/bin'
	elog
	elog "To use icecream with normal make use (e.g. in /etc/profile)"
	elog '  PATH=/usr/lib/icecc/bin:$PATH'
	elog
	elog "N.B. To use icecream with ccache, the ccache PATH should come first:"
	elog '  PATH=/usr/lib/ccache/bin:/usr/lib/icecc/bin:$PATH'
	elog
	elog "Don't forget to open the following ports in your firewall(s):"
	elog " TCP/10245 on the daemon computers (required)"
	elog " TCP/8765 for the the scheduler computer (required)"
	elog " TCP/8766 for the telnet interface to the scheduler (optional)"
	elog " UDP/8765 for broadcast to find the scheduler (optional)"
	elog
	elog "Further usage instructions: ${HOMEPAGE}"
}