[gentoo-commits] repo/gentoo:master commit in: net-fs/mc/

["Yixun Lan" <dlan@gentoo.org>]

commit:     c54e83c4be6baf180faa4fcb8431fc7df5e533f4
Author:     jinqiang zhang <peeweep <AT> 0x0 <DOT> ee>
AuthorDate: Mon Aug  4 15:10:40 2025 +0000
Commit:     Yixun Lan <dlan <AT> gentoo <DOT> org>
CommitDate: Thu Aug  7 00:37:38 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c54e83c4

net-fs/mc: fix Pre-stripped QA and remove block app-misc/mc

rename /usr/bin/mc to /usr/bin/minio-client to fix file collision with
app-misc/mc

Closes: https://bugs.gentoo.org/960264
Signed-off-by: jinqiang zhang <peeweep <AT> 0x0.ee>
Signed-off-by: Yixun Lan <dlan <AT> gentoo.org>

 net-fs/mc/mc-2025.04.16.18.13.26-r1.ebuild | 37 ++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

diff --git a/net-fs/mc/mc-2025.04.16.18.13.26-r1.ebuild b/net-fs/mc/mc-2025.04.16.18.13.26-r1.ebuild
new file mode 100644
index 000000000000..ab2cfcf3c782
--- /dev/null
+++ b/net-fs/mc/mc-2025.04.16.18.13.26-r1.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit go-module
+
+MY_PV="$(ver_cut 1-3)T$(ver_cut 4-7)Z"
+MY_PV=${MY_PV//./-}
+YEAR="$(ver_cut 1)"
+COMMIT_ID="b00526b153a31b36767991a4f5ce2cced435ee8e"
+
+DESCRIPTION="Minio client provides alternatives for ls, cat on cloud storage and filesystems"
+HOMEPAGE="https://github.com/minio/mc"
+SRC_URI="https://github.com/minio/mc/archive/RELEASE.${MY_PV}.tar.gz -> ${P}.tar.gz"
+SRC_URI+=" https://github.com/gentoo-zh/gentoo-deps/releases/download/${P}/${P}-vendor.tar.xz"
+
+S="${WORKDIR}/${PN}-RELEASE.${MY_PV}"
+LICENSE="Apache-2.0 BSD MIT MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+RESTRICT="test" # bug #927667, fails with network-sandbox
+
+src_compile() {
+	# go run buildscripts/gen-ldflags.go
+	local ldflags=" \
+		-X github.com/minio/mc/cmd.Version=${MY_PV} \
+		-X github.com/minio/mc/cmd.CopyrightYear=${YEAR} \
+		-X github.com/minio/mc/cmd.ReleaseTag=RELEASE.${MY_PV} \
+		-X github.com/minio/mc/cmd.CommitID=${COMMIT_ID}"
+	ego build -trimpath --ldflags "${ldflags}"
+}
+
+src_install() {
+	newbin mc minio-client
+	dodoc README.md CONTRIBUTING.md
+}