[gentoo-commits] repo/gentoo:master commit in: dev-python/spyder/

["Nowa Ammerlaan" <nowa@gentoo.org>]

commit:     9bf37c7d888196df1257ab9c75df7c3c4b75f42f
Author:     Nowa Ammerlaan <nowa <AT> gentoo <DOT> org>
AuthorDate: Fri May 23 07:00:31 2025 +0000
Commit:     Nowa Ammerlaan <nowa <AT> gentoo <DOT> org>
CommitDate: Fri May 23 07:00:42 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9bf37c7d

dev-python/spyder: add 6.0.7

Signed-off-by: Nowa Ammerlaan <nowa <AT> gentoo.org>

 dev-python/spyder/Manifest            |   1 +
 dev-python/spyder/spyder-6.0.7.ebuild | 203 ++++++++++++++++++++++++++++++++++
 2 files changed, 204 insertions(+)

diff --git a/dev-python/spyder/Manifest b/dev-python/spyder/Manifest
index 0c780363e359..f5006f203848 100644
--- a/dev-python/spyder/Manifest
+++ b/dev-python/spyder/Manifest
@@ -1,5 +1,6 @@
 DIST spyder-6.0.3.gh.tar.gz 15774411 BLAKE2B a9089c4d94e29cd38f2a80606ccd51daf443953f605dba22a1d7709b583add24d1a35b519a068e53b111bb96e04c27cb0a49b3d8f6fc88ac2f0e4667146361d0 SHA512 2f71667b54b8e8b85d862cb0e16d3657a2d1ce81bafa3170335866725c63e29e2349d8bff9a34422c9ff018677fd92f98d7f0ff22a064fe08e425492df216091
 DIST spyder-6.0.5.gh.tar.gz 15820718 BLAKE2B ccca332631f12d6f06ecee2f47ab7af0557aa0502eca296f0d0c712a7b66d4b745efcc7e248de30bb02e655bdfb0bffb61da563a308c4e9eea24829abac25d43 SHA512 afc4913a4075a6c25708adcef7a3311b7f3a1af9948734f63e642b5002459b2d2568631c859bd68c182afde709ccdae8966edf173c01cb5b991dcdfad447b823
 DIST spyder-6.0.6.gh.tar.gz 15831592 BLAKE2B d55066810e2eb51a2e4ab0e118e389eb7a3ab019c6cd069ee4d723f5fa99440fadd8a110b4a4c2816c6b7436be6cdb9969b1511c9c5bd2974af5b5cd8a9b4da0 SHA512 25cc04c08b7b917207f7e985c1405f939248be2b5acd688d2125e50ccb8ef722753784b5fe9400cedf69e1c896cb1c0c455821c443af4984ebb850232193ecab
+DIST spyder-6.0.7.gh.tar.gz 15831723 BLAKE2B a9f3760415cc979f00ceab0d2ec5cd0d51ac4052bd61d17c611dd5ed380a79f78bb64f6765a19d6591dcbb630e4ae80d6ab37be0a2a32f50404dde1b0fcfdbab SHA512 29753fbc666999dbc289337589907e3752230e46cf10913d19d18245eec28dc70719464c135e1096aa37e525779d64b3ddba97df8e04a53447fc4c83131a45d5
 DIST spyder-docs-98004cb46d97fa9fa1cfc3f469919928761e7054.gh.tar.gz 93375891 BLAKE2B c98d391bb33b1ba70bf9c8e8072073e87437541aacd4be42140711b786e8ae07bf5a7ca53dffdb826922b5523150fa2950b04117c335dc57f7c2c22eb693c23f SHA512 55e13f9a55075aed007be32581af954d406703dd9586352084162e01865f943c5aff3aa11b50bdc9813dd8a3a52f8fa8f961c73cfc3f96d95930f2a7b823a1d1
 DIST spyder-docs-fa91f0e9c8c2da33e7ec974e6b0e2a5ed6f04b10.gh.tar.gz 93358798 BLAKE2B 81f4d1d7b1244cb05df621e764c57e856952d9ec1b923a0d6529280651f8e15c586be0c7fe1dc65eed3792033cf0f1e5e8813d79706dbbfca0dcff29cb476831 SHA512 39d0a2d6ef45ebfd3e656916bad18adb7b4f3981e619dcb16fc6160b445cf80a264c4fd8d82f61a51a55774bf2f2a08ac0b1fb4201b2cce9046a0ddd1062daa5

