[gentoo-commits] repo/gentoo:master commit in: dev-util/cvise/

["Sam James" <sam@gentoo.org>]

commit:     8d4c41469f36d9776cfd9d33d2b9f45e8eaeb743
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat Oct  4 05:02:48 2025 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Oct  4 18:07:50 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8d4c4146

dev-util/cvise: add 2.12.0

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-util/cvise/Manifest            |  1 +
 dev-util/cvise/cvise-2.12.0.ebuild | 70 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 71 insertions(+)

diff --git a/dev-util/cvise/Manifest b/dev-util/cvise/Manifest
index 44d4881a3d58..faaa9607920f 100644
--- a/dev-util/cvise/Manifest
+++ b/dev-util/cvise/Manifest
@@ -1 +1,2 @@
 DIST cvise-2.11.0.tar.gz 272016 BLAKE2B 1551cb1c8ee80cad9c4ed5846f5185432649d75f78c9d90cca93ab8e2615fa58f1bb08d43d156289592faac68343d3e021b74e0163eb92b914b16c65c0fe7422 SHA512 4c0844f1ce0596a7aed84018ecf63fbed31e7fb474d341f9947e99ee61274713ad8ae5dce619fcbc7b2acdddb950b1418989e9cd6cd6d7a2031e56226ccf9f57
+DIST cvise-2.12.0.tar.gz 274458 BLAKE2B 7ee8a3d1d53ac930c428cab7d2102b151e9fbc4d1dfff61dc46cb69ba8ce3fd7d42d56c9ab2de9471b8bbda1c9e9ee537d7263e1f00f94ac510f75a6a55af1a0 SHA512 90c36f874985fff3ebfaf0d33d8510c4f03bbb74fcd493c66e5f25b6ee340b01fce78f2828da782e412c95c528e1387f25f20ad0d9dcd185d88fdef3816ba344

diff --git a/dev-util/cvise/cvise-2.12.0.ebuild b/dev-util/cvise/cvise-2.12.0.ebuild
new file mode 100644
index 000000000000..e8e5b2e56d54
--- /dev/null
+++ b/dev-util/cvise/cvise-2.12.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..13} )
+LLVM_COMPAT=( {16..20} )
+inherit cmake llvm-r2 python-single-r1
+
+DESCRIPTION="Super-parallel Python port of the C-Reduce"
+HOMEPAGE="https://github.com/marxin/cvise/"
+SRC_URI="
+	https://github.com/marxin/cvise/archive/v${PV}.tar.gz -> ${P}.tar.gz
+"
+
+LICENSE="UoI-NCSA"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+DEPEND="
+	$(llvm_gen_dep '
+		llvm-core/clang:${LLVM_SLOT}
+		llvm-core/llvm:${LLVM_SLOT}
+	')
+"
+RDEPEND="
+	${DEPEND}
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/chardet[${PYTHON_USEDEP}]
+		dev-python/pebble[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+	')
+	dev-util/unifdef
+	app-alternatives/lex
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	app-alternatives/lex
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pebble[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	llvm-r2_pkg_setup
+}
+
+src_prepare() {
+	sed -i -e 's:-Werror::' -e '/CMAKE_CXX_FLAGS_REL/d' CMakeLists.txt || die
+	cmake_src_prepare
+}
+
+src_test() {
+	cd "${BUILD_DIR}" || die
+	epytest
+}
+
+src_install() {
+	cmake_src_install
+
+	python_fix_shebang "${ED}"
+}