[gentoo-commits] repo/gentoo:master commit in: dev-util/diffoscope/

["Sam James" <sam@gentoo.org>]

commit:     6d1ac9a2add3de92b2cbe9a53b25219b9c9b125c
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun May 11 02:00:57 2025 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun May 11 02:00:57 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6d1ac9a2

dev-util/diffoscope: add 295

Bug: https://bugs.gentoo.org/955814
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-util/diffoscope/Manifest              |   1 +
 dev-util/diffoscope/diffoscope-295.ebuild | 143 ++++++++++++++++++++++++++++++
 2 files changed, 144 insertions(+)

diff --git a/dev-util/diffoscope/Manifest b/dev-util/diffoscope/Manifest
index 70cd7a56ef80..2a9fb9a6cce3 100644
--- a/dev-util/diffoscope/Manifest
+++ b/dev-util/diffoscope/Manifest
@@ -1,3 +1,4 @@
 DIST diffoscope-289.tar.bz2 3157044 BLAKE2B bd7c705098857251883a4506d483e23c24c845ecc624e7487afc111e01a8aee710862abf0ea1638c9c2455812d4cf6a2f491e63bfa6389d4dc9ff053a30de30b SHA512 e47538aed4136ef0891d569a0723c45d294757592762f20281fe6061aa52a4f926f49e7e491cb0a746f6f60bc14834762d1de968879db49b8a9a3b0e01a1ffc6
 DIST diffoscope-293.tar.bz2 3157506 BLAKE2B eb52326fafb8a1c8642170828f4cee10ad055c4dc586a28648806c748e2368d3fffc7a5be088be0c4792b8daf81199f4aefbf0e573cc6bc1a16068c70a697f81 SHA512 39e0d8895207d6cb108cb2483508bfded7fa55aa15dfff6bf5d293e149a9359cdf5159d3657f0f584da98889375f65ae26b0a87d6f62938cfcbd438d29d83b30
 DIST diffoscope-294.tar.bz2 3156736 BLAKE2B bbf02bcc9741c8f481123cd844c0762609fcdcc415a0610af239a61dea6950dbf4de7e4ac9229c973f97c433c1e42c9bcf16d7e3626c76d9baa55386fd3c353d SHA512 6333edd3143760302156da80672bdabdf2f9f3d4fe9e5d7f5d7d070c34069ed00b0aec44aa6e9104f1880b647219778be410fdb7e34a3a90fdb823f21d6d2ad1
+DIST diffoscope-295.tar.bz2 3156923 BLAKE2B 7b23518fe41889644854c82e1fe5ae40e23a59bf8231f4030db0ce8a5ecf1c29078b710711150aeecef783def366a3a35ef96ffe2d91b05e7ffe1bf1b43e9f01 SHA512 4b93c17bb98f764ca44b1662b10883b4cfc4559e0acfa676d9ef341f3e9482a87ad2b0f2aa74fccd6a35461d6bebb37457fec335af980ee8cb55a426a282a33b

