[gentoo-commits] repo/gentoo:master commit in: app-text/libetonyek/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     d912861e1bbfb8f3905270b6967b5bad27d56dd0
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri Sep 26 11:52:42 2025 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri Sep 26 12:12:49 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d912861e

app-text/libetonyek: add 0.1.13

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 app-text/libetonyek/Manifest                 |  1 +
 app-text/libetonyek/libetonyek-0.1.13.ebuild | 60 ++++++++++++++++++++++++++++
 2 files changed, 61 insertions(+)

diff --git a/app-text/libetonyek/Manifest b/app-text/libetonyek/Manifest
index 9472f5565d0b..9be2f9a7c25e 100644
--- a/app-text/libetonyek/Manifest
+++ b/app-text/libetonyek/Manifest
@@ -1 +1,2 @@
 DIST libetonyek-0.1.12.tar.xz 1513688 BLAKE2B d2333229d619019965f4837b3201f6f4caa4a284988a859ccbc1eab8624154135d2ca8e7b3aba5a332b2cb9b683de53ecf147d99ed09acb6c86e2a518fb60b77 SHA512 7b194a3ba8fc5b83b27e69c9cb7ac26df3830a1d2d2e114b01bfd63cf144f41d8c3c238e39e67bb96101fa2ed80e6b41a328a7cdd70628bdd3b9b732576b0980
+DIST libetonyek-0.1.13.tar.xz 1514256 BLAKE2B 1ed81b1c6720a75c9ba9005e763da3a00705794d427a0edeb895e1f9feac69656c5870cb35bb864612fbd0e4fed5ef7f0d7e4a411c1db8622bbea06eb7435281 SHA512 4ef485cc816ca570ec976b63783f457f7e3b2308c46b22712ce888fe668474c9670677d5dc93bd6ada477db9c2039d8c1bfec30c6c396d3c65a4e0292c168d36

diff --git a/app-text/libetonyek/libetonyek-0.1.13.ebuild b/app-text/libetonyek/libetonyek-0.1.13.ebuild
new file mode 100644
index 000000000000..2b18041168b9
--- /dev/null
+++ b/app-text/libetonyek/libetonyek-0.1.13.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://git.libreoffice.org/libetonyek.git"
+	inherit autotools git-r3
+else
+	SRC_URI="https://dev-www.libreoffice.org/src/libetonyek/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+fi
+
+DESCRIPTION="Library parsing Apple Keynote presentations"
+HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libetonyek"
+
+LICENSE="|| ( GPL-2+ LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-text/liblangtag
+	dev-libs/librevenge
+	dev-libs/libxml2:=
+	>=dev-util/mdds-2.1:1=
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+	media-libs/glm
+	dev-build/libtool
+	test? ( dev-util/cppunit )
+"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-text/doxygen )
+"
+
+src_prepare() {
+	default
+	[[ -d m4 ]] || mkdir "m4" || die
+	[[ ${PV} == *9999* ]] && eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-werror
+		--with-mdds=2.1
+		$(use_with doc docs)
+		$(use_enable test tests)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -type f -delete || die
+}