[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-clocks/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     3cac06751eace0433cc57e0f7a338b056478b551
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Tue Jul 29 11:39:47 2025 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Tue Jul 29 11:42:58 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3cac0675

gnome-extra/gnome-clocks: add 48.0

Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 gnome-extra/gnome-clocks/Manifest                 |  1 +
 gnome-extra/gnome-clocks/gnome-clocks-48.0.ebuild | 59 +++++++++++++++++++++++
 2 files changed, 60 insertions(+)

diff --git a/gnome-extra/gnome-clocks/Manifest b/gnome-extra/gnome-clocks/Manifest
index 3fd70bed3bd3..595e891a75a4 100644
--- a/gnome-extra/gnome-clocks/Manifest
+++ b/gnome-extra/gnome-clocks/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-clocks-46.0.tar.xz 461960 BLAKE2B 102099e5098e7677a7f65324523c26fd5253f4b992a5b8a1f40b298c5f878bf564f55955f1c14db8993fb9323934b8dbb392c23d2f1c1c7f45ef5bfeab94c3e2 SHA512 37e91c6355d21be94386f5ad7266998c87f138ab5d4274d5caf08a9941499944d8c3ee2d44fb6654a227cb48665ad9ee2ed0f919cb03a1122d7c1ed935cfc353
 DIST gnome-clocks-47.0.tar.xz 461340 BLAKE2B 6c60740cc2afcef57d18447702d3bbfef9bdf21b5150aad1dc6d678153c5d7fd76e4d6d616a7234610563576864e18a970e354a617b3b8a8a6c73a974fb1f932 SHA512 325e1804a80e73f95c8b016e78778c81cd177644694de071d5d7d227494ed7a92f1021179c47001415ddd69883eea081733ca592389626977d7fa9f2fe98a6f8
+DIST gnome-clocks-48.0.tar.xz 462784 BLAKE2B 9f346651737f00d7ed3124f0557557ccff6a1f0dbdbb34c1d3de0000d3235a13e0b0ff61a516d56fbd146eea6d0b3a8d3682905cff3eedd0f7ae7455d7343687 SHA512 6bf6c4c4b8827ccf04df8bf899098145566eeb9bcd5d4df437ef2193fa7c56d7309ab9447cecdd7bec56c2a247b7ed93b1ae4b7a2d099f8fcf34151b4eb11ecb

diff --git a/gnome-extra/gnome-clocks/gnome-clocks-48.0.ebuild b/gnome-extra/gnome-clocks/gnome-clocks-48.0.ebuild
new file mode 100644
index 000000000000..f08fce8e2e15
--- /dev/null
+++ b/gnome-extra/gnome-clocks/gnome-clocks-48.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson vala xdg
+
+DESCRIPTION="Clocks application for GNOME"
+HOMEPAGE="https://apps.gnome.org/Clocks/"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.72:2
+	>=gui-libs/gtk-4.15.3:4
+	>=dev-libs/libgweather-4.2.0:4=
+	gnome-base/gnome-desktop:4=
+	>=sci-geosciences/geocode-glib-1:2
+	>=app-misc/geoclue-2.4:2.0
+	>=gui-libs/libadwaita-1.6_alpha:1
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	$(vala_depend)
+	>=dev-libs/libgweather-4.2.0:4[vala]
+	>=gui-libs/libadwaita-1.6_alpha:1[vala]
+"
+
+DOCS=( AUTHORS.md CONTRIBUTING.md README.md )
+
+src_prepare() {
+	default
+	vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dprofile=default
+		-Ddocs=false
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}