From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1762712-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from smtp.gentoo.org (woodpecker.gentoo.org [140.211.166.183])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange X25519 server-signature RSA-PSS (4096 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id 53A98158091
	for <garchives@archives.gentoo.org>; Wed, 25 Jun 2025 12:48:49 +0000 (UTC)
Received: from lists.gentoo.org (bobolink.gentoo.org [140.211.166.189])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange x25519)
	(No client certificate requested)
	(Authenticated sender: relay-lists.gentoo.org@gentoo.org)
	by smtp.gentoo.org (Postfix) with ESMTPSA id 379FA340F94
	for <garchives@archives.gentoo.org>; Wed, 25 Jun 2025 12:48:49 +0000 (UTC)
Received: from bobolink.gentoo.org (localhost [127.0.0.1])
	by bobolink.gentoo.org (Postfix) with ESMTP id CAE8A110560;
	Wed, 25 Jun 2025 12:48:39 +0000 (UTC)
Received: from smtp.gentoo.org (mail.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange x25519)
	(No client certificate requested)
	by bobolink.gentoo.org (Postfix) with ESMTPS id C38D0110560
	for <gentoo-commits@lists.gentoo.org>; Wed, 25 Jun 2025 12:48:39 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange x25519)
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id 77EDC341000
	for <gentoo-commits@lists.gentoo.org>; Wed, 25 Jun 2025 12:48:39 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id EA5E22A7E
	for <gentoo-commits@lists.gentoo.org>; Wed, 25 Jun 2025 12:48:36 +0000 (UTC)
From: "Petr Vaněk" <arkamar@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Petr Vaněk" <arkamar@gentoo.org>
Message-ID: <1750855383.0b95f043bed7d6d1f9045127fb23f2afe2d2b6dc.arkamar@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-db/mariadb-connector-c/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-db/mariadb-connector-c/Manifest dev-db/mariadb-connector-c/mariadb-connector-c-3.3.15.ebuild
X-VCS-Directories: dev-db/mariadb-connector-c/
X-VCS-Committer: arkamar
X-VCS-Committer-Name: Petr Vaněk
X-VCS-Revision: 0b95f043bed7d6d1f9045127fb23f2afe2d2b6dc
X-VCS-Branch: master
Date: Wed, 25 Jun 2025 12:48:36 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 22c738eb-9f8e-4865-892d-df0d4e499ec5
X-Archives-Hash: a9a3d2b66283da916f93ab3e3441c2a4

commit:     0b95f043bed7d6d1f9045127fb23f2afe2d2b6dc
Author:     Petr Vaněk <arkamar <AT> gentoo <DOT> org>
AuthorDate: Mon Jun 23 09:16:03 2025 +0000
Commit:     Petr Vaněk <arkamar <AT> gentoo <DOT> org>
CommitDate: Wed Jun 25 12:43:03 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0b95f043

dev-db/mariadb-connector-c: add 3.3.15

- The sed for -Werror is no longer needed
- Rework sed for test skipping
- Skip few more tests, two are related to --skip-grant-tables, bug
  #905412 and bug #927643, one might be related to domain socket
- Migrate to tc-ld-force-bfd
- It is no longer necessary to filter LTO, the package builds fine with
  it, bug #855233
- The zstd patch is no longer applied, zstd.so is a client plugin,
  therefore it belongs to this package but it should not be installed by
  dev-db/mariadb. This was corrected in dev-db/mariadb-1.4.7-r1, older
  versions are weak blocked.

Bug: https://bugs.gentoo.org/855233
Bug: https://bugs.gentoo.org/905412
Bug: https://bugs.gentoo.org/927643
Signed-off-by: Petr Vaněk <arkamar <AT> gentoo.org>

 dev-db/mariadb-connector-c/Manifest                |   1 +
 .../mariadb-connector-c-3.3.15.ebuild              | 134 +++++++++++++++++++++
 2 files changed, 135 insertions(+)

diff --git a/dev-db/mariadb-connector-c/Manifest b/dev-db/mariadb-connector-c/Manifest
index e7b829264f20..a86b759d3f80 100644
--- a/dev-db/mariadb-connector-c/Manifest
+++ b/dev-db/mariadb-connector-c/Manifest
@@ -1 +1,2 @@
+DIST mariadb-connector-c-3.3.15-src.tar.gz 1404442 BLAKE2B 0df65d59a9d65ab9d10363ae380eece94ebaf84bee25815a526a26e358865f27244b3b5f0b773f1facdcdac70c4c5ccb2c79b3b2bbbfa4823a15d87d85dd36c3 SHA512 3ef6476ece33585134c52d31aaa83191f9171ff9ef0e11064aabbd8ce0bdad798fb0bcd2ca049b0b6c61c1eecf48e5e9f0ab54981e16ca419ac11480810de1e8
 DIST mariadb-connector-c-3.3.8-src.tar.gz 1393368 BLAKE2B 09a8a310f97809f0b0396770a77d4512fe1124de263e2077e5a14a2fa1fbc59d7e35a09d97b0471b687943fc9ce06925507e4b950fdacfdc7ca04ea5ee56bf9e SHA512 d2630bda8deb28696842a6b5dd308060a8b9a83a04dfb3ed908387f53af4108510c6f536aaecc4a3c9a035c7be91b98229d6c480366a3579b6be2c5a8d85ff56

