[gentoo-commits] repo/gentoo:master commit in: app-misc/fastfetch/

["Viorel Munteanu" <ceamac@gentoo.org>]

commit:     7f9a6b5bdbaf29f3212ed575cb70ae1c908e40a2
Author:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
AuthorDate: Fri Apr  4 06:08:00 2025 +0000
Commit:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
CommitDate: Fri Apr  4 06:08:20 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7f9a6b5b

app-misc/fastfetch: drop 2.40.0

Signed-off-by: Viorel Munteanu <ceamac <AT> gentoo.org>

 app-misc/fastfetch/Manifest                |   1 -
 app-misc/fastfetch/fastfetch-2.40.0.ebuild | 124 -----------------------------
 2 files changed, 125 deletions(-)

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index cf9f2098570e..28b8a379606b 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1,5 +1,4 @@
 DIST fastfetch-2.36.1.tar.gz 1176932 BLAKE2B 0a7727e049de9a5dbb945b171e720ea888c7d7ee77ee145b6122f09cf2933eccde5437ae76f0e89501e38e17edc4349e074747abc7dd4c89b9c1e1005b96197e SHA512 2906b8e6912185a3acdd2b615ff869fa8f44ce0e547ed5529068eb2570ef5c013ed84691e62d613e52f2433595aa4e67859cf89b4116588ba4cb7c7bb7d8bb01
 DIST fastfetch-2.38.0.tar.gz 1207024 BLAKE2B 7d3d34416899c19741667d0f1fdc2f5cf8596bd555a3e06910292a51b7d0cdbbe98e4203245d497c350195505fd01cc194cceba395f06edc6fa69761f621452a SHA512 6c4ffebd2999c3882cd31a6e393f78d693c688b67ab62972b70833e24c0fee2f9d79f3b1ea82c6262e71e0b45fcc40f296194ae54beca65a817ccd25cde771d0
 DIST fastfetch-2.39.1.tar.gz 1211540 BLAKE2B aa9cd1301bac471782f9756974533a20677da0720a1ce45bf6328ea1d39c53dcaa2c99dd693c483faf688bb3e707c56b4bdf6ebe507685883d9f141c6eb0d877 SHA512 c2c045f1af50dff43a4414939716d6d3467ee6dc8adeabe0e0cb37e7b9523ad52361627efa4b94854256e4b1349f12bd48c193fff04c764ecbd1a78023ee6526
-DIST fastfetch-2.40.0.tar.gz 1275290 BLAKE2B 52de4e6f79ed34611092ddf773aece00fb51d3a051fbc1f097c3b8294dbf8d04a8f7273e97b4b3979c15b598644d2ff71e4208312f7eb8e35265e0b50f78ad7c SHA512 6cba09f55f8a0dd7b92d6db123125d2ee6a3bcf12464b5d929460179f09952cd59c42c3d38cadfe02ea6b58924d81c4c39e787fb353eee6a52f1d8d32057632f
 DIST fastfetch-2.40.1.tar.gz 1274904 BLAKE2B 6b8d578278614d634ade1d4325937cc7c661f79eaba246cb53924f4d34a6cfac47275bdd4ae36569c999ccc857d1a7fa94b19e7286f396162e09f1f9c365dff3 SHA512 f91274772943a5cf864982b03a69cd5bb53de71efa2e85b8f39cf1bc30c0d68748924d61abe0a662acbbb9e3620b13103d0c29622891a7604e4870ebac8e8833

