[gentoo-commits] repo/proj/guru:dev commit in: gui-apps/fuzzel/

["Jonas Frei" <freijon@pm.me>]

commit:     78f7ec83ee96519c46b545349d0bf818bc13b781
Author:     Jonas Frei <freijon <AT> pm <DOT> me>
AuthorDate: Wed Aug 20 03:31:39 2025 +0000
Commit:     Jonas Frei <freijon <AT> pm <DOT> me>
CommitDate: Wed Aug 20 03:49:29 2025 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=78f7ec83

gui-apps/fuzzel: add 1.13.0

Signed-off-by: Jonas Frei <freijon <AT> pm.me>

 gui-apps/fuzzel/Manifest             |  1 +
 gui-apps/fuzzel/fuzzel-1.13.0.ebuild | 57 ++++++++++++++++++++++++++++++++++++
 2 files changed, 58 insertions(+)

diff --git a/gui-apps/fuzzel/Manifest b/gui-apps/fuzzel/Manifest
index 09bec63f47..a952fafade 100644
--- a/gui-apps/fuzzel/Manifest
+++ b/gui-apps/fuzzel/Manifest
@@ -1 +1,2 @@
 DIST fuzzel-1.12.0.tar.gz 480171 BLAKE2B 075d10974516b149f0c2d602947b2c338e710be20e57e8524b0f51ddaad8c53d8bfb95e68c8d4ec15f0a1601c15f1ca46cfc247a30f658f69865e7773a384113 SHA512 c7d25f46ac064d2cf6875c3e138a23a8120b1f01e2de64b08939009f9575dd96fa252ef3747a63daff5c7454b560795f3930111440c90b44c49aa3f157217021
+DIST fuzzel-1.13.0.tar.gz 500678 BLAKE2B 573d0d20991b9ceeead1036a833e0d422c1cfa858cc97856101200c38339ee9f9cb5a5f5f5968931921803de7d0b3a1457265f3011eb54d39a27814dd5ae6b93 SHA512 82b4d96e9991757ead84b272deae25947a1d6802e74ae790fd9ce06fe7ca170b0306dd30fda6d12b90d8e4b3257c2b6001b30d16ae7b97d4f3c309d0d4d85c50

diff --git a/gui-apps/fuzzel/fuzzel-1.13.0.ebuild b/gui-apps/fuzzel/fuzzel-1.13.0.ebuild
new file mode 100644
index 0000000000..3a65daea02
--- /dev/null
+++ b/gui-apps/fuzzel/fuzzel-1.13.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson optfeature
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://codeberg.org/dnkl/fuzzel.git"
+else
+	SRC_URI="https://codeberg.org/dnkl/fuzzel/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}/${PN}"
+fi
+
+DESCRIPTION="Application launcher for wlroots based Wayland compositors."
+HOMEPAGE="https://codeberg.org/dnkl/fuzzel"
+LICENSE="MIT"
+SLOT="0"
+IUSE="png svg"
+
+DEPEND="
+	dev-libs/wayland
+	<media-libs/fcft-4.0.0
+	>=media-libs/fcft-3.0.0
+	media-libs/fontconfig
+	x11-libs/libxkbcommon
+	x11-libs/pixman
+	png? ( media-libs/libpng )
+	svg? ( media-libs/nanosvg )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	app-text/scdoc
+	>=dev-libs/tllist-1.0.1
+	>=dev-libs/wayland-protocols-1.32
+	dev-util/wayland-scanner
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dpng-backend=$(usex png libpng none)
+		-Dsvg-backend=$(usex svg nanosvg none)
+		$(meson_feature svg system-nanosvg)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	rm -rf "${ED}/usr/share/doc/fuzzel" || die
+}
+
+pkg_postinst() {
+	optfeature "For rounded corner support" x11-libs/cairo
+}