[gentoo-commits] repo/gentoo:master commit in: dev-python/jsonpickle/

["Michał Górny" <mgorny@gentoo.org>]

commit:     7bb655af311c48f21aa5c6dc1dcc6e56bb852f87
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Feb 18 06:36:09 2025 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Feb 18 07:35:48 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7bb655af

dev-python/jsonpickle: Bump to 4.0.2

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/jsonpickle/Manifest                |  1 +
 dev-python/jsonpickle/jsonpickle-4.0.2.ebuild | 67 +++++++++++++++++++++++++++
 2 files changed, 68 insertions(+)

diff --git a/dev-python/jsonpickle/Manifest b/dev-python/jsonpickle/Manifest
index 5aa61115066c..541f5aa5470c 100644
--- a/dev-python/jsonpickle/Manifest
+++ b/dev-python/jsonpickle/Manifest
@@ -1 +1,2 @@
 DIST jsonpickle-4.0.1.gh.tar.gz 307912 BLAKE2B c8f6e9320eb38c6656d97f3b1397040a03ff09b31bb924bb38112c041e7e91954b7c1026328dd511e382a238731d6ca017331881e7fd15da68607daa1d01fba9 SHA512 21da8f4fc1d1801cd2dc7849b6088f9991814d86014df30f769e7c07035934e2f794a3a449714b64ac5cc4452f1af163a7d8c52fb5432972e058d832bab4daf1
+DIST jsonpickle-4.0.2.gh.tar.gz 308419 BLAKE2B 139b6ee1ecc50ea97cb80833f7ff018035dde4ff1d090be0f6b57b4352540c14f0d8a6038a5b00897b5d4c64d5bdd3ac577437393c16fceb0616ae75880c5929 SHA512 177c01e517c026d1c710f2754a1ba7a1bcd95de7a2b3c9d9c823c9743a096549fa3b3d3a1576e740b7dedced51eb178af6abfe1e380c511355ee4072e60a75cb

diff --git a/dev-python/jsonpickle/jsonpickle-4.0.2.ebuild b/dev-python/jsonpickle/jsonpickle-4.0.2.ebuild
new file mode 100644
index 000000000000..904a46bb3345
--- /dev/null
+++ b/dev-python/jsonpickle/jsonpickle-4.0.2.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Python library for serializing any arbitrary object graph into JSON"
+HOMEPAGE="
+	https://github.com/jsonpickle/jsonpickle/
+	https://pypi.org/project/jsonpickle/
+"
+SRC_URI="
+	https://github.com/jsonpickle/jsonpickle/archive/refs/tags/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/feedparser[${PYTHON_USEDEP}]
+		dev-python/gmpy2[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/simplejson[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+		dev-python/ujson[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# unpackaged bson dependency
+		tests/bson_test.py
+	)
+
+	if ! has_version "dev-python/gmpy2[${PYTHON_USEDEP}]"; then
+		EPYTEST_IGNORE+=( jsonpickle/ext/gmpy.py )
+	fi
+	if ! has_version "dev-python/pandas[${PYTHON_USEDEP}]"; then
+		EPYTEST_IGNORE+=( jsonpickle/ext/pandas.py )
+	fi
+
+	epytest tests
+}
+
+pkg_postinst() {
+	# Unpackaged optional backends: yajl, demjson
+	optfeature "encoding numpy-based data" dev-python/numpy
+	optfeature "encoding pandas objects" dev-python/pandas
+	optfeature "fast JSON backend" dev-python/simplejson
+}