[gentoo-commits] repo/gentoo:master commit in: dev-python/opentelemetry-api/

["Michał Górny" <mgorny@gentoo.org>]

commit:     631d6d53900e3365f33e4a2f98c1659f45254e04
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Mar 13 06:57:47 2025 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Mar 13 06:57:47 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=631d6d53

dev-python/opentelemetry-api: Bump to 1.31.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/opentelemetry-api/Manifest              |  1 +
 .../opentelemetry-api-1.31.0.ebuild                | 61 ++++++++++++++++++++++
 2 files changed, 62 insertions(+)

diff --git a/dev-python/opentelemetry-api/Manifest b/dev-python/opentelemetry-api/Manifest
index 3e114aba3a70..e9d988b09d7e 100644
--- a/dev-python/opentelemetry-api/Manifest
+++ b/dev-python/opentelemetry-api/Manifest
@@ -1 +1,2 @@
 DIST opentelemetry-python-1.30.0.gh.tar.gz 1189401 BLAKE2B 10a52a24625ee80f0b68e7fad05f770098be75c21ccf0230a786a1ffc4b3fb23daf251dc129bab840d22ff2ac9a6bab1c84e55c644abcd1b475dc7a5872447a5 SHA512 cd74100aa60639b3722f2747bd19dae42bffbfca4007837a6cf8db61a408c59601064c9718782b9f6ebeee7a30a454e03a09950b2b00845d642f6452a894674b
+DIST opentelemetry-python-1.31.0.gh.tar.gz 1224355 BLAKE2B 050149fa7c0c445556d184f921209b59b6e4e5aea225bbb315b781b0f4a95892385aeaae6f385f1fee8ef412981ce92b17e65d4dcd863622c22d027705a23890 SHA512 d69d9c8f6fee0e39c37e92fbf1df14e903b8165e07933fd6d2a70d510b373f8ca70f9b69a12ac6d8863013e87ac2753d07aebb336bec49d1c7a555dc62c15129

diff --git a/dev-python/opentelemetry-api/opentelemetry-api-1.31.0.ebuild b/dev-python/opentelemetry-api/opentelemetry-api-1.31.0.ebuild
new file mode 100644
index 000000000000..ccacff2cff89
--- /dev/null
+++ b/dev-python/opentelemetry-api/opentelemetry-api-1.31.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1
+
+MY_P="opentelemetry-python-${PV}"
+DESCRIPTION="OpenTelemetry Python API"
+HOMEPAGE="
+	https://opentelemetry.io/
+	https://pypi.org/project/opentelemetry-api/
+	https://github.com/open-telemetry/opentelemetry-python/
+"
+SRC_URI="
+	https://github.com/open-telemetry/opentelemetry-python/archive/refs/tags/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/${PN}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/deprecated-1.2.6[${PYTHON_USEDEP}]
+	dev-python/importlib-metadata[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	default
+
+	# Unnecessary restriction
+	sed -i -e '/importlib-metadata/s:, <= [0-9.]*::' pyproject.toml || die
+}
+
+python_test() {
+	cp -a "${BUILD_DIR}"/{install,test} || die
+	local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
+
+	for dep in opentelemetry-semantic-conventions opentelemetry-sdk \
+		tests/opentelemetry-test-utils
+	do
+		pushd "${WORKDIR}/${MY_P}/${dep}" >/dev/null || die
+		distutils_pep517_install "${BUILD_DIR}"/test
+		popd >/dev/null || die
+	done
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}