[gentoo-commits] repo/gentoo:master commit in: dev-python/spyder-kernels/

["Michał Górny" <mgorny@gentoo.org>]

commit:     c3ece13902b252663f38c1628441fe29641d22e4
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Sep 11 04:29:39 2025 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Sep 11 04:56:32 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c3ece139

dev-python/spyder-kernels: Bump to 3.1.0_beta1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/spyder-kernels/Manifest                 |  1 +
 .../spyder-kernels-3.1.0_beta1.ebuild              | 98 ++++++++++++++++++++++
 2 files changed, 99 insertions(+)

diff --git a/dev-python/spyder-kernels/Manifest b/dev-python/spyder-kernels/Manifest
index b58ac55ec8d1..ae96e9e74e24 100644
--- a/dev-python/spyder-kernels/Manifest
+++ b/dev-python/spyder-kernels/Manifest
@@ -1 +1,2 @@
 DIST spyder-kernels-3.0.5.gh.tar.gz 240411 BLAKE2B 28600b359fc12f8b3ffe01545a98b2fd3ec7f832e7ca5aa58f809825d7f1060ecc5929a72d615c2543b6b34685ee03b521cd087dd58725315a68e1188b72cd3c SHA512 4aaf57e7e4dc7c985f2c0e64aad6080370f1cf012ef72f49dcaaa5daed4b6b5e0c5cbcde88e127b136c87e3ae17314212dd56f89801edd87382da8d06caa9662
+DIST spyder-kernels-3.1.0b1.gh.tar.gz 245633 BLAKE2B 533f7f2ce40281a90d301f4da8744053eefeed268ef334ee227187d54c7548a606a60df3862e76ccac42721192e4a67248a0d77091dd7c27e1b4be18050dc5d8 SHA512 586fe10a38d193c287aef1d80053fb10da4bf132ac7074432edf0ea90683ef8fbcbbad75cf3346390add69de64fe259f839129e2735c30b4235615874edcd676

diff --git a/dev-python/spyder-kernels/spyder-kernels-3.1.0_beta1.ebuild b/dev-python/spyder-kernels/spyder-kernels-3.1.0_beta1.ebuild
new file mode 100644
index 000000000000..4080e18e70e2
--- /dev/null
+++ b/dev-python/spyder-kernels/spyder-kernels-3.1.0_beta1.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1
+
+MY_P=${P/_beta/b}
+DESCRIPTION="Kernels used by spyder on its ipython console"
+HOMEPAGE="
+	https://github.com/spyder-ide/spyder-kernels/
+	https://pypi.org/project/spyder-kernels/
+"
+SRC_URI="https://github.com/spyder-ide/${PN}/archive/refs/tags/v${PV/_beta/b}.tar.gz -> ${MY_P}.gh.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+
+RDEPEND="
+	dev-python/cloudpickle[${PYTHON_USEDEP}]
+	<dev-python/ipykernel-7[${PYTHON_USEDEP}]
+	>=dev-python/ipykernel-6.29.3[${PYTHON_USEDEP}]
+	<dev-python/ipython-10[${PYTHON_USEDEP}]
+	>=dev-python/ipython-8.13.0[${PYTHON_USEDEP}]
+	<dev-python/jupyter-client-9[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-client-7.4.9[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pyxdg-0.26[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-24.0.0[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.14.3[${PYTHON_USEDEP}]
+	>=dev-python/wurlitzer-1.0.3[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/cython[${PYTHON_USEDEP}]
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/h5py[${PYTHON_USEDEP}]
+			dev-python/pandas[${PYTHON_USEDEP}]
+			dev-python/xarray[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+EPYTEST_PLUGINS=( anyio pytest-rerunfailures )
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# we no longer package distributed or dask
+		spyder_kernels/console/tests/test_console_kernel.py::test_dask_multiprocessing
+
+		# RuntimeError: There is no current event loop in thread 'MainThread'.
+		# https://bugs.gentoo.org/834893
+		spyder_kernels/console/tests/test_console_kernel.py::test_cwd_in_sys_path
+		spyder_kernels/console/tests/test_console_kernel.py::test_multiprocessing
+		spyder_kernels/console/tests/test_console_kernel.py::test_multiprocessing_2
+		spyder_kernels/console/tests/test_console_kernel.py::test_runfile
+		spyder_kernels/console/tests/test_console_kernel.py::test_np_threshold
+		spyder_kernels/console/tests/test_console_kernel.py::test_turtle_launch
+		spyder_kernels/console/tests/test_console_kernel.py::test_matplotlib_inline
+
+		# pydicom only packaged in ::sci at the moment
+		spyder_kernels/utils/tests/test_iofuncs.py::test_load_dicom_files
+
+		# require polars
+		spyder_kernels/console/tests/test_console_kernel.py::test_get_value_with_polars
+		spyder_kernels/utils/tests/test_nsview.py::test_polars_dataframe
+	)
+	local EPYTEST_IGNORE=()
+
+	if ! has_version "dev-python/pandas[${PYTHON_USEDEP}]"; then
+		EPYTEST_IGNORE+=(
+			# require pandas
+			spyder_kernels/utils/tests/test_nsview.py
+		)
+	fi
+
+	if ! has_version "dev-python/h5py[${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			# require hdf5
+			spyder_kernels/utils/tests/test_iofuncs.py::test_save_load_hdf5_files
+			spyder_kernels/utils/tests/test_dochelpers.py
+		)
+	fi
+
+	epytest
+}