[gentoo-commits] repo/gentoo:master commit in: kde-apps/kdenlive/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     f21b0d95f1d820d63835d2113d7464763af38a29
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Mon Oct 13 21:52:54 2025 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Mon Oct 13 21:57:30 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f21b0d95

kde-apps/kdenlive: mv media-video/ffmpeg:= to DEPEND+RDEPEND

Closes: https://bugs.gentoo.org/964260
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-apps/kdenlive/kdenlive-25.08.2-r1.ebuild | 79 ++++++++++++++++++++++++++++
 1 file changed, 79 insertions(+)

diff --git a/kde-apps/kdenlive/kdenlive-25.08.2-r1.ebuild b/kde-apps/kdenlive/kdenlive-25.08.2-r1.ebuild
new file mode 100644
index 000000000000..711e167ab57a
--- /dev/null
+++ b/kde-apps/kdenlive/kdenlive-25.08.2-r1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_DESIGNERPLUGIN="true"
+ECM_HANDBOOK="optional"
+ECM_QTHELP="true"
+ECM_TEST="true"
+KFMIN=6.16.0
+QTMIN=6.9.1
+inherit ecm gear.kde.org optfeature xdg
+
+DESCRIPTION="Non-linear video editing suite by KDE"
+HOMEPAGE="https://kdenlive.org/en/"
+
+LICENSE="GPL-3"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="gles2-only semantic-desktop v4l"
+
+RESTRICT="test" # segfaults, bug 684132
+
+DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[concurrent,dbus,gles2-only=,gui,network,widgets,xml]
+	>=dev-qt/qtdeclarative-${QTMIN}:6[widgets]
+	>=dev-qt/qtmultimedia-${QTMIN}:6
+	>=dev-qt/qtnetworkauth-${QTMIN}:6
+	>=dev-qt/qtsvg-${QTMIN}:6
+	>=kde-frameworks/karchive-${KFMIN}:6
+	>=kde-frameworks/kbookmarks-${KFMIN}:6
+	>=kde-frameworks/kcodecs-${KFMIN}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/kfilemetadata-${KFMIN}:6
+	>=kde-frameworks/kguiaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kitemviews-${KFMIN}:6
+	>=kde-frameworks/kjobwidgets-${KFMIN}:6
+	>=kde-frameworks/knewstuff-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/knotifyconfig-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/ktextwidgets-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-frameworks/purpose-${KFMIN}:6
+	>=kde-frameworks/solid-${KFMIN}:6
+	>=media-libs/mlt-7.28.0[ffmpeg,frei0r,qt6,sdl,xml]
+	media-video/ffmpeg:=[encode(+),libass,sdl,X]
+	media-libs/opentimelineio:=
+	v4l? ( media-libs/libv4l )
+"
+RDEPEND="${DEPEND}
+	>=kde-frameworks/qqc2-desktop-style-${KFMIN}:6
+	media-video/mediainfo
+"
+BDEPEND="sys-devel/gettext"
+DEPEND+=" virtual/os-headers"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package v4l LibV4L2)
+		# disable fetching of opentimelineio
+		-DFETCH_OTIO=OFF
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	optfeature "VP8 and VP9 codec support" "media-video/ffmpeg[vpx]"
+}