[gentoo-commits] repo/gentoo:master commit in: dev-python/opentelemetry-api/

["Michał Górny" <mgorny@gentoo.org>]

commit:     9c8e1bda7a2eaddadcc1c2c91e406cf7924df36a
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Jun  5 03:12:08 2025 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Jun  5 03:42:24 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9c8e1bda

dev-python/opentelemetry-api: Bump to 1.34.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/opentelemetry-api/Manifest              |  1 +
 .../opentelemetry-api-1.34.0.ebuild                | 61 ++++++++++++++++++++++
 2 files changed, 62 insertions(+)

diff --git a/dev-python/opentelemetry-api/Manifest b/dev-python/opentelemetry-api/Manifest
index dd55a70c0c1d..f7fa38a7385f 100644
--- a/dev-python/opentelemetry-api/Manifest
+++ b/dev-python/opentelemetry-api/Manifest
@@ -1 +1,2 @@
 DIST opentelemetry-python-1.33.1.gh.tar.gz 1235726 BLAKE2B 13d1ba3667591daef6fe137b959eb04d296392a3d6f3e9944d8a692b483d24629871eae0035ec59002f106dcc4efff055c58b712edb03ee0a8eb829244654e9e SHA512 12152893ba968a7129afd44e7c4b98ab63e35618b1cf7a1724bba41a767b1321eb5ed4c54722bf257b7eb223e60537c0c8acb90e1e1677ac316b54f7748115bd
+DIST opentelemetry-python-1.34.0.gh.tar.gz 1225735 BLAKE2B 1b09460a29608f9b0d1eae4a4fc7868dac8a6f91b93503d9709cc58ad8592494d331c92f46b4a6d780082992315f297e4fc018ec5d2b7f3e63ab1e942bb520e9 SHA512 a2e3533471ad4696c19c39fd658e0c5edebbf9c7dd2953e4e92e1d719b015d51c068912a3300123fb80afc71d79c0b19c5bf57668afdfc797b2c1b1b12369870

diff --git a/dev-python/opentelemetry-api/opentelemetry-api-1.34.0.ebuild b/dev-python/opentelemetry-api/opentelemetry-api-1.34.0.ebuild
new file mode 100644
index 000000000000..02ba2aa4d5c5
--- /dev/null
+++ b/dev-python/opentelemetry-api/opentelemetry-api-1.34.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1
+
+MY_P="opentelemetry-python-${PV}"
+DESCRIPTION="OpenTelemetry Python API"
+HOMEPAGE="
+	https://opentelemetry.io/
+	https://pypi.org/project/opentelemetry-api/
+	https://github.com/open-telemetry/opentelemetry-python/
+"
+SRC_URI="
+	https://github.com/open-telemetry/opentelemetry-python/archive/refs/tags/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/${PN}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/importlib-metadata-6.0[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-4.5.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	default
+
+	# Unnecessary restriction
+	sed -i -e '/importlib-metadata/s:, < [0-9.]*::' pyproject.toml || die
+}
+
+python_test() {
+	cp -a "${BUILD_DIR}"/{install,test} || die
+	local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
+
+	for dep in opentelemetry-semantic-conventions opentelemetry-sdk \
+		tests/opentelemetry-test-utils
+	do
+		pushd "${WORKDIR}/${MY_P}/${dep}" >/dev/null || die
+		distutils_pep517_install "${BUILD_DIR}"/test
+		popd >/dev/null || die
+	done
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}