[gentoo-commits] repo/gentoo:master commit in: dev-python/sqlglot/

["Michał Górny" <mgorny@gentoo.org>]

commit:     0c0e544657d9c9a36e25934077b0e31c449ba26a
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Oct  8 04:56:58 2025 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Oct  8 06:25:51 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0c0e5446

dev-python/sqlglot: Bump to 27.21.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/sqlglot/Manifest               |   1 +
 dev-python/sqlglot/sqlglot-27.21.0.ebuild | 174 ++++++++++++++++++++++++++++++
 2 files changed, 175 insertions(+)

diff --git a/dev-python/sqlglot/Manifest b/dev-python/sqlglot/Manifest
index 9c7539a84492..cabda6f774da 100644
--- a/dev-python/sqlglot/Manifest
+++ b/dev-python/sqlglot/Manifest
@@ -2,3 +2,4 @@ DIST sqlglot-26.33.0-crates.tar.xz 8859792 BLAKE2B abb2051b392c53dc3caa705ddd8df
 DIST sqlglot-26.33.0.tar.gz 5353340 BLAKE2B 18ace866ec89ced24911803497e8cb5c55fc6c157bf62b893e90df914b8be3360403ffff67f196080cdef9b9b9078b86d471494ae9768e7947a8b4d5d39e49af SHA512 df38e899d59bdd07aca0e5370833133308f9c5be4d0c990bf8112a48776fae034b622938aba968769aa5dc5e2957d56da48c89045b91b2d33783e6e25acc4a7b
 DIST sqlglot-27.19.0.tar.gz 5479756 BLAKE2B 72ea02627fe22d6cbe7d40b9c61b93d9eb1f8f8c038efebefc922b6abec73ade89a01cac41acba1c841b91494fa3077544280777e399ef8d07bef8251900f751 SHA512 91e5b252557f7d03fded6625724676617fec9ab5614bae226c2200fea7ba95cdbfe52a224a6274b0cd7d646f58276685e3bd43b3c4180c946d1c1ad7158482ba
 DIST sqlglot-27.20.0.tar.gz 5480742 BLAKE2B 49875da9b993fc2333f9c0cfad9a8cffdd8aa2cc057ae7eb7807f217ab6e3a1a4f268664f3789480c30b7160663f3180b50c47050051a35664c1a28510e98923 SHA512 fef4fde85ebb64069e601c4a1ca59df7a1b4c85218f8a49c32486d0fdbcf234e70319e2b2ae4a908fdc8a9558b5f9c8d90bb45c53c43448d9adb1d1fd98ad866
+DIST sqlglot-27.21.0.tar.gz 5484119 BLAKE2B 901a182c7cd226876cbd248500076044b9ba2302e40c646583e4de78934a8a41bbffc967bf274d7b231eef6774098fa0ccd2a3f04f562e785f51b4842ca63ab4 SHA512 d0e776c40a7a5f0149cb2f48f5be9e6e8c61c163ac74bbe62659e4056f051408f364b58ccae68ea7341e3adee480c8c9113e61b5aa46d951112b7aa4e66d1e8b

