[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-software/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     76acad5bd86a5f34bfe2c0d0131f02855a3341dd
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Thu Jul 31 12:47:56 2025 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Thu Jul 31 13:17:45 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=76acad5b

gnome-extra/gnome-software: add 48.3

Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 gnome-extra/gnome-software/Manifest                |   1 +
 .../gnome-software/gnome-software-48.3.ebuild      | 116 +++++++++++++++++++++
 2 files changed, 117 insertions(+)

diff --git a/gnome-extra/gnome-software/Manifest b/gnome-extra/gnome-software/Manifest
index b5655d29cac0..e150fef4bbdb 100644
--- a/gnome-extra/gnome-software/Manifest
+++ b/gnome-extra/gnome-software/Manifest
@@ -1,3 +1,4 @@
 DIST gnome-software-46.4.tar.xz 2575200 BLAKE2B bc5af24e0b71f279c26b83c3808bb5ee4e41d405d9a5370f7f37b3f19aab0043b338a1f3212ad74e6cfe02794ec16ec88b222322eb27190c0863a0ac5b88b3fa SHA512 148cdb3d3b3b0d74e00adcc066cf85fc20f86d9196def5132dfbb7b579464abe12c199d7f45b289d980ea634ddbce677be7588e2600a5f08ccd4630276a78799
 DIST gnome-software-47.4.tar.xz 3047336 BLAKE2B a6b875402eb3c889972f93ef59b4aaff807551710dd1749d6c2894a0f964a4e6d50572bd9ac96ae0dc8e43dfa2e49c62443b1a51d8e9d3a9174816d228cbcea5 SHA512 f187fcbae9cafc45815734e2f81810665b266ad8e6400e1aea56e6a430258336e124c51f6d2a62cd9531f2b0c69664b094c3db51ebd6bdcc439447221a628f7b
 DIST gnome-software-47.5.tar.xz 3049164 BLAKE2B 1d780a087d0274e753962b1ceff2592cf8ba8818a28a918f7bd3780d04dd5d439551d7c82100fec6ac36e4a755cd55bee4a7f81712781cb58201b895ff47f002 SHA512 d179f8b28d8a110424a1df35a736ca3b8a5e20b82a902f7c5ffb4343da55b139583da347ad055e3e1dd29bb5cded2e73b86709ea70db583311049d58e4861778
+DIST gnome-software-48.3.tar.xz 3398204 BLAKE2B db708bbdf2743de14f9c6737731adb479ef8d9a61baba8c6bd984738154d5c71b442efa3b993a18ebd882e1f1e6b48f1a54c90d8b7404869d0bcd762e648c16e SHA512 84a0c4944a9f49d2786147f4a8e67cbb14f15fc6482b22024f8b0d6e119bccf0f2a72ca76c36e327a51a9239d25015c13a871a523f47ebe2940852db468e8f8a

diff --git a/gnome-extra/gnome-software/gnome-software-48.3.ebuild b/gnome-extra/gnome-software/gnome-software-48.3.ebuild
new file mode 100644
index 000000000000..11640431599a
--- /dev/null
+++ b/gnome-extra/gnome-software/gnome-software-48.3.ebuild
@@ -0,0 +1,116 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson virtualx xdg
+
+DESCRIPTION="Gnome install & update software"
+HOMEPAGE="https://apps.gnome.org/Software"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~loong ~x86"
+IUSE="dkms flatpak +firmware gtk-doc sysprof udev snap test"
+
+RDEPEND="
+	>=dev-libs/appstream-0.14.0:0=
+	>=x11-libs/gdk-pixbuf-2.32.0:2
+	>=dev-libs/libxmlb-0.3.4:=
+	>=gui-libs/gtk-4.16.0:4
+	>=dev-libs/glib-2.76.0:2
+	>=dev-libs/json-glib-1.6.0
+	>=net-libs/libsoup-3.0:3.0
+	>=gui-libs/libadwaita-1.6.0:1
+	sysprof? ( >=dev-util/sysprof-capture-3.40.1:4 )
+	>=gnome-base/gsettings-desktop-schemas-3.18.0
+	sys-auth/polkit
+	firmware? ( >=sys-apps/fwupd-1.6.2 )
+	flatpak? (
+		>=sys-apps/flatpak-1.14.1
+		dev-util/ostree
+	)
+	snap? (
+		app-containers/snapd
+		>=sys-libs/snapd-glib-1.64:=
+	)
+	udev? ( dev-libs/libgudev )
+	>=gnome-base/gsettings-desktop-schemas-3.18.0
+"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/libglib-testing )
+"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? (
+		dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/Disable-gs-self-test-flatpak.patch"
+)
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	sed -i -e '/install_data.*README\.md.*share\/doc\/gnome-software/d' meson.build || die
+	# We don't need language packs download support, and it fails tests in 3.34.2 for us (if they are enabled)
+	sed -i -e '/subdir.*fedora-langpacks/d' plugins/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use test tests)
+		-Dman=true
+		-Dpackagekit=false
+		# -Dpackagekit_autoremove
+		-Dpolkit=true
+		-Deos_updater=false # Endless OS updater
+		$(meson_use dkms)
+		$(meson_use firmware fwupd)
+		$(meson_use flatpak)
+		-Dmalcontent=false
+		-Drpm_ostree=false
+		-Dwebapps=true
+		-Ddefault_featured_apps=true
+		-Dhardcoded_curated=true
+		-Dhardcoded_foss_webapps=true
+		-Dhardcoded_proprietary_webapps=true
+		$(meson_use udev gudev)
+		-Dapt=false
+		$(meson_use snap)
+		-Dexternal_appstream=false
+		$(meson_use gtk-doc gtk_doc)
+		-Dhardcoded_curated=true
+		# TODO: Will this be beneficial to us with flatpak at least? If
+		# enabled, it shows some apps under installed (probably merely due to
+		# /usr/share/app-info presence), but launching and removal of them is
+		# broken
+		-Ddefault_featured_apps=false
+		-Dmogwai=false #TODO?
+		$(meson_feature sysprof)
+		-Dprofile=''
+		-Dopensuse-distro-upgrade=false
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx dbus-run-session meson test -C "${BUILD_DIR}" || die
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}