[gentoo-commits] gentoo-x86 commit in kde-base/kmail: kmail-4.4.5.ebuild ChangeLog

["Alexey Shvetsov (alexxy)" <alexxy@gentoo.org>]

alexxy      10/06/30 15:36:53

  Modified:             ChangeLog
  Added:                kmail-4.4.5.ebuild
  Log:
  [kde-base] Bump KDE SC 4.4.5 =)
  (Portage version: 2.2_rc67_p182/cvs/Linux x86_64)

Revision  Changes    Path
1.215                kde-base/kmail/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kmail/ChangeLog?rev=1.215&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kmail/ChangeLog?rev=1.215&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kmail/ChangeLog?r1=1.214&r2=1.215

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/kmail/ChangeLog,v
retrieving revision 1.214
retrieving revision 1.215
diff -u -r1.214 -r1.215
--- ChangeLog	27 Jun 2010 20:30:22 -0000	1.214
+++ ChangeLog	30 Jun 2010 15:36:53 -0000	1.215
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/kmail
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kmail/ChangeLog,v 1.214 2010/06/27 20:30:22 fauli Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kmail/ChangeLog,v 1.215 2010/06/30 15:36:53 alexxy Exp $
+
+*kmail-4.4.5 (30 Jun 2010)
+
+  30 Jun 2010; Alexey Shvetsov <alexxy@gentoo.org> +kmail-4.4.5.ebuild:
+  Version bump
 
   27 Jun 2010; Christian Faulhammer <fauli@gentoo.org> kmail-4.4.4.ebuild:
   x86 stable, bug 322791



1.1                  kde-base/kmail/kmail-4.4.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kmail/kmail-4.4.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kmail/kmail-4.4.5.ebuild?rev=1.1&content-type=text/plain

Index: kmail-4.4.5.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/kmail/kmail-4.4.5.ebuild,v 1.1 2010/06/30 15:36:53 alexxy Exp $

EAPI="3"

KMNAME="kdepim"
inherit kde4-meta

DESCRIPTION="KMail is the email component of Kontact, the integrated personal information manager of KDE."
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="debug +handbook"

DEPEND="
	$(add_kdebase_dep kdelibs 'semantic-desktop')
	$(add_kdebase_dep kdepimlibs 'semantic-desktop')
	$(add_kdebase_dep libkdepim)
	$(add_kdebase_dep libkleo)
	$(add_kdebase_dep libkpgp)
"
RDEPEND="${DEPEND}
	$(add_kdebase_dep kdepim-runtime)
"

add_blocker kmailcvt
add_blocker libksieve
add_blocker messagecore
add_blocker messagelist
add_blocker messageviewer
add_blocker mimelib

KMEXTRACTONLY="
	korganizer/org.kde.Korganizer.Calendar.xml
	libkleo/
	libkpgp/
"
KMEXTRA="
	kmailcvt/
	ksendemail/
	libksieve/
	messagecore/
	messagelist/
	messageviewer/
	mimelib/
	plugins/kmail/
"
KMLOADLIBS="libkdepim"

src_configure() {
	# Bug 308903
	use ppc64 && append-flags -mminimal-toc

	mycmakeargs=(
		-DWITH_IndicateQt=OFF
	)

	kde4-meta_src_configure
}

src_compile() {
	# Bug #276377: kontact/ can build before kmail/, causing a dependency not to be built
	# Upstream as KDE Bug #198807
	# (setting MAKEOPTS to trigger a repoman warning)
	: || MAKEOPTS="-j1"
	kde4-meta_src_compile kmail_xml
	kde4-meta_src_compile
}

pkg_postinst() {
	kde4-meta_pkg_postinst

	if ! has_version kde-base/kdepim-kresources:${SLOT}; then
		echo
		elog "For groupware functionality, please install kde-base/kdepim-kresources:${SLOT}"
		echo
	fi
	if ! has_version kde-base/kleopatra:${SLOT}; then
		echo
		elog "For certificate management and the gnupg log viewer, please install kde-base/kleopatra:${SLOT}"
		echo
	fi
}