[gentoo-commits] repo/gentoo:master commit in: dev-libs/libdex/

["Sam James" <sam@gentoo.org>]

commit:     28bd24bb18c320d282c43a7df158bfc2e1d4c45c
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat Jun 28 06:01:30 2025 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Jun 28 06:03:08 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=28bd24bb

dev-libs/libdex: add 0.10.1

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-libs/libdex/Manifest             |  1 +
 dev-libs/libdex/libdex-0.10.1.ebuild | 71 ++++++++++++++++++++++++++++++++++++
 2 files changed, 72 insertions(+)

diff --git a/dev-libs/libdex/Manifest b/dev-libs/libdex/Manifest
index a915a1759694..8c170d788cbd 100644
--- a/dev-libs/libdex/Manifest
+++ b/dev-libs/libdex/Manifest
@@ -1,3 +1,4 @@
 DIST libdex-0.10.0.tar.xz 101652 BLAKE2B 7f2e42d3fe630980fdd29bf9bc6339d9e0ba8c4ba47ab5f737a0cd855bcf319fd7ce8b0cf00c61237c4d58be1aa03c7459199a936977d7e784eb894b98f875f5 SHA512 bfdeddd3659a4f51c2b171333f35dc3a12d82c00f4c3f5817e085d1a304c6821f5c005c0fa5cca0d816a94eecdb1aaffaf8aa2355e5fe1aa3fbfe2bd76eba634
+DIST libdex-0.10.1.tar.xz 102088 BLAKE2B e8be9d2c20c60e0800e098cbb284927e7bfee6a4b1acbc1ab464cb1057b105716e2083df14ecf0b2276728b635dcb9cd03a365a1da3999b63b19e8b418cb8b45 SHA512 ada18b95eaddfccfa1d73889979c914c646fe78ff93878346db0a40483206263429b9a97a073b7129da8eeefcb80a1911f994f04f306aa41877c102683a4a1ef
 DIST libdex-0.6.1.tar.xz 99056 BLAKE2B 3899f89ac652c2790c93e2799a5b0d066c45ee314c6f773bb586e49c89a8a78e6a09ebf08263b88b25900a15ac736d2bd37590720e0ac0e074581342534eaba3 SHA512 36be15d2da9edeae195abcb6f97639dd7fdea74463cdfdf752293007e44ab41a5e5350a7005883f202d70f96047567fba6370f1a2c45a0f898c242bebc88e847
 DIST libdex-0.8.1.tar.xz 99480 BLAKE2B 2a10a9a134cdb2017b6136a54e484f6fd2bb9329957f4d3f205edabdbcbb659f3a1c97a2b1a1c61a06f253a85733500b9475eebd8554e9af5cb0abcec232052d SHA512 fc3f4d81b3a3e5c87758b2f706dc02c558becafc489c620ca491ca3b658f4c00cbc48886c6f5271e7308c4d7255610ec7ece1ad77308b5fac6088402a96543e0

diff --git a/dev-libs/libdex/libdex-0.10.1.ebuild b/dev-libs/libdex/libdex-0.10.1.ebuild
new file mode 100644
index 000000000000..b313d8d18e6b
--- /dev/null
+++ b/dev-libs/libdex/libdex-0.10.1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org linux-info meson vala
+
+DESCRIPTION="Dex provides Future-based programming for GLib-based applications"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/libdex"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~arm64 ~loong ~x86"
+
+IUSE="+eventfd gtk-doc +introspection +liburing sysprof test vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.68:2
+	liburing? ( >=sys-libs/liburing-0.7:= )
+	introspection? ( dev-libs/gobject-introspection:= )
+	sysprof? ( dev-util/sysprof-capture:4 )
+	elibc_musl? ( sys-libs/libucontext )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	vala? ( $(vala_depend) )
+	dev-util/glib-utils
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gi-docgen )
+"
+
+pkg_setup() {
+	if use eventfd && linux_config_exists; then
+		if ! linux_chkconfig_present EVENTFD ; then
+			ewarn "CONFIG_EVENTFD must be enabled for USE=eventfd"
+		fi
+	fi
+}
+
+src_prepare() {
+	default
+	use vala && vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc docs)
+		-Dexamples=false
+		$(meson_use vala vapi)
+		$(meson_feature introspection)
+		$(meson_use sysprof)
+		$(meson_use test tests)
+		$(meson_feature liburing)
+		$(meson_feature eventfd)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/${PN}-1 "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}