* [gentoo-commits] gentoo-x86 commit in net-irc/quassel: quassel-0.6.1.ebuild ChangeLog quassel-0.6.0.ebuild
@ 2010-04-18 11:44 Tomas Chvatal (scarabeus)
0 siblings, 0 replies; only message in thread
From: Tomas Chvatal (scarabeus) @ 2010-04-18 11:44 UTC (permalink / raw
To: gentoo-commits
scarabeus 10/04/18 11:44:34
Modified: ChangeLog
Added: quassel-0.6.1.ebuild
Removed: quassel-0.6.0.ebuild
Log:
Version bump. Drop broken.
(Portage version: 2.2_rc67/cvs/Linux x86_64)
Revision Changes Path
1.85 net-irc/quassel/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/quassel/ChangeLog?rev=1.85&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/quassel/ChangeLog?rev=1.85&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/quassel/ChangeLog?r1=1.84&r2=1.85
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/quassel/ChangeLog,v
retrieving revision 1.84
retrieving revision 1.85
diff -u -r1.84 -r1.85
--- ChangeLog 14 Apr 2010 11:19:30 -0000 1.84
+++ ChangeLog 18 Apr 2010 11:44:34 -0000 1.85
@@ -1,6 +1,12 @@
# ChangeLog for net-irc/quassel
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/quassel/ChangeLog,v 1.84 2010/04/14 11:19:30 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/quassel/ChangeLog,v 1.85 2010/04/18 11:44:34 scarabeus Exp $
+
+*quassel-0.6.1 (18 Apr 2010)
+
+ 18 Apr 2010; Tomáš Chvátal <scarabeus@gentoo.org>
+ -quassel-0.6.0.ebuild, +quassel-0.6.1.ebuild:
+ Version bump. Drop broken.
*quassel-0.6.0 (14 Apr 2010)
1.1 net-irc/quassel/quassel-0.6.1.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/quassel/quassel-0.6.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/quassel/quassel-0.6.1.ebuild?rev=1.1&content-type=text/plain
Index: quassel-0.6.1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/quassel/quassel-0.6.1.ebuild,v 1.1 2010/04/18 11:44:34 scarabeus Exp $
EAPI="2"
inherit cmake-utils eutils
DESCRIPTION="Qt4/KDE4 IRC client suppporting a remote daemon for 24/7 connectivity."
HOMEPAGE="http://quassel-irc.org/"
SRC_URI="http://quassel-irc.org/pub/${P/_/-}.tar.bz2"
LICENSE="GPL-3"
KEYWORDS="~amd64 ~x86 ~amd64-linux"
SLOT="0"
IUSE="ayatana dbus debug kde monolithic phonon postgres +server +ssl webkit +X"
SERVER_RDEPEND="
!postgres? ( x11-libs/qt-sql:4[sqlite] dev-db/sqlite[threadsafe] )
postgres? ( x11-libs/qt-sql:4[postgres] )
x11-libs/qt-script:4
"
GUI_RDEPEND="
x11-libs/qt-gui:4
ayatana? ( dev-libs/libindicate-qt )
kde? (
>=kde-base/kdelibs-4.3
>=kde-base/oxygen-icons-4.3
ayatana? ( kde-misc/plasma-widget-message-indicator )
)
phonon? ( || ( media-sound/phonon x11-libs/qt-phonon ) )
webkit? ( x11-libs/qt-webkit:4 )
"
RDEPEND="
dbus? ( x11-libs/qt-dbus:4 )
monolithic? (
${SERVER_RDEPEND}
${GUI_RDEPEND}
)
!monolithic? (
server? ( ${SERVER_RDEPEND} )
X? ( ${GUI_RDEPEND} )
)
ssl? ( x11-libs/qt-core:4[ssl] )
"
DEPEND="${RDEPEND}"
DOCS="AUTHORS ChangeLog README"
S="${WORKDIR}/${P/_/-}"
pkg_setup() {
if ! use monolithic && ! use server && ! use X ; then
eerror "You have to build at least one of the monolithic client (USE=monolithic),"
eerror "the quasselclient (USE=X) or the quasselcore (USE=server)."
die "monolithic, server and X flag unset."
fi
}
src_configure() {
local mycmakeargs="
$(cmake-utils_use_with ayatana LIBINDICATE)
$(cmake-utils_use_want X QTCLIENT)
$(cmake-utils_use_want server CORE)
$(cmake-utils_use_want monolithic MONO)
$(cmake-utils_use_with webkit)
$(cmake-utils_use_with phonon)
$(cmake-utils_use_with kde)
$(cmake-utils_use_with dbus)
$(cmake-utils_use_with ssl OPENSSL)
$(cmake-utils_use_with !kde OXYGEN)
-DEMBED_DATA=OFF
"
cmake-utils_src_configure
}
src_install() {
cmake-utils_src_install
if use server ; then
newinitd "${FILESDIR}"/quasselcore-2.init quasselcore || die "newinitd failed"
newconfd "${FILESDIR}"/quasselcore-2.conf quasselcore || die "newconfd failed"
insinto /etc/logrotate.d
newins "${FILESDIR}/quassel.logrotate" quassel
fi
}
pkg_postinst() {
if use server ; then
ewarn
ewarn "In order to use the quassel init script you must set the"
ewarn "QUASSEL_USER variable in ${ROOT%/}/etc/conf.d/quasselcore to your username."
ewarn "Note: This is the user who runs the quasselcore and is independent"
ewarn "from the users you set up in the quasselclient."
fi
if ( use server || use monolithic ) && use ssl ; then
elog
elog "Information on how to enable SSL support for client/core connections"
elog "is available at http://bugs.quassel-irc.org/wiki/quassel-irc."
fi
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2010-04-18 11:44 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2010-04-18 11:44 [gentoo-commits] gentoo-x86 commit in net-irc/quassel: quassel-0.6.1.ebuild ChangeLog quassel-0.6.0.ebuild Tomas Chvatal (scarabeus)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox