[gentoo-commits] repo/gentoo:master commit in: net-im/qtox/

["Jimi Huotari" <chiitoo@gentoo.org>]

commit:     759d54cb3ac44d7b921bc6c464f6fa35a6188e4c
Author:     Jimi Huotari <chiitoo <AT> gentoo <DOT> org>
AuthorDate: Tue Feb 25 13:49:57 2025 +0000
Commit:     Jimi Huotari <chiitoo <AT> gentoo <DOT> org>
CommitDate: Tue Feb 25 14:08:17 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=759d54cb

net-im/qtox: add 1.18.3

Signed-off-by: Jimi Huotari <chiitoo <AT> gentoo.org>

 net-im/qtox/Manifest           |  1 +
 net-im/qtox/qtox-1.18.3.ebuild | 77 ++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 78 insertions(+)

diff --git a/net-im/qtox/Manifest b/net-im/qtox/Manifest
index 8214149d3115..113f409ae970 100644
--- a/net-im/qtox/Manifest
+++ b/net-im/qtox/Manifest
@@ -1,2 +1,3 @@
 DIST qTox-1.17.6.tar.gz 4777590 BLAKE2B d67ea8c1d5c478a791fd8594866130874c036f22ec9fd991e0f6c81fb7919824bba8e13675b0ffaf613188215a4fce6d07545476ab5565922b3989519aedd91f SHA512 840dfbca2cb1a3db4b5ab27cb408e183b152fcd87c0cb915ee58245e7c311b8682605e73497248072a5a48b239058b101a85235ed169d19606dc7bf61865f208
 DIST qTox-1.18.2.tar.gz 5341017 BLAKE2B 563af4ae55f54876af78376942ecec1674c004643ac5e359e2bddbbd09480b415414b29268a53422d4803a876ac6ba4668c69ac7b9f9e6b018af306dcf6308df SHA512 f051ddb53c1760854685442e2c65c0339821388bb53cb2a7445d3110c66777b7ce9abe262f5b6f1920794e16bba1ef42f65765851b7c797cfc3d5540099052f6
+DIST qTox-1.18.3.tar.gz 5312073 BLAKE2B 5c7e4827b72af6bc6383600ace8bd878b47f5b3cf6edab3b8bfa65e0f489ddeca75f15f6bb5e5c41d63be2dd8a6aab2b600075284b4f8a8960377c13ca345e22 SHA512 c0d9a832fc937b5d0b67a5905d3ac60d31ffa92492533c41caad23a53d8538bc44202b09811d2d1495afb3a0a0f1badb0c6900b8a291ef78ee736d47fc030136

diff --git a/net-im/qtox/qtox-1.18.3.ebuild b/net-im/qtox/qtox-1.18.3.ebuild
new file mode 100644
index 000000000000..84d82fa29ba4
--- /dev/null
+++ b/net-im/qtox/qtox-1.18.3.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/TokTok/qTox.git"
+else
+	MY_P="qTox-${PV}"
+	SRC_URI="https://github.com/TokTok/qTox/archive/v${PV}/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}/qTox-${PV}"
+fi
+
+DESCRIPTION="Instant messaging client using the encrypted p2p Tox protocol"
+HOMEPAGE="https://qtox.github.io/"
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="spellcheck X"
+
+BDEPEND="
+	dev-qt/qttools:6[linguist]
+	virtual/pkgconfig
+"
+RDEPEND="
+	dev-db/sqlcipher
+	dev-libs/libsodium:=
+	dev-qt/qtbase:6[concurrent,gui,network,opengl,widgets,xml]
+	dev-qt/qtsvg:6
+	media-gfx/qrencode:=
+	media-libs/libexif
+	media-libs/openal
+	media-video/ffmpeg:=[webp,v4l]
+	>=net-libs/tox-0.2.19:=[av]
+	spellcheck? (
+		|| (
+			kde-frameworks/sonnet:6[aspell]
+			kde-frameworks/sonnet:6[hunspell]
+		)
+	)
+	X? (
+		dev-qt/qtbase:6=[X]
+		x11-libs/libX11
+		x11-libs/libXScrnSaver
+	)
+"
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )
+"
+
+DOCS=( CHANGELOG.md README.md doc/user_manual_en.md )
+
+src_configure() {
+	local mycmakeargs=(
+		-DASAN=OFF
+		-DPLATFORM_EXTENSIONS=$(usex X)
+		-DSPELL_CHECK=$(usex spellcheck)
+		-DSTRICT_OPTIONS=OFF
+		-DTSAN=OFF
+		-DUBSAN=ON
+		-DUPDATE_CHECK=OFF
+		-DUSE_CCACHE=OFF
+	)
+
+	[[ ${PV} != 9999 ]] && mycmakeargs+=( -DGIT_DESCRIBE=${PV} )
+
+	cmake_src_configure
+}
+
+src_test() {
+	# The excluded tests require network access.
+	cmake_src_test -E "test_(bsu|core)"
+}