diff --git a/dev-db/mariadb-connector-c/mariadb-connector-c-3.3.15.ebuild b/dev-db/mariadb-connector-c/mariadb-connector-c-3.3.15.ebuild
new file mode 100644
index 000000000000..02389b4925a4
--- /dev/null
+++ b/dev-db/mariadb-connector-c/mariadb-connector-c-3.3.15.ebuild
@@ -0,0 +1,134 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} == 9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/MariaDB/mariadb-connector-c.git"
+else
+	MY_PN=${PN#mariadb-}
+	MY_PV=${PV/_b/-b}
+	SRC_URI="https://downloads.mariadb.com/Connectors/c/connector-c-${PV}/${P}-src.tar.gz"
+	S="${WORKDIR%/}/${PN}-${MY_PV}-src"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~x86"
+fi
+
+inherit cmake-multilib flag-o-matic toolchain-funcs
+
+DESCRIPTION="C client library for MariaDB/MySQL"
+HOMEPAGE="https://mariadb.org/"
+
+LICENSE="LGPL-2.1"
+SLOT="0/3"
+IUSE="+curl gnutls kerberos +ssl static-libs test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	app-arch/zstd:=[${MULTILIB_USEDEP}]
+	sys-libs/zlib:=[${MULTILIB_USEDEP}]
+	virtual/libiconv:=[${MULTILIB_USEDEP}]
+	curl? ( net-misc/curl[${MULTILIB_USEDEP}] )
+	kerberos? (
+		|| (
+			app-crypt/mit-krb5[${MULTILIB_USEDEP}]
+			app-crypt/heimdal[${MULTILIB_USEDEP}]
+		)
+	)
+	ssl? (
+		gnutls? ( >=net-libs/gnutls-3.3.24:=[${MULTILIB_USEDEP}] )
+		!gnutls? ( dev-libs/openssl:=[${MULTILIB_USEDEP}] )
+	)
+"
+BDEPEND="test? ( dev-db/mariadb[server] )"
+RDEPEND="${DEPEND}
+	!<dev-db/mariadb-11.4.7-r1
+"
+
+MULTILIB_CHOST_TOOLS=( /usr/bin/mariadb_config )
+MULTILIB_WRAPPED_HEADERS+=( /usr/include/mariadb/mariadb_version.h )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.1.3-fix-pkconfig-file.patch
+)
+
+src_prepare() {
+	local sedargs=(
+		# These tests the remote_io plugin which requires network access
+		-e '/{"test_remote1/s:{://&:'
+
+		# These tests don't work with --skip-grant-tables
+		-e '/{"test_conc366/s:{://&:'
+		-e '/{"test_conc544/s:{://&:'
+		-e '/{"test_conc627/s:{://&:'
+		-e '/{"test_conc66/s:{://&:'
+
+		# [Warning] Aborted connection 2078 to db: 'test' user: 'root' host: '' (Got an error reading communication packets)
+		# Not sure about this one - might also require network access
+		-e '/{"test_default_auth/s:{://&:'
+
+		# Not sure about this one eighter. It should fail on connection but it
+		# does not. Maybe because we use domain socket?
+		-e '/{"test_conc26/s:{://&:'
+	)
+
+	sed -i "${sedargs[@]}" unittest/libmariadb/{connection,misc,ps_bugs}.c || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	# mariadb cannot use ld.gold, bug #508724
+	tc-ld-is-gold && tc-ld-force-bfd
+
+	# bug #943757
+	append-cflags -std=gnu17
+
+	cmake-multilib_src_configure
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DWITH_EXTERNAL_ZLIB=ON
+		-DWITH_SSL:STRING=$(usex ssl $(usex gnutls GNUTLS OPENSSL) OFF)
+		-DWITH_CURL=$(usex curl)
+		-DWITH_ICONV=ON
+		-DCLIENT_PLUGIN_AUTH_GSSAPI_CLIENT:STRING=$(usex kerberos DYNAMIC OFF)
+		-DMARIADB_UNIX_ADDR="${EPREFIX}/var/run/mysqld/mysqld.sock"
+		-DINSTALL_LIBDIR="$(get_libdir)"
+		-DINSTALL_MANDIR=share/man
+		-DINSTALL_PCDIR="$(get_libdir)/pkgconfig"
+		-DINSTALL_PLUGINDIR="$(get_libdir)/mariadb/plugin"
+		-DINSTALL_BINDIR=bin
+		-DWITH_UNIT_TESTS=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+multilib_src_test() {
+	mkdir -vp "${T}/mysql/data" || die
+
+	mysql_install_db --no-defaults --datadir="${T}/mysql/data" || die
+	mysqld --no-defaults --datadir="${T}/mysql/data" --socket="${T}/mysql/mysql.sock" --skip-grant-tables --skip-networking &
+
+	local attempts=0
+	while ! mysqladmin ping --socket="${T}/mysql/mysql.sock" --silent ; do
+		# 5 minutes should be more than enough
+		if [[ ${attempts} -gt 300 ]] ; then
+			die "mysqld not found after 300 seconds, aborting"
+		fi
+
+		sleep 1
+		attempts=$((attempts + 1))
+	done
+
+	cd unittest/libmariadb || die
+	MYSQL_TEST_SOCKET="${T}/mysql/mysql.sock" MARIADB_CC_TEST=1 ctest --verbose || die
+}
+
+multilib_src_install_all() {
+	if ! use static-libs ; then
+		find "${ED}" -name "*.a" -delete || die
+	fi
+}