diff --git a/dev-util/diffoscope/diffoscope-295.ebuild b/dev-util/diffoscope/diffoscope-295.ebuild
new file mode 100644
index 000000000000..aa51ba3236f0
--- /dev/null
+++ b/dev-util/diffoscope/diffoscope-295.ebuild
@@ -0,0 +1,143 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+PYTHON_REQ_USE="ncurses"
+inherit distutils-r1 toolchain-funcs
+
+DESCRIPTION="Will try to get to the bottom of what makes files or directories different"
+HOMEPAGE="https://diffoscope.org/ https://pypi.org/project/diffoscope/"
+# We could use pypi, but upstream provide distribution tarballs, so let's use those.
+# TODO: verify-sig
+SRC_URI="https://diffoscope.org/archive/${P}.tar.bz2"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="acl binutils bzip2 libcaca colord cpio +diff docx dtc e2fsprogs file
+find gettext gif gpg haskell hdf5 hex imagemagick iso java llvm lzma
+mono opendocument pascal pdf postscript R rpm sqlite squashfs
+ssh tar test tcpdump zip zlib zstd"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	|| (
+		dev-python/python-magic[${PYTHON_USEDEP}]
+		sys-apps/file[python,${PYTHON_USEDEP}]
+	)
+	dev-python/libarchive-c[${PYTHON_USEDEP}]
+	dev-python/distro[${PYTHON_USEDEP}]
+	dev-python/python-tlsh[${PYTHON_USEDEP}]
+	acl? ( sys-apps/acl )
+	binutils? ( sys-devel/binutils )
+	bzip2? ( app-arch/bzip2 )
+	libcaca? ( media-libs/libcaca )
+	colord? ( x11-misc/colord )
+	cpio? ( app-alternatives/cpio )
+	diff? ( sys-apps/diffutils )
+	docx? ( app-text/docx2txt )
+	dtc? ( sys-apps/dtc )
+	e2fsprogs? ( sys-fs/e2fsprogs )
+	file? ( sys-apps/file )
+	find? ( sys-apps/findutils )
+	gettext? ( sys-devel/gettext )
+	gif? ( media-libs/giflib )
+	gpg? ( app-crypt/gnupg )
+	haskell? ( dev-lang/ghc )
+	hdf5? ( sci-libs/hdf5 )
+	hex? ( app-editors/vim-core )
+	imagemagick? ( media-gfx/imagemagick )
+	iso? ( app-cdr/cdrtools )
+	java? ( virtual/jdk )
+	llvm? ( llvm-core/llvm )
+	lzma? ( app-arch/xz-utils )
+	mono? ( dev-lang/mono )
+	opendocument? ( app-text/odt2txt )
+	pascal? ( dev-lang/fpc )
+	pdf? (
+		app-text/pdftk
+		app-text/poppler
+		dev-python/pypdf[${PYTHON_USEDEP}]
+	)
+	postscript? ( app-text/ghostscript-gpl )
+	R? ( dev-lang/R )
+	rpm? ( app-arch/rpm )
+	sqlite? ( dev-db/sqlite:3 )
+	squashfs? ( sys-fs/squashfs-tools )
+	ssh? ( virtual/openssh )
+	tar? ( app-arch/tar )
+	tcpdump? ( net-analyzer/tcpdump )
+	zip? ( app-arch/unzip )
+	zlib? ( app-arch/gzip )
+	zstd? ( app-arch/zstd )
+"
+
+# pull in optional tools for tests:
+# img2txt: bug #797688
+# docx2txt: bug #797688
+BDEPEND="
+	test? (
+		|| (
+			>=app-arch/7zip-24.09[symlink(+)]
+			app-arch/p7zip
+		)
+		app-text/docx2txt
+		app-text/html2text
+		media-libs/libcaca
+		virtual/imagemagick-tools[jpeg]
+	)
+"
+
+EPYTEST_DESELECT=(
+	# Test seems to use different tarball
+	tests/test_presenters.py::test_text_proper_indentation
+
+	# Needs triage
+	tests/comparators/test_binary.py::test_with_compare_details_and_tool_not_found
+	tests/comparators/test_rlib.py::test_item3_deflate_llvm_bitcode
+	tests/comparators/test_gif.py::test_has_visuals
+
+	# img2txt based failures, bug #797688
+	tests/comparators/test_ico_image.py::test_diff
+	tests/comparators/test_ico_image.py::test_diff_meta
+	tests/comparators/test_ico_image.py::test_diff_meta2
+	tests/comparators/test_ico_image.py::test_has_visuals
+	tests/comparators/test_jpeg_image.py::test_diff
+	tests/comparators/test_jpeg_image.py::test_compare_non_existing
+	tests/comparators/test_jpeg_image.py::test_diff_meta
+	tests/comparators/test_jpeg_image.py::test_has_visuals
+
+	# docx2txt based falures, bug #797688
+	tests/comparators/test_docx.py::test_diff
+
+	# Formatting
+	tests/test_source.py::test_code_is_black_clean
+
+	# Fails on ZFS
+	tests/test_main.py::test_non_unicode_filename
+
+	# Fails on (unreleased) LLVM 16 with minor difference
+	#tests/comparators/test_macho.py::test_llvm_diff
+	#tests/comparators/test_elf.py::test_libmix_differences
+)
+
+distutils_enable_tests pytest
+
+src_test() {
+	case $(tc-get-ptr-size) in
+		4)
+			EPYTEST_IGNORE+=(
+				# Needs fixing in Perl itself (bug #934443)
+				tests/comparators/test_epub.py
+				tests/comparators/test_zip.py
+			)
+			;;
+		*)
+			;;
+	esac
+
+	distutils-r1_src_test
+}