[gentoo-commits] repo/gentoo:master commit in: sys-fs/lxcfs/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     6ab87e51140a3aceaf8ff02492313e67c1f5e5f6
Author:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
AuthorDate: Sat Aug 16 07:36:37 2025 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Sat Aug 16 07:36:37 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6ab87e51

sys-fs/lxcfs: add 6.0.5

Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 sys-fs/lxcfs/Manifest           |  2 +
 sys-fs/lxcfs/lxcfs-6.0.5.ebuild | 81 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 83 insertions(+)

diff --git a/sys-fs/lxcfs/Manifest b/sys-fs/lxcfs/Manifest
index 4b49440980c3..7700d65826c2 100644
--- a/sys-fs/lxcfs/Manifest
+++ b/sys-fs/lxcfs/Manifest
@@ -2,3 +2,5 @@ DIST lxcfs-5.0.4.tar.gz 104249 BLAKE2B 83a7b861136c34da8a24dd525fd0767193f2bbd92
 DIST lxcfs-5.0.4.tar.gz.asc 833 BLAKE2B aff883d24b374b296ea3678670e5e82c723fd0e35cfd7fed555aabbd811a104becc0b741331b4aa4a5129c9fff4dc88c6a86e7d64a89fe86aea81718f5d432dd SHA512 56b639597dbaf3008fe030147ea37192bd465c467a79e11ce139bcaa6bca1625b4bb9c4eda6ea1877446769f0fad9b4c5a3513d4f4415b841db96d5da8325ddc
 DIST lxcfs-6.0.4.tar.gz 106751 BLAKE2B 4f05cb5e31ed1f313eeb42ac7cc9e68031011af363992e9d15266d7c831fb83078821a42181142cb58418dc87b6ae71ccd79559e0c77c19b5810cb2f5dde98ab SHA512 27e27dd14e3ab6d6f33b78f3316d1d15ccdb5af76fd3631770fe8ff4e1d1a3cc6d7a8009a604660fccc63e4fa5f1601c6505f66ab76c11dcfcddd3baf7ff173b
 DIST lxcfs-6.0.4.tar.gz.asc 833 BLAKE2B 71d552694273e6b3fbeaa4fd2a07ad783ca66824fa7fef69ba79a343b65e57295a702efe580c17e77c6fdb3f79364e98206a099ef3ac99b1d1238178cd343e20 SHA512 fecc002f39f841f3ffbfd7c543cdfed61b9276e962a75230b2962a36bbef04f5444481bb1409ba38ed8f619d0887313f1cc84389f64755d6168c017f68bbaeb2
+DIST lxcfs-6.0.5.tar.gz 106565 BLAKE2B 1a726165be6670c7da4cab3e401e81229ba34f0852885de7d96e3099715c67aa5f49b48f7cfead1659cce1d0b3e191b6206df0b214a2487cac35170ea0ba104e SHA512 729c75bca4da79af9c38c6a42dbebf876d861e0b2c4b825c46edc3a39d27bae1a6a4faeff000d8a1e1a887437184a0413f763512c789cf9ce3ddbaab02de4ece
+DIST lxcfs-6.0.5.tar.gz.asc 833 BLAKE2B 58a12c083bf4b1d5138aec172223eed1d79284c6d48cc7262f9e9dac479894f094d6a8f2051aee9352c99947a638bb891cd48690d194e3d4b4392231ff8ebaef SHA512 c50289168d1a6c970dcffe61dcf2ee5296420c91cd8638b0f285e53e07b0e0d3704a199c8eceee2d282b2906e430165e86315271a9bd9335a91252727c2c921c

diff --git a/sys-fs/lxcfs/lxcfs-6.0.5.ebuild b/sys-fs/lxcfs/lxcfs-6.0.5.ebuild
new file mode 100644
index 000000000000..bd783dafb34e
--- /dev/null
+++ b/sys-fs/lxcfs/lxcfs-6.0.5.ebuild
@@ -0,0 +1,81 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit cmake meson python-any-r1 systemd verify-sig
+
+DESCRIPTION="FUSE filesystem for LXC"
+HOMEPAGE="https://linuxcontainers.org/lxcfs/introduction/ https://github.com/lxc/lxcfs/"
+SRC_URI="https://linuxcontainers.org/downloads/lxcfs/${P}.tar.gz
+	verify-sig? ( https://linuxcontainers.org/downloads/lxcfs/${P}.tar.gz.asc )"
+
+LICENSE="Apache-2.0 LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="doc test"
+
+DEPEND="sys-fs/fuse:3="
+RDEPEND="${DEPEND}"
+BDEPEND="${PYTHON_DEPS}
+	virtual/pkgconfig
+	$(python_gen_any_dep '
+		dev-python/jinja2[${PYTHON_USEDEP}]
+	')
+	doc? ( sys-apps/help2man )
+	verify-sig? ( sec-keys/openpgp-keys-linuxcontainers )"
+
+# Needs some black magic to work inside container/chroot.
+RESTRICT="test"
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/linuxcontainers.asc
+
+python_check_deps() {
+	python_has_version -b "dev-python/jinja2[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# Fix python shebangs for python-exec[-native-symlinks], #851480
+	local shebangs=($(grep -rl "#!/usr/bin/env python3" || die))
+	python_fix_shebang -q ${shebangs[*]}
+}
+
+src_configure() {
+	local emesonargs=(
+		--localstatedir "${EPREFIX}/var"
+
+		$(meson_use doc docs)
+		$(meson_use test tests)
+
+		-Dfuse-version=3
+		-Dinit-script=""
+		-Dwith-init-script=""
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	cd "${BUILD_DIR}"/tests || die "failed to change into tests/ directory."
+	./main.sh || die
+}
+
+src_install() {
+	meson_src_install
+
+	newconfd "${FILESDIR}"/lxcfs-5.0.2.confd lxcfs
+	newinitd "${FILESDIR}"/lxcfs-5.0.2.initd lxcfs
+
+	# Provide our own service file (copy of upstream) due to paths being different from upstream,
+	# #728470
+	# https://github.com/lxc/lxcfs/tree/main/config/init
+	systemd_newunit "${FILESDIR}"/lxcfs-5.0.2.service lxcfs.service
+}