diff --git a/dev-python/sqlglot/sqlglot-27.21.0.ebuild b/dev-python/sqlglot/sqlglot-27.21.0.ebuild
new file mode 100644
index 000000000000..e14a71567190
--- /dev/null
+++ b/dev-python/sqlglot/sqlglot-27.21.0.ebuild
@@ -0,0 +1,174 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CRATES="
+	aho-corasick@1.1.3
+	anes@0.1.6
+	anstyle@1.0.10
+	autocfg@1.1.0
+	bumpalo@3.16.0
+	cast@0.3.0
+	cfg-if@1.0.0
+	ciborium-io@0.2.2
+	ciborium-ll@0.2.2
+	ciborium@0.2.2
+	clap@4.5.23
+	clap_builder@4.5.23
+	clap_lex@0.7.4
+	criterion-plot@0.5.0
+	criterion@0.5.1
+	crossbeam-deque@0.8.6
+	crossbeam-epoch@0.9.18
+	crossbeam-utils@0.8.21
+	crunchy@0.2.2
+	either@1.13.0
+	half@2.4.1
+	heck@0.5.0
+	hermit-abi@0.4.0
+	indoc@2.0.4
+	is-terminal@0.4.13
+	itertools@0.10.5
+	itoa@1.0.14
+	js-sys@0.3.76
+	libc@0.2.169
+	log@0.4.22
+	memchr@2.7.4
+	memoffset@0.9.0
+	num-traits@0.2.19
+	once_cell@1.19.0
+	oorandom@11.1.4
+	plotters-backend@0.3.7
+	plotters-svg@0.3.7
+	plotters@0.3.7
+	portable-atomic@1.9.0
+	proc-macro2@1.0.89
+	pyo3-build-config@0.25.0
+	pyo3-ffi@0.25.0
+	pyo3-macros-backend@0.25.0
+	pyo3-macros@0.25.0
+	pyo3@0.25.0
+	quote@1.0.37
+	rayon-core@1.12.1
+	rayon@1.10.0
+	regex-automata@0.4.9
+	regex-syntax@0.8.5
+	regex@1.11.1
+	rustc-hash@2.1.0
+	ryu@1.0.18
+	same-file@1.0.6
+	serde@1.0.216
+	serde_derive@1.0.216
+	serde_json@1.0.133
+	syn@2.0.87
+	target-lexicon@0.13.2
+	tinytemplate@1.2.1
+	unicode-ident@1.0.12
+	unindent@0.2.3
+	walkdir@2.5.0
+	wasm-bindgen-backend@0.2.99
+	wasm-bindgen-macro-support@0.2.99
+	wasm-bindgen-macro@0.2.99
+	wasm-bindgen-shared@0.2.99
+	wasm-bindgen@0.2.99
+	web-sys@0.3.76
+	winapi-util@0.1.9
+	windows-sys@0.52.0
+	windows-sys@0.59.0
+	windows-targets@0.52.6
+	windows_aarch64_gnullvm@0.52.6
+	windows_aarch64_msvc@0.52.6
+	windows_i686_gnu@0.52.6
+	windows_i686_gnullvm@0.52.6
+	windows_i686_msvc@0.52.6
+	windows_x86_64_gnu@0.52.6
+	windows_x86_64_gnullvm@0.52.6
+	windows_x86_64_msvc@0.52.6
+"
+
+CARGO_OPTIONAL=1
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+CRATE_PV=26.33.0
+
+inherit cargo distutils-r1 pypi optfeature
+
+DESCRIPTION="An easily customizable SQL parser and transpiler"
+HOMEPAGE="
+	https://sqlglot.com/
+	https://github.com/tobymao/sqlglot/
+	https://pypi.org/project/sqlglot/
+"
+SRC_URI+="
+	native-extensions? (
+		https://github.com/gentoo-crate-dist/sqlglot/releases/download/v${CRATE_PV}/sqlglot-${CRATE_PV}-crates.tar.xz
+	)
+"
+
+LICENSE="MIT"
+LICENSE+=" native-extensions? ("
+# Dependent crate licenses
+LICENSE+="
+	Apache-2.0 Apache-2.0-with-LLVM-exceptions MIT Unicode-DFS-2016
+"
+LICENSE+=" )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+native-extensions"
+
+BDEPEND="
+	native-extensions? (
+		${RUST_DEPEND}
+		dev-util/maturin[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/pytz[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+QA_FLAGS_IGNORED="usr/lib.*/py.*/site-packages/sqlglotrs/sqlglotrs.*.so"
+
+pkg_setup() {
+	use native-extensions && rust_pkg_setup
+}
+
+src_unpack() {
+	cargo_src_unpack
+}
+
+python_compile() {
+	distutils-r1_python_compile
+
+	if use native-extensions; then
+		local DISTUTILS_USE_PEP517=maturin
+		cd sqlglotrs || die
+		distutils-r1_python_compile
+		cd - >/dev/null || die
+	fi
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# Tests require pyspark or duckdb which aren't in the tree.
+		# Pandas would be a requirement normally, but it gets ignored by proxy.
+		"tests/dataframe/integration/test_dataframe.py"
+		"tests/dataframe/integration/test_grouped_data.py"
+		"tests/dataframe/integration/test_session.py"
+		"tests/test_executor.py"
+		"tests/test_optimizer.py"
+	)
+
+	# make sure not to use an earlier installed version
+	local -x SQLGLOTRS_TOKENIZER=$(usex native-extensions 1 0)
+	rm -rf sqlglotrs || die
+	epytest
+}
+
+pkg_postinst() {
+	optfeature "simplifying timedelta expressions" dev-python/python-dateutil
+}