diff --git a/app-misc/fastfetch/fastfetch-2.40.0.ebuild b/app-misc/fastfetch/fastfetch-2.40.0.ebuild
deleted file mode 100644
index 641a422f3188..000000000000
--- a/app-misc/fastfetch/fastfetch-2.40.0.ebuild
+++ /dev/null
@@ -1,124 +0,0 @@
-# Copyright 2022-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake flag-o-matic
-
-DESCRIPTION="Fast neofetch-like system information tool"
-HOMEPAGE="https://github.com/fastfetch-cli/fastfetch"
-if [[ ${PV} == *9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/fastfetch-cli/fastfetch.git"
-	[[ ${PV} == *0.1.9999 ]] && EGIT_BRANCH=master
-	[[ ${PV} == *0.2.9999 ]] && EGIT_BRANCH=dev
-	[[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
-else
-	SRC_URI="https://github.com/fastfetch-cli/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
-fi
-
-LICENSE="MIT"
-SLOT="0"
-IUSE="X chafa dbus ddcutil drm elf gnome imagemagick opencl opengl pulseaudio sqlite test vulkan wayland xcb xfce xrandr"
-RESTRICT="!test? ( test )"
-
-# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
-# make sure to crank yyjson minimum version to match bundled version
-RDEPEND="
-	>=dev-libs/yyjson-0.10.0
-	sys-apps/hwdata
-	sys-libs/zlib
-	chafa? ( media-gfx/chafa )
-	dbus? ( sys-apps/dbus )
-	ddcutil? ( app-misc/ddcutil:= )
-	drm? ( x11-libs/libdrm )
-	elf? ( virtual/libelf:= )
-	gnome? (
-		dev-libs/glib
-		gnome-base/dconf
-	)
-	imagemagick? ( media-gfx/imagemagick:= )
-	opencl? ( virtual/opencl )
-	opengl? (
-		media-libs/libglvnd[X?]
-		X? ( x11-libs/libX11 )
-	)
-	pulseaudio? ( media-libs/libpulse )
-	sqlite? ( dev-db/sqlite:3 )
-	vulkan? (
-		media-libs/vulkan-loader
-		sys-apps/pciutils
-	)
-	wayland? ( dev-libs/wayland )
-	xcb? ( x11-libs/libxcb )
-	xfce? ( xfce-base/xfconf )
-	xrandr? ( x11-libs/libXrandr )
-"
-DEPEND="
-	${RDEPEND}
-	opengl? ( X? ( x11-base/xorg-proto ) )
-	xcb? ( x11-base/xorg-proto )
-	xrandr? ( x11-base/xorg-proto )
-	vulkan? ( dev-util/vulkan-headers )
-"
-BDEPEND="virtual/pkgconfig"
-
-REQUIRED_USE="
-	chafa? ( imagemagick )
-"
-
-pkg_pretend() {
-	if use X && ! use opengl; then
-		einfo 'USE="X" adds GLX support for USE="opengl"'
-		einfo 'This build with USE="X -opengl" will not include any extra X support.'
-	fi
-}
-
-src_configure() {
-	local fastfetch_enable_imagemagick7=no
-	local fastfetch_enable_imagemagick6=no
-	if use imagemagick; then
-		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
-		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
-	fi
-
-	local glx=no
-	if use opengl && use X; then
-		glx=yes
-	fi
-
-	local mycmakeargs=(
-		-DENABLE_RPM=no
-		-DENABLE_ZLIB=yes
-		-DENABLE_SYSTEM_YYJSON=yes
-		-DIS_MUSL=$(usex elibc_musl)
-		-DINSTALL_LICENSE=no
-		-DBUILD_FLASHFETCH=no
-
-		-DENABLE_CHAFA=$(usex chafa)
-		-DENABLE_DBUS=$(usex dbus)
-		-DENABLE_DCONF=$(usex gnome)
-		-DENABLE_DDCUTIL=$(usex ddcutil)
-		-DENABLE_DRM=$(usex drm)
-		-DENABLE_ELF=$(usex elf)
-		-DENABLE_EGL=$(usex opengl)
-		-DENABLE_GIO=$(usex gnome)
-		-DENABLE_GLX=${glx}
-		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
-		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
-		-DENABLE_OPENCL=$(usex opencl)
-		-DENABLE_PULSE=$(usex pulseaudio)
-		-DENABLE_SQLITE3=$(usex sqlite)
-		-DENABLE_VULKAN=$(usex vulkan)
-		-DENABLE_WAYLAND=$(usex wayland)
-		-DENABLE_XCB_RANDR=$(usex xcb)
-		-DENABLE_XFCONF=$(usex xfce)
-		-DENABLE_XRANDR=$(usex xrandr)
-		-DBUILD_TESTS=$(usex test)
-	)
-
-	append-cppflags -DNDEBUG
-
-	cmake_src_configure
-}