diff --git a/dev-python/spyder/spyder-6.0.7.ebuild b/dev-python/spyder/spyder-6.0.7.ebuild
new file mode 100644
index 000000000000..8811583f6eff
--- /dev/null
+++ b/dev-python/spyder/spyder-6.0.7.ebuild
@@ -0,0 +1,203 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..13} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 optfeature xdg #virtualx
+
+# Commit of documentation to fetch
+DOCS_PV="98004cb46d97fa9fa1cfc3f469919928761e7054"
+
+DESCRIPTION="The Scientific Python Development Environment"
+HOMEPAGE="
+	https://www.spyder-ide.org/
+	https://github.com/spyder-ide/spyder/
+	https://pypi.org/project/spyder/
+"
+SRC_URI="
+	https://github.com/spyder-ide/${PN}/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz
+	https://github.com/spyder-ide/${PN}-docs/archive/${DOCS_PV}.tar.gz -> ${PN}-docs-${DOCS_PV}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+# Missing deps and broken
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-python/aiohttp-3.9.3[${PYTHON_USEDEP}]
+	>=dev-python/asyncssh-2.14.0[${PYTHON_USEDEP}]
+	<dev-python/asyncssh-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/atomicwrites-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/bcrypt-4.3.0[${PYTHON_USEDEP}]
+	>=dev-python/chardet-2.0.0[${PYTHON_USEDEP}]
+	>=dev-util/cookiecutter-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/diff-match-patch-20181111[${PYTHON_USEDEP}]
+	>=dev-python/intervaltree-3.0.2[${PYTHON_USEDEP}]
+	>=dev-python/ipython-pygments-lexers-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/jellyfish-0.7[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/keyring-17.0.0[${PYTHON_USEDEP}]
+	>=dev-python/nbconvert-4.0[${PYTHON_USEDEP}]
+	>=dev-python/numpydoc-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.4.0[${PYTHON_USEDEP}]
+	>=dev-python/pickleshare-0.4[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5.3[${PYTHON_USEDEP}]
+	>=dev-python/pygithub-2.3.0[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
+	>=dev-python/pylint-venv-3.0.2[${PYTHON_USEDEP}]
+	>=dev-python/python-lsp-black-2.0.0[${PYTHON_USEDEP}]
+	<dev-python/python-lsp-black-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyls-spyder-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/pyuca-1.2[${PYTHON_USEDEP}]
+	>=dev-python/qdarkstyle-3.2.0[${PYTHON_USEDEP}]
+	<dev-python/qdarkstyle-3.3.0[${PYTHON_USEDEP}]
+	>=dev-python/qstylizer-0.2.2[${PYTHON_USEDEP}]
+	>=dev-python/qtawesome-1.4.0[${PYTHON_USEDEP}]
+	<dev-python/qtawesome-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/qtconsole-5.6.1[${PYTHON_USEDEP}]
+	<dev-python/qtconsole-5.7.0[${PYTHON_USEDEP}]
+	>=dev-python/qtpy-2.4.0[${PYTHON_USEDEP},pyqt6,quick,svg,webengine]
+	>=dev-python/rtree-0.9.7[${PYTHON_USEDEP}]
+	>=dev-python/sphinx-0.6.6[${PYTHON_USEDEP}]
+	>=dev-python/spyder-kernels-3.0.5[${PYTHON_USEDEP}]
+	<dev-python/spyder-kernels-3.1.0[${PYTHON_USEDEP}]
+	>=dev-python/superqt-0.6.2[${PYTHON_USEDEP}]
+	<dev-python/superqt-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/textdistance-4.2.0[${PYTHON_USEDEP}]
+	>=dev-python/three-merge-0.1.1[${PYTHON_USEDEP}]
+	>=dev-python/watchdog-0.10.3[${PYTHON_USEDEP}]
+	>=dev-python/yarl-1.9.4[${PYTHON_USEDEP}]
+"
+
+# BDEPEND="
+# 	test? (
+# 		dev-python/cython[${PYTHON_USEDEP}]
+# 		dev-python/flaky[${PYTHON_USEDEP}]
+# 		dev-python/matplotlib[tk,${PYTHON_USEDEP}]
+# 		dev-python/pandas[${PYTHON_USEDEP}]
+# 		dev-python/pillow[${PYTHON_USEDEP}]
+# 		dev-python/pytest-lazy-fixture[${PYTHON_USEDEP}]
+# 		dev-python/pytest-mock[${PYTHON_USEDEP}]
+# 		dev-python/pytest-order[${PYTHON_USEDEP}]
+# 		dev-python/pytest-qt[${PYTHON_USEDEP}]
+# 		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+# 		dev-python/pyyaml[${PYTHON_USEDEP}]
+# 		dev-python/qtpy[${PYTHON_USEDEP}]
+# 		dev-python/scipy[${PYTHON_USEDEP}]
+# 		dev-python/sympy[${PYTHON_USEDEP}]
+# 	)"
+
+# Based on the courtesy of Arfrever
+# This patch removes a call to update-desktop-database during build
+# This fails because access is denied to this command during build
+PATCHES=(
+	"${FILESDIR}/${PN}-5.0.0-build.patch"
+	"${FILESDIR}/${PN}-6.0.3-no-dep-on-importlib.patch"
+)
+
+DOCS=(
+	"AUTHORS.txt"
+	"Announcements.md"
+	"CHANGELOG.md"
+	"CODE_OF_CONDUCT.md"
+	"CONTRIBUTING.md"
+	"NOTICE.txt"
+	"README.md"
+	"RELEASE.md"
+)
+
+distutils_enable_tests pytest
+# TODO: Package sphinx-design
+# distutils_enable_sphinx docs/doc \
+# 	dev-python/sphinx-panels \
+# 	dev-python/pydata-sphinx-theme \
+# 	dev-python/sphinx-multiversion
+
+python_prepare_all() {
+	# move docs into workdir
+	mv ../spyder-docs-${DOCS_PV}* docs || die
+
+	# these dependencies are packaged separately:
+	#    dev-python/spyder-kernels,
+	#    dev-python/python-lsp-server,
+	#    dev-python/qdarkstyle
+	rm -r external-deps/* || die
+	# runs against things packaged in external-deps dir
+	rm conftest.py || die
+
+	# Do not depend on pyqt5<5.16, this dependency is carried by QtPy[pyqt5]
+	# Do not depend on pyqtwebengine<5.16, this dependency is carried by QtPy[webengine]
+	# Do not depend on parso and jedi, this is dependency is carried in python-lsp-server
+	# Do not depend on python-lsp-server, this dependency is carried in pyls-spyder
+	# Do not depend on ipython, this dependency is carried in spyder-kernels
+	# The explicit version requirements only make things more complicated, if e.g.
+	# pyls-spyder gains compatibility with a newer version of python-lsp-server
+	# in a new release it will take time for this information to propagate into
+	# the next spyder release. So just remove the dependency and let the other
+	# ebuilds handle the version requirements to speed things up and prevent
+	# issues such as Bug 803269.
+	sed -i \
+		-e "/'pyqt5[ 0-9<=>.,]*',/d" \
+		-e "/'pyqtwebengine[ 0-9<=>.,]*',/d" \
+		-e "/'python-lsp-server\[all\][ 0-9<=>.,]*',/d" \
+		-e "/'parso[ 0-9<=>.,]*',/d" \
+		-e "/'jedi[ 0-9<=>.,]*',/d" \
+		-e "/'pylint[ 0-9<=>.,]*',/d" \
+			setup.py || die
+		# -e "/'ipython[ 0-9<=>.,]*',/d" \
+	sed -i \
+		-e "/^PYLS_REQVER/c\PYLS_REQVER = '>=0.0.1'" \
+		-e "/^PYLSP_REQVER/c\PYLSP_REQVER = '>=0.0.1'" \
+		-e "/^PARSO_REQVER/c\PARSO_REQVER = '>=0.0.1'" \
+		-e "/^JEDI_REQVER/c\JEDI_REQVER = '>=0.0.1'" \
+		-e "/^PYLINT_REQVER/c\PYLINT_REQVER = '>=0.0.1'" \
+			spyder/dependencies.py || die
+		# -e "/^IPYTHON_REQVER/c\IPYTHON_REQVER = '>=0.0.1'" \
+
+	# do not check deps, fails because we removed dependencies above
+	sed -i -e 's:test_dependencies_for_spyder_setup_install_requires_in_sync:_&:' \
+		spyder/tests/test_dependencies_in_sync.py || die
+
+	# skip online test
+	rm spyder/widgets/github/tests/test_github_backend.py || die
+
+	export SPYDER_QT_BINDING=pyqt6
+
+	distutils-r1_python_prepare_all
+}
+
+# Calling pytest directly somehow passes the pytest arguments to spyder
+# causing an invalid argument error
+# python_test() {
+# 	virtx "${EPYTHON}" runtests.py
+# }
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "2D/3D plotting in the Python and IPython consoles" dev-python/matplotlib
+	optfeature "View and edit DataFrames and Series in the Variable Explorer" dev-python/pandas
+	optfeature "View and edit two or three dimensional arrays in the Variable Explorer" dev-python/numpy
+	optfeature "Symbolic mathematics in the IPython console" dev-python/sympy
+	optfeature "Import Matlab workspace files in the Variable Explorer" dev-python/scipy
+	optfeature "Run Cython files in the IPython console" dev-python/cython
+	optfeature "The hdf5/h5py plugin" dev-python/h5py
+	optfeature "The line profiler plugin" dev-python/spyder-line-profiler
+	optfeature "Vim key bindings" dev-python/spyder-vim
+	optfeature "Unittest support" dev-python/spyder-unittest
+	optfeature "System terminal inside spyder" dev-python/spyder-terminal
+	optfeature "Jupyter notebook support" dev-python/spyder-notebook
+	# spyder-memory-profiler is not compatible with spyder-5.2+ yet
+	# optfeature "The memory profiler plugin" dev-python/spyder-memory-profiler
+	# spyder-reports not yet updated to >=spyder-4.0.0
+	# optfeature "Markdown reports using Pweave" dev-python/spyder-reports
+	# Plugins with no release yet:
+	# optfeature "Manage virtual environments and packages" dev-python/spyder-env-manager
+	# optfeature "VCS (e.g. git) integration" dev-python/spyder-vcs
+}