[gentoo-commits] repo/gentoo:master commit in: net-im/profanity/

["Sam James" <sam@gentoo.org>]

commit:     e320bc89b97cab6c1e75751ed4e3f23005e74db7
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat Oct  4 02:32:35 2025 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Oct  4 02:32:47 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e320bc89

net-im/profanity: add 0.15.1

Bug: https://bugs.gentoo.org/953636
Signed-off-by: Sam James <sam <AT> gentoo.org>

 net-im/profanity/Manifest                |  1 +
 net-im/profanity/profanity-0.15.1.ebuild | 90 ++++++++++++++++++++++++++++++++
 2 files changed, 91 insertions(+)

diff --git a/net-im/profanity/Manifest b/net-im/profanity/Manifest
index 0bc81bb371f9..ac0ebb028ed2 100644
--- a/net-im/profanity/Manifest
+++ b/net-im/profanity/Manifest
@@ -1 +1,2 @@
 DIST profanity-0.15.0.tar.gz 967651 BLAKE2B f9767ca2fd1297ba9f31d608cf0af7fbe440f3915ce3cc9180321a11fd8461222b92bf859f590397c612342c85dbd6cd9393e1b3ae6f5b5847c0dd0ca176ada6 SHA512 e7fc08049b19c5d9295f5254a965995634780a7ab31388f70202e3fa19721d5d049d8402b79cfdfa4ac141f760fc1e8b4bce9ff8634a8669687a78f67657fac6
+DIST profanity-0.15.1.tar.gz 988721 BLAKE2B ebe742e3130bb0ce99175cf3753642ffc69598c6bcfb2daf2c4eef16415352f79ab653c31b1364ba46aa5d79354d4484059946a7c1e3aa4cf1a50da566c723d5 SHA512 45020a97bc918e5457c9eee5dd07ed4985c560c425b7c0cb28a4ce731ad86a04945bc4255d78e329ab32eb0074e54c7c6bd207f298a5499bab181fe7ccc20029

diff --git a/net-im/profanity/profanity-0.15.1.ebuild b/net-im/profanity/profanity-0.15.1.ebuild
new file mode 100644
index 000000000000..d88253b93a72
--- /dev/null
+++ b/net-im/profanity/profanity-0.15.1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..13} )
+inherit flag-o-matic python-single-r1
+
+DESCRIPTION="A console based XMPP client inspired by Irssi"
+HOMEPAGE="https://profanity-im.github.io"
+SRC_URI="
+	https://github.com/profanity-im/profanity/releases/download/${PV}/${P}.tar.gz
+"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="libnotify omemo omemo-qrcode otr gpg test xscreensaver python"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="omemo-qrcode? ( omemo ) python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	>=dev-libs/libstrophe-0.12.3:=
+	media-libs/harfbuzz:=
+	net-misc/curl
+	sys-libs/ncurses:=[unicode(+)]
+	sys-libs/readline:=
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/pango
+	x11-misc/shared-mime-info
+	gpg? ( app-crypt/gpgme:= )
+	libnotify? ( x11-libs/libnotify )
+	omemo? (
+		dev-libs/libgcrypt:=
+		net-libs/libsignal-protocol-c
+	)
+	omemo-qrcode? ( media-gfx/qrencode:= )
+	otr? ( net-libs/libotr )
+	python? ( ${PYTHON_DEPS} )
+	xscreensaver? (
+		x11-libs/libXScrnSaver
+		x11-libs/libX11
+	)
+"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-util/cmocka )
+	python? (
+		$(python_gen_cond_dep '
+			dev-python/cython[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	# lto-type-mismatch issue in tests
+	filter-lto
+
+	local myeconfargs=(
+		--enable-gdk-pixbuf
+		$(use_enable libnotify notifications)
+		$(use_enable omemo)
+		$(use_enable omemo-qrcode)
+		$(use_enable otr)
+		$(use_enable python python-plugins)
+		$(use_enable gpg pgp)
+		$(use_with xscreensaver)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake CFLAGS="${CFLAGS}"
+}
+
+src_install() {
+	default
+
+	find "${ED}" -type f -name '*.la' -delete || die
+}