[gentoo-commits] gentoo-x86 commit in sys-apps/groff: ChangeLog groff-1.20.1-r3.ebuild

["Mike Frysinger (vapier)" <vapier@gentoo.org>]

vapier      10/07/24 08:18:34

  Modified:             ChangeLog
  Added:                groff-1.20.1-r3.ebuild
  Log:
  Add tmac fix from upstream #263524 by Horst Prote.  Add memory fixes from upstream #294045 by Maurice van der Pot.
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.104                sys-apps/groff/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/groff/ChangeLog?rev=1.104&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/groff/ChangeLog?rev=1.104&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/groff/ChangeLog?r1=1.103&r2=1.104

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/groff/ChangeLog,v
retrieving revision 1.103
retrieving revision 1.104
diff -u -r1.103 -r1.104
--- ChangeLog	7 Nov 2009 06:10:09 -0000	1.103
+++ ChangeLog	24 Jul 2010 08:18:34 -0000	1.104
@@ -1,6 +1,15 @@
 # ChangeLog for sys-apps/groff
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/groff/ChangeLog,v 1.103 2009/11/07 06:10:09 matsuu Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/groff/ChangeLog,v 1.104 2010/07/24 08:18:34 vapier Exp $
+
+*groff-1.20.1-r3 (24 Jul 2010)
+
+  24 Jul 2010; Mike Frysinger <vapier@gentoo.org> +groff-1.20.1-r3.ebuild,
+  +files/groff-1.20.1-Thtml-mem-leak.patch,
+  +files/groff-1.20.1-double-frees-mem-leaks.patch,
+  +files/groff-1.20.1-tmac-ec.patch:
+  Add tmac fix from upstream #263524 by Horst Prote. Add memory fixes from
+  upstream #294045 by Maurice van der Pot.
 
 *groff-1.20.1-r2 (07 Nov 2009)
 



1.1                  sys-apps/groff/groff-1.20.1-r3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/groff/groff-1.20.1-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/groff/groff-1.20.1-r3.ebuild?rev=1.1&content-type=text/plain

Index: groff-1.20.1-r3.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/groff/groff-1.20.1-r3.ebuild,v 1.1 2010/07/24 08:18:34 vapier Exp $

inherit autotools eutils toolchain-funcs

DESCRIPTION="Text formatter used for man pages"
HOMEPAGE="http://www.gnu.org/software/groff/groff.html"
SRC_URI="mirror://gnu/groff/${P}.tar.gz
	linguas_ja? ( mirror://gentoo/${P}-r2-japanese.patch.bz2 )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE="examples X linguas_ja"

DEPEND=">=sys-apps/texinfo-4.7-r1
	X? (
		x11-libs/libX11
		x11-libs/libXt
		x11-libs/libXmu
		x11-libs/libXaw
		x11-libs/libSM
		x11-libs/libICE
	)"

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}"/${PN}-1.19.2-man-unicode-dashes.patch #16108 #17580 #121502
	epatch "${FILESDIR}"/${P}-tmac-ec.patch #263524
	epatch "${FILESDIR}"/${P}-Thtml-mem-leak.patch #294045
	epatch "${FILESDIR}"/${P}-double-frees-mem-leaks.patch #294045

	# put the docs in the Gentoo-specific spot
	sed -i \
		-e '/^docdir=/s/=.*/=@docdir@/' \
		Makefile.in \
		|| die "sed failed"

	# Make sure we can cross-compile this puppy
	if tc-is-cross-compiler ; then
		sed -i \
			-e '/^GROFFBIN=/s:=.*:=/usr/bin/groff:' \
			-e '/^TROFFBIN=/s:=.*:=/usr/bin/troff:' \
			-e '/^GROFF_BIN_PATH=/s:=.*:=:' \
			-e '/^GROFF_BIN_DIR=/s:=.*:=:' \
			contrib/*/Makefile.sub \
			doc/Makefile.in \
			doc/Makefile.sub || die "cross-compile sed failed"
	fi

	cat <<-EOF >> tmac/mdoc.local
	.ds volume-operating-system Gentoo
	.ds operating-system Gentoo/${KERNEL}
	.ds default-operating-system Gentoo/${KERNEL}
	EOF

	if use linguas_ja ; then
		epatch "${WORKDIR}"/${PF}-japanese.patch #255292
		eautoconf
		eautoheader
	fi
}

src_compile() {
	# Fix problems with not finding g++
#	tc-export CC CXX
	econf \
		--with-appresdir=/usr/share/X11/app-defaults \
		--docdir=/usr/share/doc/${PF} \
		$(use_with X x) \
		$(use linguas_ja && echo --enable-japanese)
	emake || die
}

src_install() {
	emake install DESTDIR="${D}" || die

	# The following links are required for man #123674
	dosym eqn /usr/bin/geqn
	dosym tbl /usr/bin/gtbl

	dodoc BUG-REPORT ChangeLog MORE.STUFF NEWS \
		PROBLEMS PROJECTS README REVISION TODO VERSION

	if ! use examples ; then
		rm -rf "${D}"/usr/share/doc/${PF}/examples
	fi
}