[gentoo-commits] repo/gentoo:master commit in: www-client/opera-beta/

["Matt Jolly" <kangie@gentoo.org>]

commit:     18206d42225298b8fb4a6327e89d64791950f6a5
Author:     Matt Jolly <kangie <AT> gentoo <DOT> org>
AuthorDate: Tue Sep  9 08:19:51 2025 +0000
Commit:     Matt Jolly <kangie <AT> gentoo <DOT> org>
CommitDate: Tue Sep  9 08:19:51 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=18206d42

www-client/opera-beta: automated bump (122.0.5643.6)

Signed-off-by: Matt Jolly <kangie <AT> gentoo.org>

 www-client/opera-beta/Manifest                     |   1 +
 .../opera-beta/opera-beta-122.0.5643.6.ebuild      | 166 +++++++++++++++++++++
 2 files changed, 167 insertions(+)

diff --git a/www-client/opera-beta/Manifest b/www-client/opera-beta/Manifest
index 7bc2360439e9..c0f868da2ade 100644
--- a/www-client/opera-beta/Manifest
+++ b/www-client/opera-beta/Manifest
@@ -1,3 +1,4 @@
 DIST opera-beta_121.0.5600.12_amd64.deb 130850344 BLAKE2B 7e9a27535842924c7ea89fafc19382f52fd11740a728e367359dc39fbba64bde35115fa47c29bceaae5236f220f11223ebf796f30485fba3b65210379d191f86 SHA512 60854ed6c3ad4c94b5f08b33426e7832d61534035b21c9444aa70bff1f1066b36b66185b349e16e62d6ee58e0a21702fd07bf8eb40662d124d13e4508fc912a4
 DIST opera-beta_121.0.5600.20_amd64.deb 130902956 BLAKE2B 60e44012bd963a8b1e9308f2594bb0e510282c7e2ea76edbf4bb6bf35b61b2e4db15117595e230a0005cb9bb6f3ec526fe810760e4dfc3a2f8aebda17a7f9605 SHA512 a70dca3912cceaf7a4f02dcbbb4b23f32b015dc4fa5c280a83e823cc86c08d1733b7c6a93a3e2e0350015ab1b6320bac23dbf63dcac7cafdc83425fc5a4f4bba
 DIST opera-beta_121.0.5600.3_amd64.deb 130881048 BLAKE2B 6d8d1a09cb911b42ca85f8fb317a6283379dad9899c2582a041b39402b8e3566e158f7e0f7c93d8c2fcaae732f74d41da49176320005bbe6f085e372f33a1c73 SHA512 8e47bb8aaa74706767b0cb41103354ae2d6fd71ab9565813407332887f8a1f0a15175e0fc667202651ac69c167d00aeaa4dfe592438b93a137fa4dfd21ca5fa1
+DIST opera-beta_122.0.5643.6_amd64.deb 131856364 BLAKE2B 198381d96b5d08563f90f3d5b0a9071cef228449082a21ae8bbc759252309881b33b6eeb88a8cc566d7946d6ea4f524565669e9d6e3289c9a1279649f563dbc4 SHA512 bd234b0e65feb37c954afc151ca4970d4fa6cdb19c986654b1293a599d1dde0c7fc19098a81e0600e257d82b2f692ae059e4abf23fc732148c4912a5e71767c5

diff --git a/www-client/opera-beta/opera-beta-122.0.5643.6.ebuild b/www-client/opera-beta/opera-beta-122.0.5643.6.ebuild
new file mode 100644
index 000000000000..3895c8fe9f75
--- /dev/null
+++ b/www-client/opera-beta/opera-beta-122.0.5643.6.ebuild
@@ -0,0 +1,166 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CHROMIUM_LANGS="
+	bg bn ca cs da de el en-GB en-US es-419 es fil fi fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+
+# These are intended for ebuild maintainer use to force RPM if DEB is not available.
+: ${OPERA_FORCE_RPM=no}
+
+inherit chromium-2 pax-utils xdg
+
+if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+	inherit rpm
+	OPERA_ARCHIVE_EXT="rpm"
+else
+	inherit unpacker
+	OPERA_ARCHIVE_EXT="deb"
+fi
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+# Commit ref from `strings libffmpeg.so | grep -F "FFmpeg version"` matches this Chromium version
+# used to select the correct ffmpeg-chromium version (corresponds to a major version of Chromium)
+# Does not need to be updated for every new version of Opera, only when it breaks
+CHROMIUM_VERSION="137"
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}"
+S=${WORKDIR}
+
+LICENSE="OPERA-2018"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+IUSE="+ffmpeg-chromium +proprietary-codecs +suid qt6"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+	proprietary-codecs? (
+		!ffmpeg-chromium? ( >=media-video/ffmpeg-6.1-r1:0/58.60.60[chromium] )
+		ffmpeg-chromium? ( media-video/ffmpeg-chromium:${CHROMIUM_VERSION} )
+	)
+	qt6? ( dev-qt/qtbase:6[gui,widgets] )
+"
+
+QA_PREBUILT="*"
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rpm_src_unpack "${A[0]}"
+	else
+		unpacker
+	fi
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
+	else
+		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	fi
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rm "${OPERA_HOME}/setup_repo.sh" || die
+	else
+		rm -r "usr/share/lintian" || die
+
+		# fix docs
+		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+		gzip -d usr/share/doc/${PF}/changelog.gz || die
+	fi
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		dosym ../../usr/$(get_libdir)/chromium/libffmpeg.so$(usex ffmpeg-chromium .${CHROMIUM_VERSION} "") \
+			  /${OPERA_HOME}/libffmpeg.so
+	fi
+
+	rm "${OPERA_HOME}/libqt5_shim.so" || die
+	if ! use qt6; then
+		rm "${OPERA_HOME}/libqt6_shim.so" || die
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "/${OPERA_HOME}/opera_sandbox"
+}