[gentoo-commits] gentoo-x86 commit in media-video/isight-firmware-tools: ChangeLog isight-firmware-tools-1.5.92.ebuild isight-firmware-tools-1.5.90.ebuild

[gentoo-commits] gentoo-x86 commit in media-video/isight-firmware-tools: ChangeLog isight-firmware-tools-1.5.92.ebuild isight-firmware-tools-1.5.90.ebuild

[Gilles Dartiguelongue (eva)]

eva         10/05/14 17:53:21

  Modified:             ChangeLog
  Added:                isight-firmware-tools-1.5.92.ebuild
  Removed:              isight-firmware-tools-1.5.90.ebuild
  Log:
  Version bump. Support for new firwares. Clean up old revision.
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.12                 media-video/isight-firmware-tools/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/isight-firmware-tools/ChangeLog?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/isight-firmware-tools/ChangeLog?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/isight-firmware-tools/ChangeLog?r1=1.11&r2=1.12

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/isight-firmware-tools/ChangeLog,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- ChangeLog	5 May 2010 22:07:00 -0000	1.11
+++ ChangeLog	14 May 2010 17:53:21 -0000	1.12
@@ -1,6 +1,13 @@
 # ChangeLog for media-video/isight-firmware-tools
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/isight-firmware-tools/ChangeLog,v 1.11 2010/05/05 22:07:00 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/isight-firmware-tools/ChangeLog,v 1.12 2010/05/14 17:53:21 eva Exp $
+
+*isight-firmware-tools-1.5.92 (14 May 2010)
+
+  14 May 2010; Gilles Dartiguelongue <eva@gentoo.org>
+  -isight-firmware-tools-1.5.90.ebuild,
+  +isight-firmware-tools-1.5.92.ebuild:
+  Version bump. Support for new firwares. Clean up old revision.
 
 *isight-firmware-tools-1.5.90-r1 (05 May 2010)
 



1.1                  media-video/isight-firmware-tools/isight-firmware-tools-1.5.92.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/isight-firmware-tools/isight-firmware-tools-1.5.92.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/isight-firmware-tools/isight-firmware-tools-1.5.92.ebuild?rev=1.1&content-type=text/plain

Index: isight-firmware-tools-1.5.92.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/isight-firmware-tools/isight-firmware-tools-1.5.92.ebuild,v 1.1 2010/05/14 17:53:21 eva Exp $

EAPI="2"

inherit eutils multilib versionator

MY_MAJORV="$(get_version_component_range 1).6"
DESCRIPTION="Extract, load or export firmware for the iSight webcams"
HOMEPAGE="http://bersace03.free.fr/ift/"
SRC_URI="http://launchpad.net/${PN}/main/${MY_MAJORV}/+download/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND=">=dev-libs/glib-2.14
	virtual/libusb:0
	dev-libs/libgcrypt
	>=sys-fs/udev-149"
DEPEND="${RDEPEND}
	>=dev-util/intltool-0.35.5
	sys-apps/texinfo"

src_prepare() {
	# Fix rules for recent udev versions, bug #316027
	sed 's/SYSFS/ATTR/g' -i src/isight.rules.in.in || die "sed 1 failed"

	# Fix multilib support
	sed "s:/lib/firmware:/$(get_libdir)/firmware:" \
		-i src/isight.rules.in.in || die "sed 2 failed"

	# Fix build with -O0, bug #221325
	epatch "${FILESDIR}/${PN}-1.5.90-build-O0.patch"
}

src_configure() {
	# https://bugs.launchpad.net/isight-firmware-tools/+bug/243255
	econf --docdir=/usr/share/doc/${PF}
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	mv "${D}"/etc/udev/rules.d/isight.rules "${D}"/etc/udev/rules.d/70-isight.rules
	rm -f "${D}/usr/share/doc/${PF}/HOWTO"
	dodoc AUTHORS ChangeLog HOWTO NEWS README || die "dodoc failed"
}

pkg_postinst() {
	elog "You need to extract your firmware prior to being able to loading it"
	elog "ift-extract --apple-driver /macos/System/Library/Extensions/IOUSBFamily.kext/Contents/PlugIns/AppleUSBVideoSupport.kext/Contents/MacOS/AppleUSBVideoSupport"
	elog "If you do not have OSX you can get AppleUSBVideoSupport from"
	elog "http://www.mediafire.com/?81xtkqyttjt"
}